hydro_soil.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE hydro_soil(IO, KK, PK, PEK, DMK, PTSTEP,  &
                            PLETR, PLEG, PPG, PEVAPCOR, PD_G3, &
                            PWSAT, PWFC, PDWGI1, PDWGI2, PLEGI,&
                            PWG3, PRUNOFF, PDRAIN, PWWILT )  
!     #####################################################################
!
!!****  *HYDRO_SOIL*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the evolution of the water variables, i.e., the superficial
!     and deep-soil volumetric water content (wg and w2), the equivalent
!     liquid water retained in the vegetation canopy (Wr), the equivalent
!     water of the snow canopy (Ws), and also of the albedo and density of
!     the snow (i.e., ALBS and RHOS).  Also determine the runoff and drainage
!     into the soil.
!         
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!    Noilhan and Planton (1989)
!!    Belair (1995)
!!      
!!    AUTHOR
!!    ------
!!
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      Original    14/03/95 
!!                  31/08/98 (V. Masson and F. Habets) add Dumenil et Todini
!!                           runoff scheme
!!                  31/08/98 (V. Masson and A. Boone) add the third soil-water
!!                           reservoir (WG3,D3)
!!                  15/03/99 A. Boone soil ice modification: advance
!!                           soil ice and liquid water, do budget checks
!!                  25/01/00 A. Boone : fully implicit method for WG2, WG3
!!                  05/03/07 A. Boone : changed drainage diagnostic computation for
!!                                      single bulk-soil option...i.e. for
!!                                      cases when IO%CISBA=2-L or d2>=d3 (IO%CISBA=3-L)
!!                                      for tighter water budget closure 
!!                  07/08/12 B. Decharme : Soil ice energy conservation
!!                     04/13 B. Decharme : Apply physical limits on wg here instead of in hydro.F90
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_k_t, isba_p_t, isba_pe_t
USE modd_diag_misc_isba_n, ONLY : diag_misc_isba_t
!
USE modd_csts,     ONLY : xlvtt, xrholw, xlmtt, xlstt, xday
USE modd_isba_par, ONLY : xwgmin
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_k_t), INTENT(INOUT) :: KK
TYPE(isba_p_t), INTENT(INOUT) :: PK
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
TYPE(diag_misc_isba_t), INTENT(INOUT) :: DMK
!
REAL, INTENT(IN)                  :: PTSTEP
!                                      timestep of the integration (s)
!
REAL, DIMENSION(:), INTENT(IN)    :: PLETR, PLEG, PPG, PEVAPCOR
!                                      PLETR    = evapotranspiration of the vegetation (W m-2)
!                                      PLEG     = latent heat of evaporation over the ground (W m-2)
!                                      PPG      = total water reaching the ground (kg m-2 s-1)
!                                      PEVAPCOR = correction for any excess evaporation 
!                                                from snow as it completely ablates (kg m-2 s-1)
!
REAL, DIMENSION(:), INTENT(IN)    :: PD_G3, PWSAT, PWFC
!                                      PD_G3 = depth of the soil column (m)
!                                      PWSAT = saturation volumetric water content
!                                              of the soil (m3 m-3)
!                                      PWFC  = field capacity volumetric water
!                                              content (m3 m-3)
!
REAL, DIMENSION(:), INTENT(IN)    :: PDWGI1, PDWGI2, PLEGI
!                                      PDWGI1 = surface layer liquid water equivalent 
!                                               volumetric ice content time tendency (m3 m-3)
!                                      PDWGI2 = deep-soil layer liquid water equivalent  
!                                               volumetric ice content time tendency  (m3 m-3)
!                                      PLEGI  = surface soil ice sublimation (W m-2)
!
REAL, DIMENSION(:), INTENT(INOUT) :: PWG3
!                                      PWG3   = bulk deep-soil moisture at 't+dt' (m3 m-3)
!
REAL, DIMENSION(:), INTENT(OUT)   :: PRUNOFF, PDRAIN
!                                      PRUNOFF = runoff (kg m-2 s-1)
!                                      PDRAIN  = drainage (kg m-2 s-1)
!
REAL, DIMENSION(:), INTENT(IN)    :: PWWILT
!                                    PWWILT = wilting point volumetric water
!                                             content (m3 m-3)
!*      0.2    declarations of local variables
!
!
REAL, DIMENSION(SIZE(PEK%XTG,1))   :: ZWGI1M, ZWG2M, ZWG3M, ZWGI2M
!                                      Prognostic variables of ISBA at 't-dt'
!                                      ZWG2M = root-soil volumetric water content
!                                      ZWG3M = deep-soil volumetric water content
!                                      ZWGI1M = surface-soil volumetric ice content
!                                      ZWGI2M = deep-soil volumetric ice content
!
REAL, DIMENSION(SIZE(PEK%XTG,1))   :: ZETR, ZEG
!                                             ZETR = evapotranspiration rate
!                                             ZEG = evaporation rate from the ground
!
! 
REAL, DIMENSION(SIZE(PEK%XTG,1))   :: ZWSAT, ZWFC
!                                             ZWSAT = Wsat  when ice is present
!                                             ZWFC  = Wfc   when ice is present
!
REAL, DIMENSION(SIZE(PWG3))  :: ZC4
REAL, DIMENSION(SIZE(PWG3))  :: ZWAVG, ZSINK2,                                    &
                                  ZFACTOR, ZDRAINCF2, ZDRAINCF3, ZDRAIN2,           &
                                  ZDELTA2, ZDELTA3, ZDELTA22, ZDELTA33,             &
                                  ZWDRAIN2, ZWDRAIN3  
