grid_modif_conf_proj.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE grid_modif_conf_proj(U,KLUOUT,KLUNAM,KGRID_PAR,KL,PGRID_PAR, &
                                               KGRID_PAR2,KL2,OMODIF,PGRID_PAR2      )  
!     ################################################################
!
!!****  *GRID_MODIF_CONF_PROJ* - routine to read in namelist the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!!         M.Moge   06/2015 Initialization of MODD_SPAWN variables
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surf_par, ONLY : nundef
!
#ifdef SFX_MNH
USE modd_spawn, ONLY : ndxratio,ndyratio,nxsize,nysize,nxor,nyor
#endif
!
USE mode_pos_surf
USE mode_gridtype_conf_proj
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_regular_grid_spawn
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
INTEGER,                      INTENT(IN)    :: KLUOUT     ! output listing logical unit
INTEGER,                      INTENT(IN)    :: KLUNAM     ! namelist file logical unit
INTEGER,                      INTENT(IN)    :: KL         ! number of points
INTEGER,                      INTENT(IN)    :: KGRID_PAR  ! size of PGRID_PAR
REAL, DIMENSION(KGRID_PAR),   INTENT(IN)    :: PGRID_PAR  ! parameters defining the grid
INTEGER,                      INTENT(INOUT) :: KL2        ! number of points in modified grid
INTEGER,                      INTENT(INOUT) :: KGRID_PAR2 ! size of PGRID_PAR2
LOGICAL,                      INTENT(IN)    :: OMODIF     ! flag to modify the grid
REAL, DIMENSION(KGRID_PAR2),  INTENT(OUT)   :: PGRID_PAR2 ! parameters defining the modified grid
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!* initial grid
REAL                              :: ZLAT0    ! reference latitude
REAL                              :: ZLON0    ! reference longitude
REAL                              :: ZRPK     ! projection parameter 
!                                             !   K=1 : stereographic north pole
!                                             ! 0<K<1 : Lambert, north hemisphere
!                                             !   K=0 : Mercator
!                                             !-1<K<0 : Lambert, south hemisphere
!                                             !   K=-1: stereographic south pole
REAL                              :: ZBETA    ! angle between grid and reference longitude
REAL                              :: ZLATOR   ! latitude  of point of coordinates X=0, Y=0
REAL                              :: ZLONOR   ! longitude of point of coordinates X=0, Y=0
INTEGER                           :: IIMAX1   ! number of points in I direction
INTEGER                           :: IJMAX1   ! number of points in J direction
REAL, DIMENSION(:),   ALLOCATABLE :: ZX1      ! X conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: ZY1      ! Y conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: ZDX1     ! X grid mesh size
REAL, DIMENSION(:),   ALLOCATABLE :: ZDY1     ! Y grid mesh size
!
!* new grid
INTEGER                           :: IIMAX2   ! number of points in I direction
INTEGER                           :: IJMAX2   ! number of points in J direction
REAL, DIMENSION(:),   ALLOCATABLE :: ZX2      ! X conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: ZY2      ! Y conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: ZDX2     ! X grid mesh size
REAL, DIMENSION(:),   ALLOCATABLE :: ZDY2     ! Y grid mesh size
!
!* other variables
LOGICAL :: GFOUND
REAL, DIMENSION(:), POINTER       :: ZGRID_PAR
!
!
!*       0.3   Declarations of namelist
!              ------------------------
!
INTEGER :: IXOR = 1            ! position of modified bottom left point
INTEGER :: IYOR = 1            ! according to initial grid
INTEGER :: IXSIZE = -999       ! number of grid meshes in initial grid to be
INTEGER :: IYSIZE = -999       ! covered by the modified grid
INTEGER :: IDXRATIO = 1        ! resolution ratio between modified grid
INTEGER :: IDYRATIO = 1        ! and initial grid
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!
NAMELIST/nam_inifile_conf_proj/ixor,iyor,ixsize,iysize,idxratio,idyratio
!
!------------------------------------------------------------------------------
!
!*       1.    Reading of projection parameters
!              --------------------------------
!
IF (lhook) CALL dr_hook('GRID_MODIF_CONF_PROJ',0,zhook_handle)
 CALL posnam(klunam,'NAM_INIFILE_CONF_PROJ',gfound,kluout)
IF (gfound) READ(unit=klunam,nml=nam_inifile_conf_proj)
!
#ifdef SFX_MNH
! store the parameter in MODD_SPAWN
nxor = ixor
nyor = iyor
nxsize = ixsize
nysize = iysize
ndxratio = idxratio
ndyratio = idyratio
#endif
!
!---------------------------------------------------------------------------
!
!*       2.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
ALLOCATE(zx1(kl))
ALLOCATE(zy1(kl))
ALLOCATE(zdx1(kl))
ALLOCATE(zdy1(kl))
!
 CALL get_gridtype_conf_proj(pgrid_par,zlat0,zlon0,zrpk,zbeta,    &
                              zlator,zlonor,                       &
                              iimax1,ijmax1,                       &
                              zx1,zy1,zdx1,zdy1                    )  
!
!---------------------------------------------------------------------------
!
!*       3.    Default : no modification
!              -------------------------
!
IF (ixsize==-999) ixsize=iimax1
IF (iysize==-999) iysize=ijmax1
!
!---------------------------------------------------------------------------
!
!*       4.    Modification of the grid
!              ------------------------
!
!* number of points
!
iimax2=ixsize*idxratio
ijmax2=iysize*idyratio
!
kl2 = iimax2 * ijmax2
!
 CALL regular_grid_spawn(u,kluout,                              &
                          kl, iimax1,ijmax1,zx1,zy1,zdx1,zdy1,  &
                          ixor, iyor, idxratio, idyratio,       &
                          ixsize, iysize,                       &
                          kl2, iimax2,ijmax2,zx2,zy2,zdx2,zdy2  )   
DEALLOCATE(zx1)
DEALLOCATE(zy1)
DEALLOCATE(zdx1)
DEALLOCATE(zdy1)
!
!---------------------------------------------------------------------------
!
!*       5.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
 CALL put_gridtype_conf_proj(zgrid_par,zlat0,zlon0,zrpk,zbeta,    &
                              zlator,zlonor,                       &
                              iimax2,ijmax2,                       &
                              zx2,zy2,zdx2,zdy2                    )  
!
!---------------------------------------------------------------------------
DEALLOCATE(zx2)
DEALLOCATE(zy2)
DEALLOCATE(zdx2)
DEALLOCATE(zdy2)
!---------------------------------------------------------------------------
!
!* 1st call : initializes dimension
!
IF (kgrid_par2==0) THEN
  kgrid_par2 = SIZE(zgrid_par)
!
ELSE
!
!* 2nd call : initializes grid array
!
  pgrid_par2(:) = 0.
  pgrid_par2(:) = zgrid_par
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('GRID_MODIF_CONF_PROJ',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE grid_modif_conf_proj