init_bemn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #############################################################
      SUBROUTINE init_bem_n ( DTCO, TOP, BOP, DTT, DTB, BDD, G, &
                              T, B, KLUOUT)
!     #############################################################
!
!!****  *INIT_BEM_n* - routine to initialize Building Energy Model
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      G. Pigeon   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    04/2012
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
!
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_bem_option_n, ONLY : bem_options_t
USE modd_data_teb_n, ONLY : data_teb_t
USE modd_data_bem_n, ONLY : data_bem_t
USE modd_bld_description_n, ONLY : bld_desc_t
USE modd_sfx_grid_n, ONLY : grid_t 
USE modd_teb_n, ONLY : teb_t
USE modd_bem_n, ONLY : bem_t
!
USE modi_convert_patch_teb
USE modi_window_data
USE modi_hvac_autosize
USE modi_bem_morpho
USE modi_stores_hvac_autosize
!
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(teb_options_t), INTENT(INOUT) :: TOP
TYPE(bem_options_t), INTENT(INOUT) :: BOP
TYPE(data_teb_t), INTENT(INOUT) :: DTT
TYPE(data_bem_t), INTENT(INOUT) :: DTB
TYPE(bld_desc_t), INTENT(INOUT) :: BDD
TYPE(grid_t), INTENT(INOUT) :: G
TYPE(teb_t), INTENT(INOUT) :: T
TYPE(bem_t), INTENT(INOUT) :: B
!
INTEGER, INTENT(IN) :: KLUOUT ! logical unit of output listing
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER                         :: JJ               ! counter
INTEGER                         :: ILU              ! sizes of TEB arrays
LOGICAL                         :: GPRINT           ! flag for warning prints in output file
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!         Initialisation for IO
!

IF (lhook) CALL dr_hook('INIT_BEM_N',0,zhook_handle)
!
!
!*       3.     Physiographic data fields from land cover:
!               -----------------------------------------
!
ilu = SIZE(top%XCOVER,1)
IF (top%CBEM=='DEF') ilu=0
!
ALLOCATE(b%XHC_FLOOR    (ilu,bop%NFLOOR_LAYER))
ALLOCATE(b%XTC_FLOOR    (ilu,bop%NFLOOR_LAYER))
ALLOCATE(b%XD_FLOOR     (ilu,bop%NFLOOR_LAYER))
!
ALLOCATE(b%XTCOOL_TARGET(ilu))
ALLOCATE(b%XTHEAT_TARGET(ilu))
ALLOCATE(b%XEFF_HEAT    (ilu))
ALLOCATE(b%XSHGC        (ilu))
ALLOCATE(b%XQIN         (ilu))
ALLOCATE(b%XQIN_FRAD    (ilu))
ALLOCATE(b%XSHGC_SH     (ilu))
ALLOCATE(b%XU_WIN       (ilu))
ALLOCATE(b%XTRAN_WIN    (ilu))
ALLOCATE(b%XFLOOR_HEIGHT(ilu))
ALLOCATE(b%XINF         (ilu))
!
ALLOCATE(b%XQIN_FLAT    (ilu))
ALLOCATE(b%XHR_TARGET   (ilu))
ALLOCATE(b%XV_VENT      (ilu))
ALLOCATE(b%XCAP_SYS_HEAT(ilu))
ALLOCATE(b%XCAP_SYS_RAT (ilu))
ALLOCATE(b%XT_ADP       (ilu))
ALLOCATE(b%XM_SYS_RAT   (ilu))
ALLOCATE(b%XCOP_RAT     (ilu))
ALLOCATE(b%XT_SIZE_MAX  (ilu))
ALLOCATE(b%XT_SIZE_MIN  (ilu))
ALLOCATE(b%XF_WATER_COND(ilu))
ALLOCATE(b%CNATVENT     (ilu))
ALLOCATE(b%XNATVENT     (ilu))
!
ALLOCATE(b%XABS_WIN (ilu))
ALLOCATE(b%XUGG_WIN (ilu))
ALLOCATE(b%LSHADE   (ilu))
ALLOCATE(b%XSHADE   (ilu))
ALLOCATE(b%LSHAD_DAY(ilu))
ALLOCATE(b%LNATVENT_NIGHT(ilu))
ALLOCATE(b%XAUX_MAX    (ilu))
ALLOCATE(b%XN_FLOOR(ilu))
ALLOCATE(b%XGLAZ_O_BLD(ilu))
ALLOCATE(b%XMASS_O_BLD(ilu))
ALLOCATE(b%XFLOOR_HW_RATIO(ilu))
ALLOCATE(b%XF_FLOOR_MASS(ilu))
ALLOCATE(b%XF_FLOOR_WALL(ilu))
ALLOCATE(b%XF_FLOOR_WIN(ilu))
ALLOCATE(b%XF_FLOOR_ROOF(ilu))
ALLOCATE(b%XF_WALL_FLOOR(ilu))
ALLOCATE(b%XF_WALL_MASS(ilu))
ALLOCATE(b%XF_WALL_WIN(ilu))
ALLOCATE(b%XF_WIN_FLOOR(ilu))
ALLOCATE(b%XF_WIN_MASS(ilu))
ALLOCATE(b%XF_WIN_WALL(ilu))
ALLOCATE(b%XF_WIN_WIN(ilu))
ALLOCATE(b%XF_MASS_FLOOR(ilu))
ALLOCATE(b%XF_MASS_WALL(ilu))
ALLOCATE(b%XF_MASS_WIN(ilu))

