grid_from_file.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE grid_from_file (U,GCP,PGRID_FULL_PAR,HPROGRAM,HFILE,HFILETYPE,&
                                 OGRID,HGRID,KGRID_PAR,PGRID_PAR,KL,HDIR)
!     ##########################################################
!!
!!    PURPOSE
!!    -------
!!   Reads in namelist the grid type and parameters.
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson                   Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original     01/2004
!!      M.Moge     02/2015  Parallelization of spawning
!!      M.Moge     04/2015  Parallelization of prep_pgd on son model
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modd_surfex_mpi, ONLY : nrank, nsize_task
!
#ifdef MNH_PARALLEL
USE mode_tools_ll, ONLY : get_dim_phys_ll
#endif
!
USE modi_read_nam_gridtype
USE modi_open_aux_io_surf
USE modi_read_gridtype
USE modi_close_aux_io_surf
USE modi_read_surf
USE modi_open_namelist
USE modi_close_namelist
USE modi_grid_modif
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_luout
IMPLICIT NONE
!
!*    0.1    Declaration of dummy arguments
!            ------------------------------
!
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
REAL, DIMENSION(:), POINTER :: PGRID_FULL_PAR
!
 CHARACTER(LEN=6),  INTENT(IN)   :: HPROGRAM   ! program calling the surface
 CHARACTER(LEN=28), INTENT(IN)   :: HFILE      ! file name
 CHARACTER(LEN=6),  INTENT(IN)   :: HFILETYPE  ! file type
LOGICAL,           INTENT(IN)   :: OGRID      ! .true. if grid is imposed by atm. model
 CHARACTER(LEN=10), INTENT(OUT)  :: HGRID      ! type of horizontal grid
INTEGER,           INTENT(OUT)  :: KGRID_PAR  ! size of PGRID_PAR
REAL, DIMENSION(:), POINTER     :: PGRID_PAR  ! parameters defining this grid
INTEGER,           INTENT(OUT)  :: KL         ! number of points on processor
 CHARACTER(LEN=1), INTENT(IN) :: HDIR
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER           :: IIMAX
INTEGER           :: IJMAX
INTEGER           :: IIMAX_LOC
INTEGER           :: IJMAX_LOC
INTEGER           :: ILUOUT ! listing  file  logical unit
INTEGER           :: ILUNAM ! namelist file  logical unit
INTEGER           :: IRESP  ! return code
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*    0.3    Declaration of namelists
!            ------------------------
!
!------------------------------------------------------------------------------
!
!*       1.    Defaults
!              --------
!
IF (lhook) CALL dr_hook('GRID_FROM_FILE',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!---------------------------------------------------------------------------
!
!*       2.    Opening of the file
!              -------------------
!
!---------------------------------------------------------------------------
!
!*       3.    Number of points in this file
!              -----------------------------
!
IF (hdir/='H') THEN
  !
  CALL open_aux_io_surf(hfile,hfiletype,'FULL  ',hdir=hdir)
  !  
  CALL read_surf(hfiletype,'DIM_FULL  ',kl,iresp,hdir=hdir)
  u%NDIM_FULL = kl
  !
  !---------------------------------------------------------------------------
  !
  !*       4.    Grid type
  !              ---------
  !
   CALL read_surf(hfiletype,'GRID_TYPE',hgrid,iresp,hdir=hdir)
  !
  !---------------------------------------------------------------------------
  !
  !*       5.    Reading parameters of the grid
  !              ------------------------------
  !
#ifdef MNH_PARALLEL
  CALL read_surf(hprogram,'IMAX ',iimax, iresp,hdir='H')
  CALL read_surf(hprogram,'JMAX ',ijmax, iresp,hdir='H')
  u%NIMAX_SURF_ll = iimax
  u%NJMAX_SURF_ll = ijmax
  CALL get_dim_phys_ll('B',iimax_loc,ijmax_loc)
  u%NSIZE_FULL = iimax_loc*ijmax_loc
  kl = u%NSIZE_FULL
  CALL read_gridtype(hfiletype,hgrid,kgrid_par,u%NSIZE_FULL,.false.,hdir='H')
  !
  ALLOCATE(pgrid_par(kgrid_par))
  CALL read_gridtype(hfiletype,hgrid,kgrid_par,u%NSIZE_FULL,.true.,pgrid_par,iresp,hdir='H')
#else  
  CALL read_gridtype(hfiletype,hgrid,kgrid_par,kl,.false.,hdir=hdir)
  !
  ALLOCATE(pgrid_par(kgrid_par))
   CALL read_gridtype(hfiletype,hgrid,kgrid_par,kl,.true.,pgrid_par,iresp,hdir=hdir)
#endif
  !
  !---------------------------------------------------------------------------
  !
  !*       6.    Closes the file
  !              ---------------
  !
  CALL close_aux_io_surf(hfile,hfiletype)
  !
  !------------------------------------------------------------------------------
  !
  !*       7.    Open namelist
  !              -------------
  !
  CALL open_namelist(hprogram,ilunam)
  !
  !------------------------------------------------------------------------------
  !
  !*       8.    Grid modification
  !              -----------------
  !
  IF (.NOT. ogrid) CALL grid_modif(u,iluout,ilunam,hgrid,kgrid_par,pgrid_par,kl)
  !
  CALL close_namelist(hprogram,ilunam)
  !
ELSE
  !
  CALL read_nam_gridtype(gcp,pgrid_full_par,u%NDIM_FULL,hprogram,hgrid,kgrid_par,pgrid_par,kl,hdir)
  !
ENDIF
  !
  !------------------------------------------------------------------------------
  !
!*       9.    Close namelist
!              --------------
!
IF (lhook) CALL dr_hook('GRID_FROM_FILE',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE grid_from_file