isba_ceb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########
SUBROUTINE isba_ceb(IO, KK, PK, PEK, DK, DEK, DMK,      &
                    HIMPLICIT_WIND, PTSTEP, PPEW_A_COEF,   &
                    PPEW_B_COEF, PPET_A_COEF, PPEQ_A_COEF, PPET_B_COEF,&
                    PPEQ_B_COEF, PSW_RAD, PLW_RAD, PEXNS, PEXNA, PTA,  &
                    PVMOD, PQA, PRR, PSR, PPS, PZREF, PUREF, PDIRCOSZW,&
                    PF5, PFFG_NOSNOW, PFFV_NOSNOW, PRHOA, PCS,         &
                    PSOILCONDZ, PSOILHCAPZ, PFROZEN1, PTDEEP_A,        &
                    PGRNDFLUX, PFLSN_COR, PSNOW_THRUFAL, PDELTA, PHUGI,&
                    PALBT, PEMIST, PDEEP_FLUX, PUSTAR, PAC_AGG, PHU_AGG )
!     ##########################################################################
!
!
!!****  *ISBA_CEB*  
!!
!!    PURPOSE
!!    -------
!       Monitor for the calculation of the surface composit energy budget
!!      call of drag, e_budget, and isba_fluxes
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!    Noilhan and Planton (1989)
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/03/95 
!!      (B. Decharme)   03/16 Bug : limitation of Er for Interception reservoir
!!                                  PTSTEP insted of ZTSTEP in drag.F90
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_k_t, isba_p_t, isba_pe_t
USE modd_diag_n, ONLY : diag_t
USE modd_diag_evap_isba_n, ONLY : diag_evap_isba_t
USE modd_diag_misc_isba_n, ONLY : diag_misc_isba_t
!
USE modd_surf_par,   ONLY : xundef
!
USE modd_surf_atm,   ONLY : lcpl_arp
!
USE modi_drag
USE modi_e_budget
USE modi_isba_fluxes
!
USE mode_thermos
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!              -------------------------
!
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_k_t), INTENT(INOUT) :: KK
TYPE(isba_p_t), INTENT(INOUT) :: PK
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
TYPE(diag_t), INTENT(INOUT) :: DK
TYPE(diag_evap_isba_t), INTENT(INOUT) :: DEK
TYPE(diag_misc_isba_t), INTENT(INOUT) :: DMK
!
 CHARACTER(LEN=*),    INTENT(IN) :: HIMPLICIT_WIND   ! wind implicitation option
!                                                    ! 'OLD' = direct
!                                                    ! 'NEW' = Taylor serie, order 1
REAL,                 INTENT(IN) :: PTSTEP    ! timestep of the integration
REAL, DIMENSION(:),  INTENT(IN)  :: PPEW_A_COEF, PPEW_B_COEF,                   &
                                    PPET_A_COEF, PPEQ_A_COEF, PPET_B_COEF,      &
                                    PPEQ_B_COEF  
!                                  PPEW_A_COEF = A-wind coefficient (m2s/kg)
!                                  PPEW_B_COEF = B-wind coefficient (m/s)
!                                  PPET_A_COEF = A-air temperature coefficient
!                                  PPET_B_COEF = B-air temperature coefficient
!                                  PPEQ_A_COEF = A-air specific humidity coefficient
!                                  PPEQ_B_COEF = B-air specific humidity coefficient
!
REAL, DIMENSION(:), INTENT(IN)   :: PSW_RAD, PLW_RAD
!                                     PSW_RAD = incoming solar radiation
!                                     PLW_RAD = atmospheric infrared radiation

