init_isban.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#############################################################
SUBROUTINE init_isba_n (DTCO, OREAD_BUDGETC, UG, U, USS, GCP, IM, DTZ,&
                        NDST, SLT, SV, HPROGRAM, HINIT, OLAND_USE,    &
                        KI, KSV, KSW, HSV, PCO2, PRHOA, PZENITH,      &
                        PAZIM, PSW_BANDS, PDIR_ALB, PSCA_ALB, PEMIS,  &
                        PTSRAD, PTSURF, KYEAR, KMONTH, KDAY, PTIME,   &
                        TPDATE_END, HATMFILE, HATMFILETYPE, HTEST      )
!#############################################################
!
!!****  *INIT_ISBA_n* - routine to initialize ISBA
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      Modified by P. Le Moigne (11/2004): miscellaneous diagnostics
!!      Modified by P. Le Moigne (06/2006): seeding and irrigation    
!!      Modified by B. Decharme    (2008) : SGH and Flooding scheme
!!      Modified by B. Decharme  (01/2009): optional deep soil temperature as in Arpege
!!      Modified by R. Hamdi     (01/2009): Cp and L
!!      Modified by B. Decharme  (06/2009): read topographic index statistics
!!      Modified by P. Le Moigne (01/2009): Beljaars sso
!!      Modified by B. Decharme  (08/2009): Active Trip coupling variable if Earth System Model
!!      A.L. Gibelin   04/09 : change BSLAI_NITRO initialisation
!!      A.L. Gibelin   04/09 : modifications for CENTURY model 
!!      A.L. Gibelin   06/09 : soil carbon initialisation
!!      B. Decharme    07/11 : read pgd+prep
!!      R. Alkama      05/12 : new carbon spinup
!!      J.Escobar      11/13 : add USE MODI_DEFAULT_CROCUS
!!      B. Decharme  04/2013 new coupling variables
!!      P. Samuelsson  10/14 : MEB
!!
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surfex_n, ONLY : isba_model_t
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
USE modd_data_tsz0_n, ONLY : data_tsz0_t
USE modd_dst_n, ONLY : dst_np_t
USE modd_slt_n, ONLY : slt_t
USE modd_sv_n, ONLY : sv_t
!
USE modd_type_date_surf, ONLY : date
!
USE modd_data_cover,     ONLY : xdata_lai, xdata_h_tree,                          &
                                xdata_albnir_veg, xdata_albvis_veg,               &
                                xdata_albuv_veg, xdata_rsmin,                     &
                                xdata_root_extinction,xdata_root_lin,             &
                                xdata_rgl, xdata_cv, xdata_gamma, xdata_gmes,     &
                                xdata_gc, xdata_bslai, xdata_sefold, xdata_laimin,&
                                xdata_dmax, xdata_stress, xdata_f2i,              &
                                xdata_veg, xdata_green, xdata_z0, xdata_z0_o_z0h, &
                                xdata_emis_eco, xdata_wrmax_cf,                   &
                                xdata_ce_nitro,xdata_cf_nitro,xdata_cna_nitro,    &
                                xdata_soilrc_so2, xdata_soilrc_o3, xdata_re25,    &
                                xdata_gmes_st, xdata_bslai_st, xdata_sefold_st,   &
                                xdata_gc_st, xdata_dmax_st
!
USE modd_write_surf_atm,  ONLY : lsplit_patch
USE modd_surf_atm,       ONLY : lcpl_gcm
USE modd_surf_par,       ONLY : xundef, nundef
USE modd_agri,           ONLY : lagrip
!
USE mode_tartes, ONLY : init_tartes
USE mode_snowcro_flanner, ONLY : read_fz06
!
USE modd_read_namelist,  ONLY : lnam_read
!
USE modd_co2v_par,  ONLY : xmco2, xspin_co2
USE modd_csts,      ONLY : xmd
!
USE modi_init_io_surf_n
!
USE modi_get_luout
USE modi_abor1_sfx
USE modi_default_isba
USE modi_default_ch_dep
USE modi_default_ch_bio_flux
USE modi_default_diag_isba
USE modi_default_crocus
USE modi_read_default_isba_n
USE modi_read_isba_conf_n
USE modi_read_prep_isba_snow
USE modi_read_prep_isba_carbon
USE modi_read_surf
USE modi_prep_ctrl_isba
USE modi_read_isba_date
USE modi_read_pgd_isba_n
USE modi_compute_isba_parameters
USE modi_read_nam_prep_isba_n
USE modi_ini_data_param
!
USE modi_set_surfex_filein
!
USE modi_end_io_surf_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
LOGICAL, INTENT(IN) :: OREAD_BUDGETC
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
TYPE(isba_model_t), INTENT(INOUT) :: IM
!
TYPE(data_tsz0_t), INTENT(INOUT) :: DTZ
TYPE(dst_np_t), INTENT(INOUT) :: NDST
TYPE(slt_t), INTENT(INOUT) :: SLT
TYPE(sv_t), INTENT(INOUT) :: SV
!
 CHARACTER(LEN=6),                 INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=3),                 INTENT(IN)  :: HINIT     ! choice of fields to initialize