!
REAL, DIMENSION(SIZE(PWG3))  :: ZEXCESSF, ZA2, ZB2, ZC2, ZA3, ZB3, ZC3, ZWDRAIN, ZEXCESSFC
!
REAL, DIMENSION(SIZE(PWG3))  :: ZWLIM2, ZWLIM3, ZWWILT
!
INTEGER                 :: JJ
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*       0.     Initialization
!               --------------
!
!
IF (lhook) CALL dr_hook('HYDRO_SOIL',0,zhook_handle)
zwsat(:)     = 0.
zwfc(:)      = 0.
zwwilt(:)    = 0.
!
pdrain(:)   = 0.
prunoff(:)   = 0.
!
zdrain2(:)   = 0.
zdraincf2(:) = 0.
zdraincf3(:) = 0.
zdelta2(:)   = 0.0
zdelta3(:)   = 0.0
zdelta22(:)  = 0.0
zdelta33(:)  = 0.0
zsink2(:)    = 0.
zwdrain(:)   = 0.0
zwdrain2(:)  = 0.0
zwdrain3(:)  = 0.0
za2(:)       = 0.0
zb2(:)       = 0.0
zc2(:)       = 0.0
za3(:)       = 0.0
zb3(:)       = 0.0
zc3(:)       = 0.0
!
zexcessf(:)  = 0.0
!
! Fields at time t-dt
!
zwg2m(:)     = pek%XWG(:,2)
zwg3m(:)     = pwg3(:)
zwgi1m(:)    = pek%XWGI(:,1)
zwgi2m(:)    = pek%XWGI(:,2)

!-------------------------------------------------------------------------------
!
DO jj=1,SIZE(pek%XTG,1)
!
!*       1.     New Wsat
!               --------
!
  zwsat(jj) = pwsat(jj) - zwgi2m(jj)      ! per definition ZWGI2M<PWSAT-0.001
!                                             ! then ZWSAT>0.001
!
  zwfc(jj)   = pwfc(jj)   * zwsat(jj) / pwsat(jj)
!
  zwwilt(jj) = pwwilt(jj) * zwsat(jj) / pwsat(jj)
!
!
!                                           evaporation rates
!
  zetr(jj) = pletr(jj) / xlvtt