SELECT CASE(top%CBEM)
!----------
CASE("DEF")
!-----------
   !parameters that needs to be 0 for calculation
   b%XGR  (:)         = 0.
   b%XF_WASTE_CAN(:)  = 0.
!----------
CASE("BEM")
!----------

  b%XAUX_MAX(:) = 5.
  CALL convert_patch_teb(bdd, dtb, dtco, dtt, top, 0., b = b  )
   !
   !
   ! *.     indoor relative surf. and view factors
   !        --------------------------------------
   !
   CALL bem_morpho(t%XBLD, t%XWALL_O_HOR, t%XBLD_HEIGHT, &
                   t%XWALL_O_BLD, b     )
   !
   ! *.     Window optical and thermal data
   !        -------------------------------
   !
   CALL window_data(ilu, b )
   gprint = .false.
   DO jj=1,SIZE(b%XSHADE)
      IF (b%XSHADE(jj) >= 0.0 .AND. b%XSHADE(jj) < 0.5) THEN
         b%LSHADE(jj) = .false.
      ELSEIF (b%XSHADE(jj) >= 0.5 .AND. b%XSHADE(jj) <= 1.0) THEN
         b%LSHADE(jj) = .true.
      ELSE
       gprint = .true.
       b%LSHADE(jj) = .false.
      ENDIF
   ENDDO
   IF (gprint) WRITE(kluout,*) &
   'TEB-BEM : Error in specifying shading devices for at least one point, no shading device for these points'
   b%LSHAD_DAY(:) = .false.
   !
   ! *.     Nocturnal surventilation
   !        ------------------------
   gprint = .false.
   DO jj=1,SIZE(b%XNATVENT)
      IF (b%XNATVENT(jj) >= 0.0 .AND. b%XNATVENT(jj) < 0.5) THEN
        b%CNATVENT(jj) = 'NONE'
      ELSEIF (b%XNATVENT(jj) >= 0.5 .AND. b%XNATVENT(jj) < 1.5) THEN
        b%CNATVENT(jj) = 'MANU'
      ELSEIF (b%XNATVENT(jj) >= 1.5 .AND. b%XNATVENT(jj) <= 2.5) THEN
        b%CNATVENT(jj) = 'AUTO'        
      ELSEIF (b%XNATVENT(jj) >= 2.5 .AND. b%XNATVENT(jj) <= 3.5) THEN
        b%CNATVENT(jj) = 'MECH'        
      ELSE
        gprint = .true.
        b%CNATVENT(jj) = 'NONE'        
      ENDIF
    ENDDO
    IF (gprint) WRITE(kluout,*) 'TEB-BEM : Chosen option for surventilation is not yet implemented; None venting is kept instead'

   b%LNATVENT_NIGHT(:) = .false.
   !
END SELECT
!
!-------------------------------------------------------------------------------
!
!*       8.     Building HVAC automatic sizing:
!               -------------------------------  
IF (top%CBEM=='BEM' .AND. bop%LAUTOSIZE) THEN
  CALL hvac_autosize(b, bop, g, t, top, ilu,kluout)
  !* stores the real systems characteristics in physiographic data 
  !  for further use
  CALL stores_hvac_autosize(b, bop, dtb)
ENDIF
!
!-------------------------------------------------------------------------------
!
!
IF (lhook) CALL dr_hook('INIT_BEM_N',1,zhook_handle)
!
!
END SUBROUTINE init_bem_n