REAL, DIMENSION(:), INTENT(IN)   :: PEXNA, PEXNS, PTA, PVMOD, PQA, PRR, PSR, PPS
!                                     PEXNA= Exner function near surface atmospheric variables
!                                     PEXNS   = Exner function at the surface
!                                     PTA = 2m temperature
!                                     PVMOD = module of the horizontal wind
!                                             NOTE it should be input as >= 1. (m)
!                                     PQA = specific humidity
!                                     PPS = surface pressure
!                                     PRR = rain rate    
!                                     PSR = snow rate             
!
REAL, DIMENSION(:), INTENT(IN)   :: PZREF, PUREF
!                                     PZREF = reference height of the first
!                                             atmospheric level 
!                                     PUREF = reference height of the wind
!                                             NOTE this is different from ZZREF
!                                             ONLY in stand-alone/forced mode,
!                                             NOT when coupled to a model (MesoNH)
!
REAL, DIMENSION(:), INTENT(IN)    :: PF5
!                                     PF5 = water stress function for Hv
REAL, DIMENSION(:), INTENT(IN)    :: PDIRCOSZW 
!                                     PDIRCOSZW = Cosinus of the angle between the normal to the surface and the vertical
!
REAL, DIMENSION(:), INTENT(IN)   :: PFFG_NOSNOW, PFFV_NOSNOW
!
REAL, DIMENSION(:), INTENT(IN)   :: PRHOA
!                                   PRHOA = near-ground air density
!
REAL, DIMENSION(:), INTENT(IN)   :: PCS
!                                     PEMIS = emissivity
!                                     PCS    = heat capacity of the snow (K m2 J-1)
REAL, DIMENSION(:), INTENT(IN)   :: PGRNDFLUX, PFLSN_COR, PSNOW_THRUFAL 
!                                     PGRNDFLUX = soil/snow interface flux (W/m2) using
!                                                 ISBA-SNOW3L option
!                                     PFLSN_COR = soil/snow interface correction flux to conserve energy (W/m2)
!                                     PSNOW_THRUFAL  = snow runoff/melt leaving pack and available
!                                                  at the surface for runoff or infiltration
!                                                  [kg/(m2 s)]
REAL, DIMENSION(:,:), INTENT(IN)  :: PSOILCONDZ, PSOILHCAPZ
!                                     PSOILCONDZ= ISBA-DF Soil conductivity profile  [W/(m K)]
!                                     PSOILHCAPZ=ISBA-DF Soil heat capacity profile [J/(m3 K)]
!
REAL, DIMENSION(:), INTENT(IN)    :: PFROZEN1
!                                     PFROZEN1 = ice fraction in supurficial soil
!
REAL, DIMENSION(:), INTENT(IN)     :: PTDEEP_A
!                                      PTDEEP_A = Deep soil temperature
!                                                 coefficient depending on flux
!inout
!
REAL, DIMENSION(:),   INTENT(INOUT) :: PDELTA
!                                      PDELTA = fraction of the foliage covered
!                                              by intercepted water
!out
!
REAL, DIMENSION(:), INTENT(OUT)  :: PHUGI
!                                     PHUGI = ground (ice) relative humidity
!
REAL, DIMENSION(:), INTENT(OUT)  :: PALBT, PEMIST
!                                     PALBT  = averaged albedo
!                                     PEMIST = averaged emissivity
!
REAL, DIMENSION(:), INTENT(OUT)   :: PDEEP_FLUX ! Heat flux at bottom of ISBA (W/m2)
!
REAL, DIMENSION(:), INTENT(OUT)     :: PUSTAR
!                                      PUSTAR  = friction velocity
!
REAL, DIMENSION(:),  INTENT(OUT) :: PAC_AGG  ! aggregated aerodynamic conductance
                                     ! for evaporative flux calculations
REAL, DIMENSION(:),  INTENT(OUT) :: PHU_AGG  ! aggregated relative humidity
                                    ! for evaporative flux calculations