LOGICAL,                          INTENT(IN)  :: OLAND_USE !
INTEGER,                          INTENT(IN)  :: KI        ! number of points
INTEGER,                          INTENT(IN)  :: KSV       ! number of scalars
INTEGER,                          INTENT(IN)  :: KSW       ! number of short-wave spectral bands
 CHARACTER(LEN=6), DIMENSION(KSV), INTENT(IN)  :: HSV       ! name of all scalar variables
REAL,             DIMENSION(KI),  INTENT(IN)  :: PCO2      ! CO2 concentration (kg/m3)
REAL,             DIMENSION(KI),  INTENT(IN)  :: PRHOA     ! air density
REAL,             DIMENSION(KI),  INTENT(IN)  :: PZENITH   ! solar zenithal angle
REAL,             DIMENSION(KI),  INTENT(IN)  :: PAZIM     ! solar azimuthal angle (rad from N, clock)
REAL,             DIMENSION(KSW), INTENT(IN)  :: PSW_BANDS ! middle wavelength of each band
REAL,             DIMENSION(KI,KSW),INTENT(OUT) :: PDIR_ALB  ! direct albedo for each band
REAL,             DIMENSION(KI,KSW),INTENT(OUT) :: PSCA_ALB  ! diffuse albedo for each band
REAL,             DIMENSION(KI),  INTENT(OUT) :: PEMIS     ! emissivity
REAL,             DIMENSION(KI),  INTENT(OUT) :: PTSRAD    ! radiative temperature
REAL,             DIMENSION(KI),  INTENT(OUT) :: PTSURF    ! surface effective temperature         (K)
!
INTEGER,                          INTENT(IN)  :: KYEAR     ! current year (UTC)
INTEGER,                          INTENT(IN)  :: KMONTH    ! current month (UTC)
INTEGER,                          INTENT(IN)  :: KDAY      ! current day (UTC)
REAL,                             INTENT(IN)  :: PTIME     ! current time since
                                                          !  midnight (UTC, s)
TYPE(date), INTENT(INOUT) :: TPDATE_END
!
 CHARACTER(LEN=28),                INTENT(IN)  :: HATMFILE    ! atmospheric file name
 CHARACTER(LEN=6),                 INTENT(IN)  :: HATMFILETYPE! atmospheric file type
 CHARACTER(LEN=2),                 INTENT(IN)  :: HTEST       ! must be equal to 'OK'
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(KI) :: ZCO2     ! CO2 concentration  (kg/m3)
REAL                :: ZSPINCO2
INTEGER             :: ISPINEND
!
INTEGER             :: ILUOUT   ! unit of output listing file
INTEGER             :: IVERSION       ! surface version
INTEGER             :: IRESP   ! return code
INTEGER             :: ISIZE_LMEB_PATCH   ! Number of patches where multi-energy balance should be applied
!
 CHARACTER(LEN=3) :: YSNOW_SCHEME
