interpol_sbl.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE interpol_sbl( PZ, PIN, PH, POUT)
!     #####################################################################
!
!!
!!    PURPOSE
!!    -------
!     This routine do interpolation of field from canopy levels to a defined
!     height. Interpolation is linear.
!         
!     
!!**  METHOD
!!    ------
!     We search for the levels aroud the specified height of interpolation and
!     then perform a linear interpolation. If height of interpolation isn't
!     between two canopy levels, we send the value XUNDEF.
!
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!     Sebastien Riette
!!
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      Original    14/01/2010
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surf_par, ONLY : xundef
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
REAL, DIMENSION(:,:), INTENT(IN)       :: PZ     ! Height of canopy levels
REAL, DIMENSION(:,:), INTENT(IN)       :: PIN    ! Filed values on canopy levels
REAL,                 INTENT(IN)       :: PH     ! Height of interpolation
!
REAL, DIMENSION(:)  , INTENT(OUT)      :: POUT   ! Interpolated value
!
!*      0.2    declarations of local variables
!
INTEGER :: ILEVEL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
! Starting from the bottom, we look for the canopy level just below 10m and
! we interpolate linearly the canopy wind field if we're not on last level. If
! we are on last level, we do nothing and XUNDEF is left in POUT.
IF (lhook) CALL dr_hook('INTERPOL_SBL',0,zhook_handle)
pout(:) = xundef
ilevel=1

!While there are XUNDEF values and we aren't at canopy's top
DO WHILE(any(pout(:)==xundef) .AND. ilevel/=SIZE(pz,2))

  !Where interpolation is needed and possible
  !(10m is between ILEVEL and ILEVEL+1)
  WHERE(pout(:)==xundef .AND. pz(:,ilevel+1)>=10.)

    !Interpolation between ILEVEL and ILEVEL+1
    pout(:)=pin(:,ilevel) + &
              (pin(:,ilevel+1)-pin(:,ilevel)) * &
              (ph-pz(:,ilevel)) / (pz(:,ilevel+1)-pz(:,ilevel))  

  END WHERE
  ilevel=ilevel+1
END DO
IF (lhook) CALL dr_hook('INTERPOL_SBL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE interpol_sbl