!
!
!*      0.2    declarations of local parameters
!
REAL, PARAMETER            :: ZDEKTH_COR = 0.6
!                             ZDEKTH_COR = depth over which the correction flux is applied
!
REAL, PARAMETER            :: ZDTG1_COR = 10.0 
!                             ZDTG1_COR = Delta temperature limit to comput the correction flux (K)
!
!
!*      0.3    declarations of local variables
!
REAL, DIMENSION(SIZE(PTA)) :: ZQSAT     ! expression for the saturation specific humidity 
!
REAL, DIMENSION(SIZE(PTA)) :: ZDQSAT    ! expression for the saturation specific humidity derivative
!
REAL, DIMENSION(SIZE(PTA)) :: ZTA_IC, ZQA_IC, ZUSTAR2_IC ! TA, QA and friction updated values
!                                                        ! if implicit coupling with atmosphere used.
!
REAL, DIMENSION(SIZE(PTA)) :: ZLEG_DELTA  ! soil evaporation delta fn
REAL, DIMENSION(SIZE(PTA)) :: ZLEGI_DELTA ! soil sublimation delta fn
!
REAL, DIMENSION(SIZE(PTA)) :: ZT2M     ! restore temperature before time integration (K)
REAL, DIMENSION(SIZE(PTA)) :: ZTSM     ! surface temperature before time integration (K)
!
REAL, DIMENSION(SIZE(PEK%XTG,1),SIZE(PEK%XTG,2)) :: ZFLUX_COR, ZLAYERHCAP
!                                           ZFLUX_COR = correction flux by layer to conserve energy (W/m2)
!
REAL, DIMENSION(SIZE(PTA)) :: ZGRNDFLUX, ZTOTALHCAP, ZWORK
!
INTEGER                    :: INJ, INL, JI, JL
LOGICAL                    :: LEXPLICIT_SNOW
!
!*      0.4    declarations of local time spliting variables
!
! Working arrays for flux averaging over time split
!
REAL, DIMENSION(SIZE(PTA)) :: ZDEEP_FLUX, ZLE_FLOOD, ZLEI_FLOOD, &
                              ZRN, ZH, ZLE, ZLEG, ZLEV,  &
                              ZLES, ZLER, ZLETR, ZEVAP,      &
                              ZGFLUX, ZMELTADV, ZMELT,           &
                              ZRESTORE, ZLEGI, ZUSTAR2,          &
                              ZAC_AGG, ZHU_AGG
!
REAL, DIMENSION(SIZE(PTA)) :: ZDEEP_FLUX_SUM, ZLE_FLOOD_SUM, ZLEI_FLOOD_SUM, &
                              ZRN_SUM, ZH_SUM, ZLE_SUM, ZLEG_SUM, ZLEV_SUM,  &
                              ZLES_SUM, ZLER_SUM, ZLETR_SUM, ZEVAP_SUM,      &
                              ZGFLUX_SUM, ZMELTADV_SUM, ZMELT_SUM,           &
                              ZRESTORE_SUM, ZLEGI_SUM, ZUSTAR2_SUM,          &
                              ZAC_AGG_SUM, ZHU_AGG_SUM
!
REAL, PARAMETER            :: ZTSPLIT  = 300. ! s Minimum time tstep required to time-split energy budget
INTEGER                    :: ITSPLIT, JSPLIT
REAL                       :: ZTSTEP, ZNSPLIT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('ISBA_CEB',0,zhook_handle)
!
!-------------------------------------------------------------------------------
!
!*      1.0    Preliminaries
!              -------------
!
inj=SIZE(pek%XTG,1)
inl=SIZE(pek%XTG,2)
!
!local init
!
zqsat(:) = xundef
zta_ic(:) = xundef
zqa_ic(:) = xundef
zustar2_ic(:) = xundef
zleg_delta(:) = xundef
zlegi_delta(:) = xundef
zdqsat(:) = xundef
!
zdeep_flux(:) = xundef
zle_flood(:) = xundef
zlei_flood(:) = xundef
zrn(:) = xundef
zh(:) = xundef
zle(:) = xundef
zleg(:) = xundef
zlev(:) = xundef
zles(:) = xundef
zler(:) = xundef
zletr(:) = xundef
zevap(:) = xundef
zgflux(:) = xundef
zmeltadv(:) = xundef
zmelt(:) = xundef
zrestore(:) = xundef
zlegi(:) = xundef
zac_agg(:) = xundef
zhu_agg(:) = xundef
!
zustar2_sum(:) = 0.0
zevap_sum(:) = 0.0
!
zrn_sum(:) = 0.0
zh_sum(:) = 0.0
zgflux_sum(:) = 0.0
zle_sum(:) = 0.0
!
zleg_sum(:) = 0.0
zlegi_sum(:) = 0.0
zlev_sum(:) = 0.0
zles_sum(:) = 0.0
zler_sum(:) = 0.0
zletr_sum(:) = 0.0
zle_flood_sum(:) = 0.0
zlei_flood_sum(:) = 0.0
!
zdeep_flux_sum(:) = 0.0
zmeltadv_sum(:) = 0.0
zmelt_sum(:) = 0.0
zrestore_sum(:) = 0.0
zac_agg_sum(:) = 0.0
zhu_agg_sum(:) = 0.0
!
!-------------------------------------------------------------------------------
!
zgrndflux(:  ) = pgrndflux(:)
!
zflux_cor(:,:) = 0.0
!
!-------------------------------------------------------------------------------
!
!*      2.0    Correction flux to conserv energy budget
!              ----------------------------------------
!
lexplicit_snow=(pek%TSNOW%SCHEME == '3-L' .OR. pek%TSNOW%SCHEME == 'CRO')
!
IF(lexplicit_snow.AND.io%CISBA/='DIF')THEN
!
  zflux_cor(:,1)=pek%XPSN(:)*pflsn_cor(:)