INTEGER :: ISNOW_NLAYER, JP
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!               Initialisation for IO
!
!
IF (lhook) CALL dr_hook('INIT_ISBA_N',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
IF (htest/='OK') THEN
  CALL abor1_sfx('INIT_ISBAN: FATAL ERROR DURING ARGUMENT TRANSFER')
END IF
!
!               Other little things
!
IF (lnam_read) THEN
 !
 !*       0.     Defaults
!               --------

 !        0.1. Hard defaults
 !      
 CALL default_isba(im%O%XTSTEP, im%O%XOUT_TSTEP,                                   &
                   im%O%CRUNOFF, im%O%CSCOND,                                      &
                   im%O%CC1DRY, im%O%CSOILFRZ, im%O%CDIFSFCOND, im%O%CSNOWRES,     &
                   im%O%CCPSURF, im%O%XCGMAX, im%O%XCDRAG, im%O%CKSAT, im%O%LSOC,  &
                   im%O%CRAIN, im%O%CHORT, im%O%LGLACIER, im%O%LCANOPY_DRAG,       &
                   im%O%LVEGUPD, im%O%LSPINUPCARBS, im%O%LSPINUPCARBW,             &
                   im%O%XSPINMAXS, im%O%XSPINMAXW, im%O%XCO2_START, im%O%XCO2_END, &
                   im%O%NNBYEARSPINS, im%O%NNBYEARSPINW, im%O%LNITRO_DILU     )
 !                  
 CALL default_ch_dep(im%CHI%CCH_DRY_DEP)
 CALL default_ch_bio_flux(im%CHI%LCH_BIO_FLUX)                  
 CALL default_diag_isba(im%ID%O%N2M, im%ID%O%LSURF_BUDGET, im%ID%O%L2M_MIN_ZS, im%ID%O%LRAD_BUDGET, &
                        im%ID%O%LCOEF, im%ID%O%LSURF_VARS, im%ID%DE%LSURF_EVAP_BUDGET,              &
                        im%ID%DM%LSURF_MISC_BUDGET, im%ID%DM%LSURF_DIAG_ALBEDO,                     &
                        im%ID%O%LSURF_BUDGETC, im%ID%DM%LSURF_MISC_DIF, im%ID%O%LPATCH_BUDGET,      &
                        im%ID%O%LPGD, im%ID%O%LRESET_BUDGETC, im%ID%DE%LWATER_BUDGET,               &
                        im%ID%DM%LPROSNOW,im%ID%DM%LVOLUMETRIC_SNOWLIQ,im%ID%O%XDIAG_TSTEP          )  
 !
 CALL default_crocus(im%O%LSNOWDRIFT, im%O%LSNOWDRIFT_SUBLIM, im%O%LSNOW_ABS_ZENITH, &
                     im%O%CSNOWMETAMO, im%O%CSNOWRAD)
 ! 
ENDIF
!
!        0.2. Defaults from file header
!    
 CALL read_default_isba_n(im%CHI, im%ID%DE, im%ID%O, im%ID%DM, im%O, hprogram)
!
 CALL read_isba_conf_n(im%CHI, im%ID%DE, im%ID%O, im%ID%DM, im%O, hprogram)
!
 CALL init_io_surf_n(dtco, u, hprogram,'FULL  ','ISBA  ','READ ')
 CALL read_surf(hprogram,'VERSION',iversion,iresp)
 CALL end_io_surf_n(hprogram)
!
!*       1.     Reading of configuration:
!               -------------------------
!
!* initialization of snow and carbon schemes
!
im%O%NNBYEARSOLD = 1
im%O%NSPINS      = 1
im%O%NSPINW      = 1
!
IF (hinit=='PRE') THEN 
  CALL read_prep_isba_snow(hprogram,ysnow_scheme,isnow_nlayer)
!
!* initialization of soil carbon scheme
!
  CALL read_prep_isba_carbon(hprogram,im%O%CRESPSL)
!
  IF (im%O%CRESPSL=='CNT') THEN
    im%O%NNLITTER = 2
    im%O%NNLITTLEVS = 2
    im%O%NNSOILCARB = 3
  ELSE
    im%O%NNLITTER = 0
    im%O%NNLITTLEVS = 0
    im%O%NNSOILCARB = 0
  ENDIF

ELSEIF (hinit=='ALL') THEN
  !
  CALL init_io_surf_n(dtco, u, hprogram,'NATURE','ISBA  ','READ ')
  !
  IF (iversion<6) THEN
    im%O%CRESPSL='DEF'
  ELSE  
    CALL read_surf(hprogram,'RESPSL',im%O%CRESPSL,iresp)
    CALL read_surf(hprogram,'NLITTER',im%O%NNLITTER,iresp)
    CALL read_surf(hprogram,'NLITTLEVS',im%O%NNLITTLEVS,iresp)
    CALL read_surf(hprogram,'NSOILCARB',im%O%NNSOILCARB,iresp)
    IF(iversion>=7.AND.(im%O%LSPINUPCARBS.OR.im%O%LSPINUPCARBW))THEN
      CALL read_surf(hprogram,'NBYEARSOLD',im%O%NNBYEARSOLD,iresp)
    ELSE
      im%O%NNBYEARSOLD=nundef
    ENDIF
  ENDIF
  !
  CALL end_io_surf_n(hprogram)
  !
ENDIF
!
IF (im%O%CISBA/="DIF") THEN
  im%O%NLAYER_DUN  = 2
  im%O%NLAYER_HORT = 2        
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       2.     Physiographic fields
!               --------------------
!
!
!* date
!
SELECT CASE (hinit)
  CASE ('PGD')
    im%S%TTIME%TDATE%YEAR = nundef
    im%S%TTIME%TDATE%MONTH= nundef
    im%S%TTIME%TDATE%DAY  = nundef
    im%S%TTIME%TIME       = xundef

  CASE ('PRE')
    CALL prep_ctrl_isba(im%ID%O, im%ID%DE%LSURF_EVAP_BUDGET, im%ID%DM%LSURF_MISC_BUDGET, &
                        im%ID%DM%LSURF_MISC_DIF, iluout)    
    IF (lnam_read) CALL read_nam_prep_isba_n(hprogram)                        
    CALL read_isba_date(hprogram, hinit, iluout, hatmfile, hatmfiletype, kyear, kmonth, kday, ptime, im%S%TTIME)
    tpdate_end = im%S%TTIME%TDATE

  CASE DEFAULT
    CALL init_io_surf_n(dtco, u, hprogram,'FULL  ','SURF  ','READ ')
    CALL read_surf(hprogram,'DTCUR',im%S%TTIME,iresp)
    CALL end_io_surf_n(hprogram)
END SELECT
!
!-----------------------------------------------------------------------------------------------------
! READ PGD FILE
!-----------------------------------------------------------------------------------------------------
!
! initialization for I/O
!
 CALL set_surfex_filein(hprogram,'PGD ') ! change input file name to pgd name
 CALL init_io_surf_n(dtco, u, hprogram,'NATURE','ISBA  ','READ ')
!
!
!*       2.1    Cover, soil and orographic fields:
!               ---------------------------------
!
 CALL read_pgd_isba_n(im%CHI, dtco, im%DTV, dtz, im%GB, im%G, im%ISS, im%O, im%S, im%K, &
                      ug, u, uss, gcp, sv, hprogram, oland_use, tpdate_end)
!
IF (hinit=='PRE') THEN 
  DO jp = 1,im%O%NPATCH
    im%NPE%AL(jp)%TSNOW%SCHEME = ysnow_scheme
    im%NPE%AL(jp)%TSNOW%NLAYER = isnow_nlayer
  ENDDO
ENDIF
!
isize_lmeb_patch=count(im%O%LMEB_PATCH(:))
!
!
!*       2.2    Check:
!               ------
!
IF ( im%O%CPHOTO/='NON' .AND. im%O%NPATCH/=12 .AND. im%O%NPATCH/=19 )THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CPHOTO AND NPATCH')
ENDIF
!
IF (hinit=='PRE' .AND. ysnow_scheme.NE.'3-L' .AND. ysnow_scheme.NE.'CRO' .AND. im%O%CISBA=='DIF') THEN
    CALL abor1_sfx("INIT_ISBAN: WITH CISBA = DIF, CSNOW MUST BE 3-L OR CRO")
ENDIF
IF ( im%O%CPHOTO/='NIT' .AND. im%O%CPHOTO/='NCB' .AND. lagrip) THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CPHOTO AND LAGRIP')
ENDIF
IF ( im%O%CPHOTO/='NCB' .AND. im%O%CRESPSL=='CNT') THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CPHOTO AND CRESPSL')
ENDIF
IF (hinit=='PRE' .AND. isize_lmeb_patch>0 .AND. ysnow_scheme.NE.'3-L' .AND. ysnow_scheme.NE.'CRO') THEN
    CALL abor1_sfx("INIT_ISBAN: WITH LMEB_PATCH = TRUE, CSNOW MUST BE 3-L OR CRO")
ENDIF
IF(im%O%CPHOTO/='NCB'.AND.im%O%LSPINUPCARBW)THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CPHOTO AND LSPINUPCARBW (if not NCB must be false)')
ENDIF
IF(im%O%CRESPSL/='CNT'.AND.im%O%LSPINUPCARBS)THEN
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN CRESPSL AND LSPINUPCARBS (if not CNT must be false)')
ENDIF
IF(im%O%LSPINUPCARBW.AND.REAL(im%o%nnbyearspinw)>REAL(im%o%nnbyearspins)*0.5)then
  WRITE(iluout,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(iluout,*)'INIT_ISBAN: INCONSISTENCY BETWEEN NNBYEARSPINW AND NNBYEARSPINS'
  WRITE(iluout,*)'NNBYEARSPINW MUST BE < TO 0.5 * NNBYEARSPINS'
  WRITE(iluout,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN NNBYEARSPINW AND NNBYEARSPINS')
ENDIF
IF(im%O%LSPINUPCARBS.AND.(im%O%XCO2_START==xundef.OR.im%O%XCO2_END==xundef))THEN
  WRITE(iluout,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(iluout,*)'INIT_ISBAN: INCONSISTENCY BETWEEN LSPINUPCARBS AND XCO2_START OR XCO2_END'
  WRITE(iluout,*)'FOR ISBA-CC SPINUP XCO2_START AND XCO2_END MUST BE DEFINED'
  WRITE(iluout,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  CALL abor1_sfx('INIT_ISBAN: INCONSISTENCY BETWEEN LSPINUPCARBS AND XCO2_START OR XCO2_END')
ENDIF
!
 CALL end_io_surf_n(hprogram)
 CALL set_surfex_filein(hprogram,'PREP') ! restore input file name
!
!-------------------------------------------------------------------------------
!
! During soil carbon spinup with ISBA-CC: 
!        (1) grass parameters are attributed to all agricultural PFT with atmospheric CO2 concentration 
!            fixed to Pre-industrial CO2 consentration XCO2_START
!        (2) Atmospheric CO2 concentration rampin up from XCO2_START to XCO2_END
!
ispinend=im%O%NNBYEARSPINS-nint(im%O%NNBYEARSPINS*xspin_co2)
!
im%O%LAGRI_TO_GRASS = .false.
!
IF ( im%O%LSPINUPCARBS .AND. (im%O%NNBYEARSOLD <= ispinend) ) THEN
!
   im%O%LAGRI_TO_GRASS = .true.
!
   CALL ini_data_param(ph_tree=xdata_h_tree,plai=xdata_lai,                                           &
                       palbnir_veg=xdata_albnir_veg, palbvis_veg=xdata_albvis_veg,                    &
                       palbuv_veg=xdata_albuv_veg, prsmin=xdata_rsmin,                                &
                       prgl=xdata_rgl, pcv=xdata_cv, pgamma=xdata_gamma,                              &
                       pgmes=xdata_gmes, pgc=xdata_gc, pbslai=xdata_bslai,                            &
                       psefold=xdata_sefold, plaimin_out=xdata_laimin, pdmax=xdata_dmax,              &
                       pstress=xdata_stress, pf2i=xdata_f2i, pveg_out=xdata_veg,                      &
                       pgreen=xdata_green, pz0=xdata_z0, pz0_o_z0h=xdata_z0_o_z0h,                    &
                       pemis_eco=xdata_emis_eco, pwrmax_cf=xdata_wrmax_cf,                            &
                       proot_lin=xdata_root_lin, proot_extinction=xdata_root_extinction,              &
                       psoilrc_so2=xdata_soilrc_so2, psoilrc_o3=xdata_soilrc_o3, pre25=xdata_re25,    &
                       pce_nitro=xdata_ce_nitro,pcf_nitro=xdata_cf_nitro,pcna_nitro=xdata_cna_nitro,  &
                       pgmes_st=xdata_gmes_st, pgc_st=xdata_gc_st, pbslai_st=xdata_bslai_st,          &
                       psefold_st=xdata_sefold_st, pdmax_st=xdata_dmax_st, oagri_to_grass=im%O%LAGRI_TO_GRASS)
!
   zco2(:) = prhoa(:) * im%O%XCO2_START * 1.e-6 * xmco2 / xmd
!
ELSEIF(im%O%LSPINUPCARBS .AND. (im%O%NNBYEARSOLD > ispinend) .AND. (im%O%NNBYEARSOLD <= im%O%NNBYEARSPINS) )THEN
!
   zspinco2 = im%O%XCO2_START + (im%O%XCO2_END-im%O%XCO2_START) * REAL(IM%O%NNBYEARSOLD - ISPINEND) / &
                REAL(im%o%nnbyearspins - ispinend)
!
   zco2(:) = prhoa(:) * zspinco2 * 1.e-6 * xmco2 / xmd
!
ELSE
!
   zco2(:) = pco2(:)
!
ENDIF
!
!-----------------------------------------------------------------------------------------------------
! END READ PGD FILE
!-----------------------------------------------------------------------------------------------------
!
!-----------------------------------------------------------------------------------------------------
! Make sure some diags are conputed when coupled with atmosphere
!-----------------------------------------------------------------------------------------------------
!
IF(lcpl_gcm.AND.im%ID%O%LSURF_BUDGET) THEN
  im%ID%DE%LSURF_EVAP_BUDGET=.true.
ENDIF
!
!-----------------------------------------------------------------------------------------------------
!
IF (oland_use .OR. hinit=='PGD') THEN
  IF (lhook) CALL dr_hook('INIT_ISBA_N',1,zhook_handle)
  RETURN
END IF
!
 CALL compute_isba_parameters(dtco, oread_budgetc, ug, u,                    &
                             im%O, im%DTV, im%SB, im%S, im%G, im%K, im%NK,  &
                             im%NG, im%NP, im%NPE, im%NAG, im%NISS, im%ISS, &
                             im%NCHI, im%CHI, im%ID, im%GB, im%NGB,         &
                             ndst, slt, sv, hprogram,hinit,oland_use,       &
                             ki,ksv,ksw, hsv,zco2,prhoa,                &
                             pzenith,psw_bands,pdir_alb,psca_alb,       &
                             pemis,ptsrad,ptsurf,htest                  )
!
IF ( im%O%CSNOWMETAMO/="B92" ) THEN
  CALL read_fz06('drdt_bst_fit_60.nc')
ENDIF
!
IF ( im%O%CSNOWRAD=="TAR" .OR. im%O%CSNOWRAD=="TA1" .OR.  im%O%CSNOWRAD=="TA2" ) THEN
  CALL init_tartes()
END IF
!
IF (hinit=='ALL') THEN 
  ysnow_scheme = im%NPE%AL(1)%TSNOW%SCHEME
  isnow_nlayer = im%NPE%AL(1)%TSNOW%NLAYER
ENDIF
!
IF (.NOT.lsplit_patch) THEN

  ALLOCATE(im%S%XWORK_WR(ki,im%O%NPATCH))
  im%S%XWORK_WR(:,:) = xundef

  ALLOCATE(im%S%XWSN_WR(ki,isnow_nlayer,im%O%NPATCH))
  ALLOCATE(im%S%XRHO_WR(ki,isnow_nlayer,im%O%NPATCH))
  ALLOCATE(im%S%XALB_WR(ki,im%O%NPATCH))
  IF (ysnow_scheme=='3-L' .OR. ysnow_scheme=='CRO') THEN
    ALLOCATE(im%S%XHEA_WR(ki,isnow_nlayer,im%O%NPATCH))
    ALLOCATE(im%S%XAGE_WR(ki,isnow_nlayer,im%O%NPATCH))
    IF (ysnow_scheme=='CRO') THEN
      ALLOCATE(im%S%XSG1_WR(ki,isnow_nlayer,im%O%NPATCH))
      ALLOCATE(im%S%XSG2_WR(ki,isnow_nlayer,im%O%NPATCH))
      ALLOCATE(im%S%XHIS_WR(ki,isnow_nlayer,im%O%NPATCH))
    ELSE
      ALLOCATE(im%S%XSG1_WR(0,0,1))
      ALLOCATE(im%S%XSG2_WR(0,0,1)) 
      ALLOCATE(im%S%XHIS_WR(0,0,1))   
    ENDIF
  ELSE
    ALLOCATE(im%S%XHEA_WR(0,0,1))
    ALLOCATE(im%S%XAGE_WR(0,0,1))
  ENDIF

  ALLOCATE(im%S%TDATE_WR(ki,im%O%NPATCH))

ELSE

  ALLOCATE(im%S%XWORK_WR(0,1))

  ALLOCATE(im%S%XWSN_WR(0,0,1))
  ALLOCATE(im%S%XRHO_WR(0,0,1))
  ALLOCATE(im%S%XALB_WR(0,1))
  ALLOCATE(im%S%XHEA_WR(0,0,1))
  ALLOCATE(im%S%XAGE_WR(0,0,1))
  ALLOCATE(im%S%XSG1_WR(0,0,1))
  ALLOCATE(im%S%XSG2_WR(0,0,1)) 
  ALLOCATE(im%S%XHIS_WR(0,0,1))

  ALLOCATE(im%S%TDATE_WR(0,1))

ENDIF
!
IF (lhook) CALL dr_hook('INIT_ISBA_N',1,zhook_handle)
!
END SUBROUTINE init_isba_n