!
! Remove sublimation from total soil evaporation: this is done
! because ZEG is a liquid water sink term. Sublimation
! is removed from the surface ice tendency equation (below):
! PLEG represents the total of sublimation and evaporation.
! Also, add an additional possible correction which is used if
! evaporation from the snow surface exceeds the last amount of
! snow on the surface as the snow completely ablates (this
! is a very small term and is generally negligible HOWEVER
! it is retained here for a high order water budget):
!
  zeg(jj)  = pleg(jj) / xlvtt + pevapcor(jj)
!
!-------------------------------------------------------------------------------
!
!*       4.     EVOLUTION OF THE SUPERFICIAL WATER CONTENT WG1
!               ----------------------------------------------
!
!                                           updated values for wg 
!
  pek%XWG(jj,1) = (pek%XWG(jj,1) - ptstep * &
            (dmk%XC1(jj)*(zeg(jj)-ppg(jj))/xrholw - dmk%XC2(jj)*dmk%XWGEQ(jj)/xday)) &
              / (1. + ptstep * dmk%XC2(jj) / xday)  
!
!
ENDDO
!
IF(io%CKSAT=='SGH' .OR. io%CKSAT=='EXP') THEN
  zwlim2(:)=zwwilt(:)
  zwlim3(:)=pwwilt(:)
ELSE
  zwlim2(:)=xwgmin
  zwlim3(:)=xwgmin
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       5.     EVOLUTION OF THE DEEP WATER CONTENT WG2 and WG3
!               -----------------------------------------------
!
!*       5.1    2-L ISBA version
!               ----------------
!
IF (io%CISBA=='2-L') THEN
! 
  DO jj=1,SIZE(pek%XTG,1)
!
    pek%XWG(jj,2) = zwg2m(jj) - ptstep*(zeg(jj) + zetr(jj) - ppg(jj)) / (pk%XDG(jj,2) * xrholw)  
!
!*       6.     DRAINAGE FROM THE DEEP SOIL
!               ------------------
!
    zwdrain(jj)   = kk%XWDRAIN(jj) * &
            max(0.0, min(zwfc(jj),pek%XWG(jj,2))-zwlim2(jj))/(zwfc(jj)-zwlim2(jj))

    zdrain2(jj)   =  max( min(zwdrain(jj),pek%XWG(jj,2)) , &
               pek%XWG(jj,2)-zwfc(jj) )*pk%XC3(jj,1) / (pk%XDG(jj,2)*xday) * ptstep  
!
!                                      the deep-soil volumetric water content w2
!                                      is modified consequently
!
    pek%XWG(jj,2)    = pek%XWG(jj,2) - zdrain2(jj)

    pdrain(jj)  = zdrain2(jj)*pk%XDG(jj,2)*xrholw/ptstep  ! Final output units: kg m-2 s-1
!
  ENDDO
!
ELSE
!
  DO jj=1,SIZE(pek%XTG,1)

!*       5.2    3-L ISBA version (with only 2 active layers)
!               ----------------
!
    IF (pk%XDG(jj,2) >= pd_g3(jj)) THEN

      pek%XWG(jj,2) = zwg2m(jj) - ptstep*(zeg(jj) + zetr(jj) - ppg(jj))   &
                    / (pk%XDG(jj,2) * xrholw)  

!*       6.     DRAINAGE FROM THE DEEP SOIL
!               ------------------
!                                      when w2 > wfc, there is drainage
!
      zwdrain(jj) = kk%XWDRAIN(jj) * &
              max(0.0, min(zwfc(jj),pek%XWG(jj,2))-zwlim2(jj))/(zwfc(jj)-zwlim2(jj))

      zdrain2(jj) = max( min(zwdrain(jj),pek%XWG(jj,2)) , &
              pek%XWG(jj,2)-zwfc(jj) )*pk%XC3(jj,1) / (pk%XDG(jj,2)*xday) * ptstep  

      pek%XWG(jj,2)    = pek%XWG(jj,2) -  zdrain2(jj)
      pwg3(jj)    = pek%XWG(jj,2)

      pdrain(jj)  = zdrain2(jj)*pk%XDG(jj,2)*xrholw/ptstep  ! Final output units: kg m-2 s-1
!
    ELSE