!
ELSEIF(lexplicit_snow.AND.io%CISBA=='DIF')THEN
!
  zlayerhcap(:,:) = 0.0
  ztotalhcap(:) = 0.0
!
! To conserv energy, the correction flux is distributed at least
! over the first layers of the soil, ZDEKTH_COR. This method prevent 
! numerical oscillations especially when explicit snow vanishes
!
  zwork(:) = min(pk%XDG(:,inl),zdekth_cor)
!
  zlayerhcap(:,1)= 1.0/dmk%XCT(:)
  ztotalhcap(:  )= 1.0/dmk%XCT(:)
  DO jl=2,inl
    DO ji=1,inj
      zlayerhcap(ji,jl) = psoilhcapz(ji,jl) * min( pk%XDZG(ji,jl), &
                max(0.0,zwork(ji)-pk%XDG(ji,jl) +pk%XDZG(ji,jl)) )
      ztotalhcap(ji   ) = ztotalhcap(ji) + zlayerhcap(ji,jl)
    ENDDO
  ENDDO
!
  DO jl=1,inl
    DO ji=1,inj
      IF(ztotalhcap(ji)>0.0)THEN
        zflux_cor(ji,jl) = pek%XPSN(ji)*pflsn_cor(ji)*zlayerhcap(ji,jl)/ztotalhcap(ji)
      ENDIF
    ENDDO
  ENDDO
!
! The second correction is computed if the delta temperature
! due to snow/soil ground flux is superior to ZDTG1_COR (K)
! Especially relevant when PPSN ~ 1 over vegetated area
!
  zwork(:)=ptstep*dmk%XCT(:)*pek%XPSN(:)*abs(pgrndflux(:))
!
  WHERE(ztotalhcap(:)>0.0.AND.zwork(:)>=zdtg1_cor)
    zgrndflux(:) = pgrndflux(:)*zlayerhcap(:,1)/ztotalhcap(:)
  ENDWHERE
!
  DO jl=2,inl
    DO ji=1,inj
      IF(ztotalhcap(ji)>0.0.AND.zwork(ji)>=zdtg1_cor)THEN
        zflux_cor(ji,jl)=zflux_cor(ji,jl)+pek%XPSN(ji)*pgrndflux(ji) &
                                         *zlayerhcap(ji,jl)/ztotalhcap(ji)
      ENDIF
    ENDDO
  ENDDO
!
ENDIF
!
!-------------------------------------------------------------------------------
!
IF(lcpl_arp)THEN
  itsplit = 1
ELSE
  itsplit  = max(1,nint(ptstep/ztsplit))  ! number of split-time steps
ENDIF
!
znsplit  = REAL(itsplit)
!
ztstep  = ptstep/znsplit             ! split time step
!
!-------------------------------------------------------------------------------
!
DO jsplit=1,itsplit
!
!  Save surface and sub-surface temperature values at beginning of time step for 
!  budget and flux calculations:
!
   ztsm(:) = pek%XTG(:,1)
   zt2m(:) = pek%XTG(:,2)
