init_outfn_surf_atmn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE init_outfn_surf_atm_n (DGO, UG, U, CHE, CHU, SV, HSELECT, HPROGRAM, KLUOUT)
!     ###############################
!
!
!!****  *INIT_OUTFN_SURF_ATM_n* -  create output files and defines variables
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      P. LeMoigne   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    05-04
!!      Modified 06-10 by S. Faroux
!!      modified   06-13  B. Decharme  : Add some key
!!                                       Add diag (Qs, Evap, Subl)
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_ch_emis_field_n, ONLY : ch_emis_field_t
USE modd_ch_surf_n, ONLY : ch_surf_t
USE modd_sv_n, ONLY : sv_t
!
USE modd_diag_n, ONLY : diag_options_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_ol_fileid,       ONLY : xnetcdf_fileid_out, xnetcdf_filename_out
!
!
USE modn_io_offline,      ONLY : xtstep_output
!
USE modi_get_dim_full_n
USE modi_ol_define_dim
USE modi_get_date_ol
USE modi_create_file
USE modi_ol_write_coord
USE modi_ol_write_proj
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE netcdf
!
IMPLICIT NONE
!
TYPE(diag_options_t), INTENT(INOUT) :: DGO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
TYPE(ch_emis_field_t), INTENT(INOUT) :: CHE
TYPE(ch_surf_t), INTENT(INOUT) :: CHU
TYPE(sv_t), INTENT(INOUT) :: SV
!
 CHARACTER(LEN=*),DIMENSION(:),INTENT(IN) :: HSELECT
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM
INTEGER, INTENT(IN) :: KLUOUT
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
 CHARACTER(LEN=100), DIMENSION(:), POINTER :: YNAME_DIM
 CHARACTER(LEN=100), DIMENSION(1) :: YATT_TITLE, YATT 
 CHARACTER(LEN=40),DIMENSION(1)   :: YDATE
 CHARACTER(LEN=13),DIMENSION(1)   :: YUNIT1, YUNIT2
 CHARACTER(LEN=100)               :: YCOMMENT 
 CHARACTER(LEN=50)                :: YFILE
!
REAL,DIMENSION(:), POINTER    :: ZX, ZY
REAL,DIMENSION(:), POINTER    :: ZLAT,ZLON
!
INTEGER, DIMENSION(:), POINTER   :: IDIMS, IDDIM
INTEGER                          :: IFILE_ID, IVAR_ID, IDIMID
INTEGER                          :: IDIM1, IDIM2, INDIMS
INTEGER                          :: INI, JFILE
INTEGER                          :: JRET
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------

! 1. Compute output lenght dimension
!-----------------------------------
IF (lhook) CALL dr_hook('INIT_OUTFN_SURF_ATM_N',0,zhook_handle)
!
!
 CALL get_dim_full_n(u%NDIM_FULL, ini)
!
NULLIFY(zx)
NULLIFY(zy)
!
 CALL ol_define_dim(ug, u%NSIZE_FULL, hprogram, kluout, ini, idim1, &
                    yunit1, yunit2, zx, zy, idims, iddim, yname_dim,plat=zlat,plon=zlon)
 CALL get_date_ol(u%TTIME,xtstep_output,ydate(1))
!
indims = SIZE(iddim)
!
! 4. Create output file for fraction of tiles
!--------------------------------------------
!
yatt_title(1)='units'
!
yfile='SURF_ATM.OUT.nc'
 CALL create_file(yfile,idims(1:indims-1),yname_dim(1:indims-1),ifile_id,iddim(1:indims-1))
jret=nf90_redef(ifile_id)
!
 CALL ol_write_proj(hselect,ifile_id,ug)
!
DO jfile = 1,SIZE(xnetcdf_filename_out) 
  IF (trim(yfile)==trim(xnetcdf_filename_out(jfile))) THEN
    xnetcdf_fileid_out(jfile) = ifile_id
    EXIT
  ENDIF
ENDDO
!
 CALL ol_write_coord(dgo%CSELECT,yfile,ifile_id,iddim(1:indims-1),yatt_title,yname_dim(1:indims-1),&
                     yunit1,yunit2,idim1,ydate,zx,zy,zlon,zlat)
!
!
! 5. Create output file for diagnostic variables
!-----------------------------------------------
yfile='SURF_ATM_DIAGNOSTICS.OUT.nc'
 CALL create_file(yfile,idims,yname_dim,ifile_id,iddim)
jret=nf90_redef(ifile_id)
!
 CALL ol_write_proj(hselect,ifile_id,ug)
!
DO jfile = 1,SIZE(xnetcdf_filename_out) 
  IF (trim(yfile)==trim(xnetcdf_filename_out(jfile))) THEN
    xnetcdf_fileid_out(jfile) = ifile_id
    EXIT
  ENDIF
ENDDO
!
IF (chu%LCH_EMIS .AND. sv%NBEQ>0 .AND. chu%LCH_SURF_EMIS) THEN
  !
  IF (chu%CCH_EMIS=='AGGR') jret = nf90_def_dim(ifile_id,"Temporal_emiss",che%NTIME_MAX,idimid)
  !
ENDIF
!
 CALL ol_write_coord(dgo%CSELECT,yfile,ifile_id,iddim,yatt_title,&
                    yname_dim,yunit1,yunit2,idim1,ydate,zx,zy,zlon,zlat)
!
IF (ASSOCIATED(zx)) DEALLOCATE(zx,zy)
DEALLOCATE(zlon,zlat)
!
IF (lhook) CALL dr_hook('INIT_OUTFN_SURF_ATM_N',1,zhook_handle)
!
END SUBROUTINE init_outfn_surf_atm_n