!
!*       5.3    3-L ISBA version (with 3 active layers)
!               ----------------
!
! Linear drainage term check (m3 m-3):
! Use a linear scaling to prevent it from completely drying out the soil. This
! term will, under most conditions, not result in such a drying. Until a more
! rhobust (but more complicated) method is developed for maintaining a minimum river
! flow under dry conditions, this method will be used.
!
      zwdrain2(jj) = kk%XWDRAIN(jj)* max(0.0, min(zwfc(jj),zwg2m(jj))-zwlim2(jj))/(zwfc(jj)-zwlim2(jj))
      zwdrain3(jj) = kk%XWDRAIN(jj)* max(0.0, min(pwfc(jj),zwg3m(jj))-zwlim3(jj))/(pwfc(jj)-zwlim3(jj))
!
! Delta functions:
!
      zdelta2(jj)    = 0.0
      IF ( zwg2m(jj) - zwfc(jj) > zwdrain2(jj) ) zdelta2(jj) = 1.0
  !
      zdelta3(jj)    = 0.0
      IF ( zwg3m(jj) - pwfc(jj) > zwdrain3(jj) ) zdelta3(jj) = 1.0
  !
  !

! evaluate inter-facial water content, grid factor, and diffusion coefficient:

      zwavg(jj)     = ( ( (zwg2m(jj)**6)* pk%XDG(jj,2)          +                       &
                           (zwg3m(jj)**6)*(pd_g3(jj)-pk%XDG(jj,2)) )/pd_g3(jj) )**(1./6.)  

      zfactor(jj)   = pk%XDG(jj,2)/(pd_g3(jj)-pk%XDG(jj,2))

      zc4(jj)   = pk%XC4REF(jj)*(zwavg(jj)**kk%XC4B(jj))                &
                     *(10.**(-kk%XC4B(jj)*pek%XWGI(jj,2)/(pwsat(jj)-xwgmin)))  
!
! calculate sources/sinks
!
      zsink2(jj)   = -(zeg(jj) + zetr(jj) - ppg(jj) )/(pk%XDG(jj,2)*xrholw)

! Compute evolution of water content using linearized equations
! (see Boone 2000, Appendix F.2 for details)
!
! sink terms are treated explicitly, other terms are implicit
!
      zdraincf2(jj) = pk%XC3(jj,1) / (pk%XDG(jj,2) * xday)
      zdelta22(jj)  = zdelta2(jj)*zwfc(jj) - (1.0-zdelta2(jj))*zwdrain2(jj)
      zc2(jj)       = 1.0 + ptstep*(zdelta2(jj)*zdraincf2(jj) + (zc4(jj)/xday)) 
      zb2(jj)       = ptstep*zc4(jj)/(xday*zc2(jj))
      za2(jj)       = ( zwg2m(jj) + ptstep*(zsink2(jj) + zdraincf2(jj)*zdelta22(jj)) )/zc2(jj)
!
      zdraincf3(jj) = pk%XC3(jj,2) / ( (pd_g3(jj)-pk%XDG(jj,2)) * xday)
      zdelta33(jj)  = zdelta3(jj)*pwfc(jj) - (1.0-zdelta3(jj))*zwdrain3(jj)
      zc3(jj)       = 1.0 + ptstep*(zdelta3(jj)*zdraincf3(jj) + zfactor(jj)*(zc4(jj)/xday)) 
      zb3(jj)       = ptstep*zfactor(jj)*(zdelta2(jj)*zdraincf2(jj) + (zc4(jj)/xday) )/zc3(jj)
      za3(jj)       = ( zwg3m(jj) + ptstep*(                                                 &
                         - zfactor(jj)*zdraincf2(jj)*zdelta22(jj)                            &
                          +            zdraincf3(jj)*zdelta33(jj)) )/zc3(jj)  
!
! Advance volumetric water content values in time:
! system of 2 linear equations:
!
      pek%XWG(jj,2) = ( za2(jj)+zb2(jj)*za3(jj) )/(1.0 - zb2(jj)*zb3(jj))
      pwg3(jj)       = za3(jj) + zb3(jj)*pek%XWG(jj,2)