!
!
!*      3.0    Aerodynamic drag and heat transfer coefficients
!              -----------------------------------------------
! 
!  In DRAG, we use the timestep of ISBA (PTSTEP) and not the split time step (ZTSTEP)
!  because diagnostic canopy evaporation (Er) must be consistent with PWR water
!  mass to limit negative dripping in hydro_veg
!
   CALL drag(io%CISBA, pek%TSNOW%SCHEME, io%CCPSURF, ptstep, pek%XTG(:,1), pek%XWG(:,1), &
             pek%XWGI(:,1), pexns, pexna, pta, pvmod, pqa, prr, psr, pps, dmk%XRS, &
             pek%XVEG, dk%XZ0, dk%XZ0EFF, dk%XZ0H, kk%XWFC(:,1), kk%XWSAT(:,1),    &
             pek%XPSNG, pek%XPSNV, pzref, puref, pdircoszw, pdelta, pf5, pek%XRESA,&
             dk%XCH, dk%XCD, dk%XCDN, dk%XRI, dk%XHUG, phugi, dmk%XHV, dk%XHU,     &
             pk%XCPS, dk%XQS, kk%XFFG, kk%XFFV, kk%XFF, pffg_nosnow, pffv_nosnow, &
             zleg_delta, zlegi_delta, pek%XWR, prhoa, pk%XLVTT, pqsat=zqsat ) 
!
!*      4.0    Resolution of the surface and soil energy budget
!              ------------------------------------------------
!
   CALL e_budget(io, kk, pk, pek, dk, dmk, himplicit_wind,  &
                 ztstep, puref, ppew_a_coef, ppew_b_coef, ppet_a_coef,          &
                 ppeq_a_coef, ppet_b_coef, ppeq_b_coef, pvmod, ztsm, zt2m,      &
                 psw_rad, plw_rad, pta, pqa, pps, prhoa, pexns, pexna,          &
                 phugi, zleg_delta, zlegi_delta,  zgrndflux, zflux_cor,         &
                 psoilcondz, psoilhcapz, palbt, pemist, zqsat, zdqsat,          &
                 pfrozen1, ptdeep_a, zta_ic, zqa_ic, zustar2_ic, zdeep_flux,    &
                 zrestore          )
!
!*      5.0    Energy and momentum fluxes
!              --------------------------
!
!*******************************************************************************
! WARNING: at this stage, ZALBT and ZEMIST have two different meanings according
!          to the ISBA snow-scheme option:
!  'D95' : they represent aggregated (snow + flood + snow-flood-free) albedo and emissivity
!  '3-L' : they represent                    flood + snow-flood-free  albedo and emissivity
!*******************************************************************************
!
   CALL isba_fluxes(io, kk, pk, pek, dmk, ztstep,           &
                    psw_rad, plw_rad, zta_ic, zqa_ic, prhoa, pexns, pexna,    &
                    dk%XHUG, phugi, zleg_delta, zlegi_delta, pdelta, pf5,   &
                    pcs, ztsm, zt2m, pfrozen1, palbt, pemist, zqsat, zdqsat,  &
                    psnow_thrufal, zrn, zh, zle, zleg, zlegi, zlev, zles,     &
                    zler, zletr, zevap, zgflux, zmeltadv, zmelt, psoilcondz,  &
                    zle_flood, zlei_flood )
!
!
!*      6.0    Aggregated coefficients
!              -----------------------
!
!  Compute aggregated coefficients for evaporation
!  Sum(LEV+LEG+LEGI+LES) = ACagg * Lv * RHOA * (HUagg.Qsat - Qa)
!
   zac_agg(:) =   1. / pek%XRESA(:) / pk%XLVTT(:)     &
             * ( pk%XLVTT(:) *    pek%XVEG(:) * (1.-pek%XPSNV(:)) * dmk%XHV(:)   &
               + pk%XLVTT(:) *(1.-pek%XVEG(:))* (1.-pek%XPSNG(:)) * (1.-pfrozen1(:))  &
               + pk%XLSTT(:) *(1.-pek%XVEG(:))* (1.-pek%XPSNG(:)) * pfrozen1(:)  &
               + pk%XLSTT(:) *                      pek%XPSN (:)   )  
