hor_interpol_gauss.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE hor_interpol_gauss(KLUOUT,PFIELDIN,PFIELDOUT)
!     #################################################################################
!
!!****  *HOR_INTERPOL_GAUSS* - Interpolation from a gaussian grid
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      M. Jidane   Dec 2013 : initialize NNI if not already done
!!------------------------------------------------------------------
!
USE modd_surfex_mpi, ONLY : nrank, npio
USE modd_horibl, ONLY : lgloblon, lglobs, lglobn, xilo1h, xilo2h, ninloh, &
                        xla, xola, xolo, np, xloph
USE modd_prep,       ONLY : xlat_out, xlon_out, linterp
USE modd_grid_gauss, ONLY : xila1, xilo1, xila2, xilo2, ninla, ninlo, nilen, lrotpole, &
                              xlap, xlop, xcoef, xlat, xlon
USE modd_grid_grib,  ONLY : nni
USE modd_surf_par,   ONLY : xundef
!
USE modi_horibl_surf_gridin
USE modi_horibl_surf_value
USE modi_horibl_surf_extrap
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER,            INTENT(IN)  :: KLUOUT    ! logical unit of output listing
REAL, DIMENSION(:,:), INTENT(IN)    :: PFIELDIN  ! field to interpolate horizontally
REAL, DIMENSION(:,:), INTENT(OUT)   :: PFIELDOUT ! interpolated field
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(:,:), POINTER :: ZFIELDIN0=>null()
REAL, DIMENSION(:,:,:), ALLOCATABLE :: ZFIELDIN 
!
INTEGER, DIMENSION(:,:,:), ALLOCATABLE :: ILSMIN  
INTEGER, DIMENSION(:,:), ALLOCATABLE :: IMASKIN  ! input mask
INTEGER, DIMENSION(:), ALLOCATABLE :: IMASKOUT ! output mask
INTEGER, DIMENSION(:), POINTER :: IMASK=>null()
INTEGER, DIMENSION(SIZE(NP,1),SIZE(NP,2)) :: IP
INTEGER                         :: INO, INL     ! output number of points
INTEGER                         :: JL, JI    ! loop counter
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
!*      1.    Allocations
!
IF (lhook) CALL dr_hook('HOR_INTERPOL_GAUSS',0,zhook_handle)
ino = SIZE(xlat_out)
inl = SIZE(pfieldout,2)
!
ALLOCATE(imaskout(ino))
imaskout = 1
!
IF (nni==0) nni=nilen
ALLOCATE(imaskin(nni,inl))
!
IF (nrank==npio) THEN
  imaskin(:,:) = 1.
  WHERE(pfieldin(:,:)==xundef) imaskin(:,:) = 0.
ENDIF

ALLOCATE(zfieldin(ino,inl,12))
ALLOCATE(ilsmin(ino,inl,12))
!
 CALL horibl_surf_gridin(ninla,ninlo,nni,pfieldin(:,:),ino, &
                        .false.,kluout,lglobs,lglobn,lgloblon,np, &
                        zfieldin0,zfieldin,ilsmin,imaskin,imaskout,imask)
!
DO jl=1,SIZE(np,2)
  DO ji = 1,SIZE(np,1)
    ip(ji,jl) = imask(np(ji,jl))
  ENDDO
ENDDO
!
DO jl=1,SIZE(pfieldout,2)
  !
  CALL horibl_surf_value(nni,ino,pfieldout(:,jl),linterp,zfieldin(:,jl,:),ilsmin(:,jl,:),&
                         xolo,xola,xla,xloph,imaskin(:,jl),imaskout)
  !
ENDDO
!
 CALL horibl_surf_extrap(xila1,xilo1h,xila2,xilo2h,ninla,ninlo,nni,pfieldin,&
                         ino,ip,xlon,xlat,pfieldout,kluout,linterp)
!
!*      5.    Deallocations
!
imask => null()
DEALLOCATE(imaskin )
DEALLOCATE(imaskout)
DEALLOCATE(zfieldin0)
DEALLOCATE(zfieldin)
DEALLOCATE(ilsmin)
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('HOR_INTERPOL_GAUSS',1,zhook_handle)
!
END SUBROUTINE hor_interpol_gauss