isba_budget.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE isba_budget (IO, PK, PEK, DEK, OWATER_BUDGET, PTSTEP,&
                       PWG_INI, PWGI_INI, PWR_INI, PSWE_INI, PRAIN, PSNOW, PEVAP  )
!     ###############################################################################
!
!!****  *ISBA_BUDGET * - water and energy budget for ISBA
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2012
!!      B. Decharme    01/16 : Bug with flood budget
!!------------------------------------------------------------------
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_p_t, isba_pe_t
USE modd_diag_evap_isba_n, ONLY : diag_evap_isba_t
!
USE modd_surf_par,   ONLY : xundef
USE modd_csts,       ONLY : xrholw
!     
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_p_t), INTENT(INOUT) :: PK
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
TYPE(diag_evap_isba_t), INTENT(INOUT) :: DEK
!
LOGICAL, INTENT(IN) :: OWATER_BUDGET
!
REAL,                  INTENT(IN) :: PTSTEP     ! timestep of the integration    (s)
!
REAL, DIMENSION(:),    INTENT(IN) :: PWG_INI    ! total wg at t-1                (kg m-2)
REAL, DIMENSION(:),    INTENT(IN) :: PWGI_INI   ! total wgi at t-1               (kg m-2)
REAL, DIMENSION(:),    INTENT(IN) :: PWR_INI    ! total wr at t-1                (kg m-2)
REAL, DIMENSION(:),    INTENT(IN) :: PSWE_INI   ! total swe at t-1               (kg m-2)
!
REAL, DIMENSION(:),    INTENT(IN)  :: PRAIN     ! Rain rate                      (kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: PSNOW     ! Snow rate                      (kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: PEVAP     ! total evaporative flux         (kg/m2/s)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PEK%XWR)) :: ZINPUT
REAL, DIMENSION(SIZE(PEK%XWR)) :: ZOUTPUT
REAL, DIMENSION(SIZE(PEK%XWR)) :: ZTENDENCY
REAL, DIMENSION(SIZE(PEK%XWR)) :: ZICEFLUX
REAL, DIMENSION(SIZE(PEK%XWR)) :: ZSWE_T
REAL, DIMENSION(SIZE(PEK%XWR)) :: ZWG_T
REAL, DIMENSION(SIZE(PEK%XWR)) :: ZWGI_T
REAL, DIMENSION(SIZE(PEK%XWR)) :: ZSNDRIFT
REAL, DIMENSION(SIZE(PEK%XWR)) :: ZEFLOOD
!
INTEGER :: INI, INL, INLS
INTEGER :: JI, JL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('ISBA_BUDGET',0,zhook_handle)
!
!*      1.0    Init
!       -----------
!
ini =SIZE(pek%XWG,1)
inl =SIZE(pek%XWG,2)
inls=SIZE(pek%TSNOW%WSNOW,2)
!
dek%XDWG (:) = xundef
dek%XDWGI(:) = xundef
dek%XDWR (:) = xundef
dek%XDSWE(:) = xundef
!
IF (pek%TSNOW%SCHEME=='3-L'.OR.pek%TSNOW%SCHEME=='CRO') THEN
  zsndrift(:) = dek%XSNDRIFT(:)
ELSE
  zsndrift(:) = 0.0
ENDIF
!
!*      2.0    Comptut isba water budget in kg/m2/s
!       -------------------------------------------
!
IF(owater_budget)THEN
!
! total swe at t in kg/m2
  zswe_t(:)=0.0
  DO jl=1,inls
    DO ji=1,ini
      zswe_t(ji) = zswe_t(ji)+pek%TSNOW%WSNOW(ji,jl)
    ENDDO
  ENDDO
!
! total wg and wgi at t in kg/m2
  zwg_t(:)= 0.0
  zwgi_t(:)= 0.0
  IF(io%CISBA=='DIF')THEN
    DO jl=1,inl
      DO ji=1,ini
        IF(pek%XWG(ji,jl)/=xundef)THEN
          zwg_t(ji) = zwg_t(ji)+pek%XWG(ji,jl) *pk%XDZG(ji,jl)*xrholw
          zwgi_t(ji) = zwgi_t(ji)+pek%XWGI(ji,jl)*pk%XDZG(ji,jl)*xrholw
        ENDIF
      ENDDO
    ENDDO
  ELSE
    zwg_t(:) = pek%XWG (:,2)*pk%XDG(:,2)*xrholw
    zwgi_t(:) = pek%XWGI(:,2)*pk%XDG(:,2)*xrholw
    IF(io%CISBA=='3-L')THEN
      zwg_t(:)=zwg_t(:)+pek%XWG(:,3)*(pk%XDG(:,3)-pk%XDG(:,2))*xrholw
    ENDIF
  ENDIF
!
! Comptut reservoir time tendencies in kg/m2/s
  dek%XDWG (:) = (zwg_t(:)-pwg_ini(:))/ptstep
  dek%XDWGI(:) = (zwgi_t(:)-pwgi_ini(:))/ptstep
  dek%XDWR (:) = (pek%XWR(:)-pwr_ini(:))/ptstep
  dek%XDSWE(:) = (zswe_t(:)-pswe_ini(:))/ptstep
!
! ice calving flux if used
  IF(io%LGLACIER)THEN
    ziceflux(:)=dek%XICEFLUX(:)
  ELSE
    ziceflux(:)=0.0
  ENDIF
!
! Floodplains evaporation (kg/m2/s)
  zeflood(:) = dek%XLE_FLOOD(:)/pk%XLVTT(:)+dek%XLEI_FLOOD(:)/pk%XLSTT(:)
!
! total input water in the system at t
  zinput(:)=prain(:)+psnow(:)+dek%XIFLOOD(:)+dek%XIRRIG_FLUX(:)
!
! total output water in the system at t
  zoutput(:) = pevap(:)+dek%XDRAIN  (:)+dek%XRUNOFF (:) &
             + dek%XPFLOOD(:)+ziceflux(:)+zsndrift(:) - zeflood(:)
!
! total reservoir time tendencies at "t - (t-1)"
  ztendency(:) = dek%XDWG(:)+dek%XDWGI(:)+dek%XDWR(:)+dek%XDSWE(:)
!
! isba water budget (dw/dt=in-out) in kg/m2/s
  dek%XWATBUD(:)=ztendency(:)-(zinput(:)-zoutput(:))
!
ENDIF
!
!*      3.0    Comptut isba energy budget in W/m2
!       -----------------------------------------
!
! not yet implemented
!
IF (lhook) CALL dr_hook('ISBA_BUDGET',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE isba_budget