init_io_surf_ascn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE init_io_surf_asc_n (DTCO, U, HMASK,HACTION)
!     ######################
!
!!****  *INIT_IO_SURF_ASC* Keep in memory the output files
!!
!!    PURPOSE
!!    -------
!
!!
!!**  IMPLICIT ARGUMENTS
!!    ------------------
!!      None 
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      P. Le Moigne 04/2004: distinguish in and out file name
!!      P. Le Moigne 04/2006: special HACTION='GTMSK' to initialize
!!                            a mask different of 'FULL ' in order 
!!                            to read dimensions only.
!!      S. Faroux 06/2012 : implementations for MPI
!
!*       0.   DECLARATIONS
!             ------------
!
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surfex_mpi, ONLY : nrank, nindex, nsize, npio
!
USE modd_io_surf_asc,ONLY: nunit,cfilein,cfileout,nmask,nluout,nfull,cmask, &
                           lcreated,cfile
!
USE modi_get_luout
USE modi_read_surf
USE modi_get_dim_full_n
USE modi_get_size_full_n
USE modi_get_type_dim_n
USE modi_init_io_surf_mask_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HMASK    
 CHARACTER(LEN=5),  INTENT(IN)  :: HACTION    
!
INTEGER                        :: ILU,IRET, IL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('INIT_IO_SURF_ASC_N',0,zhook_handle)
!
 CALL get_luout('ASCII ',nluout)
!
nunit=20
!
IF (haction=='GTMSK') THEN
  IF (nrank==npio) THEN
    OPEN(unit=nunit,file=cfilein,form='FORMATTED')
  ENDIF
  cmask = hmask
  cfile = cfilein
  IF (lhook) CALL dr_hook('INIT_IO_SURF_ASC_N',1,zhook_handle)
  RETURN
ENDIF
!
IF (haction == 'READ ') THEN
  OPEN(unit=nunit,file=cfilein,form='FORMATTED')
  ! NFULL must be known even if HMASK/=FULL because it's no longer 
  ! updated in init_io_surf_maskn.
  cmask = 'FULL ' 
  CALL read_surf(&
                 'ASCII ','DIM_FULL',nfull,iret,hdir='A')
  cmask = hmask
  cfile = cfilein
ELSE
  IF (nrank==npio) THEN
    IF (lcreated) THEN
      OPEN(unit=nunit,file=cfileout,form='FORMATTED',position='APPEND')
    ELSE
      OPEN(unit=nunit,file=cfileout,form='FORMATTED')
      lcreated=.true.
    ENDIF
  ENDIF
  ! NFULL must be known in every case. 
  CALL get_dim_full_n(u%NDIM_FULL, nfull)
  cmask = hmask
  cfile = cfileout
ENDIF
!
! nindex is needed for call to get_size_full_n. In init_index_mpi, 
! it's not initialized for first readings.  
IF (.NOT.ALLOCATED(nindex) .AND. nrank==npio) THEN
  ALLOCATE(nindex(nfull))
  nindex(:) = 0
ELSE
  CALL get_dim_full_n(u%NDIM_FULL,nfull)  
ENDIF
!
!------------------------------------------------------------------------------
!
! MASK is sized according to the mpi task running
 CALL get_size_full_n('ASCII ',nfull,u%NSIZE_FULL,ilu)
IF (ilu>nsize) nsize = ilu
!
il = ilu
 CALL get_type_dim_n(dtco, u,hmask,il)
 CALL init_io_surf_mask_n(dtco, u, hmask, il, nluout, ilu, nmask)
!
!
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('INIT_IO_SURF_ASC_N',1,zhook_handle)
!------------------------------------------------------------------------------
END SUBROUTINE init_io_surf_asc_n