!
! Drainage (kg m-2 s-1): this term is implicit and is extracted directly from
!                        the drainage computation in the above equations.
!
      zwdrain(jj)   = (xrholw*pk%XC3(jj,2)/xday)*                                                 &
                       ( zdelta3(jj)*(pwg3(jj)-pwfc(jj)) + (1.0-zdelta3(jj))*zwdrain3(jj) )  
!
! As drainage is implicit, perform a check to prevent any negative drainage
! (can arise rarely and is generally negligible, but to ensure a high order conservation):
!
      pdrain(jj)    = max(0.0, zwdrain(jj))
      pwg3(jj)      = pwg3(jj) + (pdrain(jj) - zwdrain(jj))*ptstep/((pd_g3(jj)-pk%XDG(jj,2))*xrholw)
!
    ENDIF
  ENDDO
END IF
!
!-------------------------------------------------------------------------------
!
DO jj=1,SIZE(pek%XTG,1)
!*       7.     EFFECT OF THE MELTING/FREEZING ON THE SOIL WATER CONTENT
!               --------------------------------------------------------
!
!*       7.1    Effect on surface water liquid and ice reservoirs
!               -------------------------------------------------
!
! First, advance the surface layer ice content using the time tendency
! and sublimation (*heat effect* of sublimation already accounted
! for in latent heat flux calculation):
!           
  pek%XWGI(jj,1) = zwgi1m(jj) + pdwgi1(jj) - plegi(jj)*ptstep/(xlstt*pk%XDG(jj,1)*xrholw)
!
! Next, update the liquid water content:
!
  pek%XWG(jj,1)  = pek%XWG(jj,1)  - pdwgi1(jj) 
!
! Make sure that ice has not dropped below
! zero due to sublimation (the ONLY way
! it can drop below 0). If it has, then
! freeze the needed liquid water (thus warming the
! layer) to ensure sublimation is accomodated,
! then extract this from liquid water store.
! This is a correction used ONLY when last traces
! of soil ice sublimate within a model time step.
!
  zexcessfc(jj)= 0.0
!
  zexcessf(jj) = max(0.0, - pek%XWGI(jj,1))
  pek%XWG(jj,1)     = pek%XWG(jj,1)  - zexcessf(jj)
  pek%XWGI(jj,1)    = pek%XWGI(jj,1) + zexcessf(jj)
  zexcessfc(jj)= zexcessfc(jj) - zexcessf(jj)
!
! Modif H.Douville 26/08/03 (global scale)
! Make sure that ice has not raised above 
! saturation (minus XWGMIN) due to sublimation.
! If it has, then melt the needed frozen water 
! (thus cooling the layer) to ensure sublimation
! is accomodated, then extract this from frozen water store.
!
  zexcessf(jj) = min(0.0, pwsat(jj) - xwgmin - pek%XWGI(jj,1))
  pek%XWG(jj,1)     = pek%XWG(jj,1)  - zexcessf(jj)
  pek%XWGI(jj,1)    = pek%XWGI(jj,1) + zexcessf(jj)
  zexcessfc(jj)= zexcessfc(jj) - zexcessf(jj)
!
! Make sure that liquid has not dropped below
! minimum threshold: this could arise due to
! evaporation and ice formation. Melt the needed water.
! Normally simply a budget check, i.e. usually small but accounted
! for none-the-less to assure high accuracy.
!
  zexcessf(jj) = max(0.0, xwgmin - pek%XWG(jj,1))
  pek%XWGI(jj,1)    = pek%XWGI(jj,1)  - zexcessf(jj)
  pek%XWG(jj,1)     = pek%XWG(jj,1)   + zexcessf(jj)
  zexcessfc(jj)= zexcessfc(jj) + zexcessf(jj)
!
! removes very small values due to computation precision
!
  IF(pek%XWGI(jj,1) < 1.0e-10) THEN
    zexcessf(jj)    = pek%XWGI(jj,1)
    pek%XWG(jj,1)  = pek%XWG(jj,1) + zexcessf(jj)
    pek%XWGI(jj,1) = 0.0
    zexcessfc(jj)   = zexcessfc(jj) + zexcessf(jj)
  ENDIF
