isba_budget_init.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE isba_budget_init (OWATER_BUDGET, HISBA, PEK, PDG, PDZG, &
                            PWG_INI, PWGI_INI, PWR_INI, PSWE_INI )
!     ###############################################################################
!
!!****  *ISBA_BUDGET_INIT * - initialize water and energy budget for ISBA
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2012
!!
!!------------------------------------------------------------------
!
!
USE modd_diag_evap_isba_n, ONLY : diag_evap_isba_t
USE modd_isba_n, ONLY : isba_pe_t
!
USE modd_surf_par,   ONLY : xundef
USE modd_csts,       ONLY : xrholw
!    
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
LOGICAL, INTENT(IN) :: OWATER_BUDGET
!
 CHARACTER(LEN=*),     INTENT(IN)  :: HISBA      ! type of ISBA version:
!                                               ! '2-L' (default)
!                                               ! '3-L'
!                                               ! 'DIF'
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
!
REAL, DIMENSION(:,:),  INTENT(IN) :: PDG        ! soil layer depth               (m)
REAL, DIMENSION(:,:),  INTENT(IN) :: PDZG       ! soil layer thickness           (m)
!
REAL, DIMENSION(:), INTENT(OUT)   :: PWG_INI    ! total wg at t-1                (kg m-2)
REAL, DIMENSION(:), INTENT(OUT)   :: PWGI_INI   ! total wgi at t-1               (kg m-2)
REAL, DIMENSION(:), INTENT(OUT)   :: PWR_INI    ! total wr at t-1                (kg m-2)
REAL, DIMENSION(:), INTENT(OUT)   :: PSWE_INI   ! total swe at t-1               (kg m-2)
!
!*      0.2    declarations of local variables
!
INTEGER :: INI, INL, INLS
INTEGER :: JI, JL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('ISBA_BUDGET_INIT',0,zhook_handle)
!
ini =SIZE(pek%XWG,1)
inl =SIZE(pek%XWG,2)
inls=SIZE(pek%TSNOW%WSNOW,2)
!
pwg_ini(:) = xundef
pwgi_ini(:) = xundef
pswe_ini(:) = xundef
pwr_ini(:) = xundef
!
!
! * Water budget
!   ------------
!
IF(owater_budget)THEN
!
! total wr at t-1
  pwr_ini(:)=pek%XWR(:)
!
! total swe at t-1
  pswe_ini(:)=0.0
  DO jl=1,inls
     DO ji=1,ini
        pswe_ini(ji)=pswe_ini(ji)+pek%TSNOW%WSNOW(ji,jl)
     ENDDO
  ENDDO
!
! total wg and wgi at t-1
  pwg_ini(:)= 0.0
  pwgi_ini(:)= 0.0
  IF(hisba=='DIF')THEN
    DO jl=1,inl
       DO ji=1,ini
          IF(pek%XWG(ji,jl)/=xundef)THEN
             pwg_ini(ji)=pwg_ini(ji)+pek%XWG (ji,jl)*pdzg(ji,jl)*xrholw
             pwgi_ini(ji)=pwgi_ini(ji)+pek%XWGI(ji,jl)*pdzg(ji,jl)*xrholw
          ENDIF
       ENDDO
    ENDDO
  ELSE
    pwg_ini(:)=pek%XWG (:,2)*pdg(:,2)*xrholw
    pwgi_ini(:)=pek%XWGI(:,2)*pdg(:,2)*xrholw
    IF(hisba=='3-L')THEN
      pwg_ini(:)=pwg_ini(:)+pek%XWG(:,3)*(pdg(:,3)-pdg(:,2))*xrholw
    ENDIF
  ENDIF
!
ENDIF
!
! * Energy budget
!   -------------
!
! not yet implemented
!
!
IF (lhook) CALL dr_hook('ISBA_BUDGET_INIT',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE isba_budget_init