!
   WHERE(zac_agg(:)>0.0)
     zhu_agg(:) =   1. / (pek%XRESA(:) * zac_agg(:)) / pk%XLVTT(:)         &
                  * ( pk%XLVTT(:)*    pek%XVEG(:) *(1.-pek%XPSNV(:))                 *dmk%XHV(:)   &
                    + pk%XLVTT(:)*(1.-pek%XVEG(:))*(1.-pek%XPSNG(:))*(1.-pfrozen1(:))*dk%XHUG(:)  &
                    + pk%XLSTT(:)*(1.-pek%XVEG(:))*(1.-pek%XPSNG(:))*    pfrozen1(:) *phugi(:) &
                    + pk%XLSTT(:)*                     pek%XPSN  (:)                )  
   ENDWHERE
!
   zustar2_sum(:) = zustar2_sum(:) + zustar2_ic(:)
!
   zevap_sum(:) = zevap_sum(:) + zevap(:)
!
   zrn_sum(:) = zrn_sum(:) + zrn(:)
   zh_sum(:) = zh_sum(:) + zh(:)
   zgflux_sum(:) = zgflux_sum(:) + zgflux(:)
   zle_sum(:) = zle_sum(:) + zle(:)
!
   zleg_sum(:) = zleg_sum(:) + zleg(:)
   zlegi_sum(:) = zlegi_sum(:) + zlegi(:)   
   zlev_sum(:) = zlev_sum(:) + zlev(:)
   zles_sum(:) = zles_sum(:) + zles(:)
   zler_sum(:) = zler_sum(:) + zler(:)
   zletr_sum(:) = zletr_sum(:) + zletr(:)
   zle_flood_sum(:) = zle_flood_sum(:) + zle_flood(:)
   zlei_flood_sum(:) = zlei_flood_sum(:) + zlei_flood(:)   
!
   zdeep_flux_sum(:) = zdeep_flux_sum(:) + zdeep_flux(:)
   zmeltadv_sum(:) = zmeltadv_sum(:) + zmeltadv(:)
   zmelt_sum(:) = zmelt_sum(:) + zmelt(:)
   zrestore_sum(:) = zrestore_sum(:) + zrestore(:)
   zac_agg_sum(:) = zac_agg_sum(:) + zac_agg(:)
   zhu_agg_sum(:) = zhu_agg_sum(:) + zhu_agg(:)
!
!-------------------------------------------------------------------------------
!
ENDDO
!
pustar(:) = sqrt(zustar2_sum(:)/znsplit)
!
dk%XEVAP     (:) = zevap_sum(:) / znsplit
!
dk%XRN       (:) = zrn_sum(:) / znsplit
dk%XH        (:) = zh_sum(:) / znsplit
dk%XGFLUX    (:) = zgflux_sum(:) / znsplit
pek%XLE      (:) = zle_sum(:) / znsplit
!
dek%XLEG      (:) = zleg_sum(:) / znsplit
dek%XLEGI     (:) = zlegi_sum(:) / znsplit
dek%XLEV      (:) = zlev_sum(:) / znsplit
dek%XLES      (:) = zles_sum(:) / znsplit
dek%XLER      (:) = zler_sum(:) / znsplit
dek%XLETR     (:) = zletr_sum(:) / znsplit
dek%XLE_FLOOD (:) = zle_flood_sum(:) / znsplit
dek%XLEI_FLOOD(:) = zlei_flood_sum(:) / znsplit
!
pdeep_flux(:) = zdeep_flux_sum(:) / znsplit
dek%XMELTADV  (:) = zmeltadv_sum(:) / znsplit
dek%XMELT     (:) = zmelt_sum(:) / znsplit
dek%XRESTORE  (:) = zrestore_sum(:) / znsplit
pac_agg(:) = zac_agg_sum(:) / znsplit
phu_agg(:) = zhu_agg_sum(:) / znsplit
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('ISBA_CEB',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE isba_ceb