!
! Cummulative phase change for the ice/liquid budget corrections:
!
  pek%XTG(jj,1) = pek%XTG(jj,1) - zexcessfc(jj)*xlmtt*dmk%XCT(jj)*xrholw*pk%XDG(jj,1)
!
!
!*       7.2    Effect on deep-soil liquid and ice reservoirs
!               ---------------------------------------------
!
! Update the ice content using the ice tendency:
! Since this reservoir includes surface reservoir, add
! any changes in ice content due to sublimation:
!
  pek%XWGI(jj,2) = zwgi2m(jj) + pdwgi2(jj) - plegi(jj)*ptstep/(xlstt*pk%XDG(jj,2)*xrholw)
!
! Update the liquid water content:
!
  pek%XWG(jj,2)   = pek%XWG(jj,2)   - pdwgi2(jj)
!
! Make sure that ice has not dropped below
! zero due to sublimation (as above).
!
  zexcessfc(jj)= 0.0
!
  zexcessf(jj) = max(0.0, -pek%XWGI(jj,2))
  pek%XWG(jj,2)     = pek%XWG(jj,2)  - zexcessf(jj)
  pek%XWGI(jj,2)    = pek%XWGI(jj,2) + zexcessf(jj)
  zexcessfc(jj)= zexcessfc(jj) - zexcessf(jj)
!
! Budget check of minimum threshold for liquid
! water as for surface: MUCH LESS likely
! to be utilized, but retained for accuracy
! in energy and water balance (as above).
!
  zexcessf(jj) = max(0.0, xwgmin - pek%XWG(jj,2))
  pek%XWGI(jj,2)    = pek%XWGI(jj,2)  - zexcessf(jj)
  pek%XWG(jj,2)     = pek%XWG(jj,2)   + zexcessf(jj)
  zexcessfc(jj)= zexcessfc(jj) + zexcessf(jj)
!
! removes very small values due to computation precision
!
  IF (pek%XWGI(jj,2) < 1.0e-10 * ptstep) THEN
      zexcessf(jj) = pek%XWGI(jj,2)
      pek%XWG(jj,2)    = pek%XWG(jj,2) + zexcessf(jj)
      pek%XWGI(jj,2)    = 0.
      zexcessfc(jj)= zexcessfc(jj) + zexcessf(jj)
  ENDIF
!
! Cummulative phase change for the ice/liquid budget corrections:
!
  pek%XTG(jj,2) = pek%XTG(jj,2) - zexcessfc(jj)*xlmtt*dmk%XCG(jj)*xrholw*pk%XDG(jj,2)
!
!
ENDDO
!
!-------------------------------------------------------------------------------
!
!*       8.     PHYSICAL LIMITS AND RUNOFF
!               --------------------------
!
! runoff of second layer
!
prunoff(:) = max( 0., pek%XWG(:,2)+pek%XWGI(:,2)-pwsat(:) )*pk%XDG(:,2) * xrholw / ptstep
!
! now apply limits:
!
pek%XWG(:,1) = min( pek%XWG(:,1), pwsat(:) - pek%XWGI(:,1) )
pek%XWG(:,1) = max( pek%XWG(:,1), xwgmin              )
!
pek%XWG(:,2) = min( pek%XWG(:,2), pwsat(:) - pek%XWGI(:,2) )
pek%XWG(:,2) = max( pek%XWG(:,2), xwgmin              )
!
!runoff of third layer added to drainage
!
IF (io%CISBA=='3-L') THEN
   pdrain(:) = pdrain(:) + max( 0., pwg3(:)-pwsat(:) )* (pd_g3(:)-pk%XDG(:,2)) * xrholw / ptstep  
   pwg3(:) = min( pwg3(:), pwsat(:)         )
   pwg3(:) = max( pwg3(:), xwgmin           )
END IF
!
IF (lhook) CALL dr_hook('HYDRO_SOIL',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE hydro_soil