get_sizes_parallel.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
SUBROUTINE get_sizes_parallel (DTCO, UG, U, KPROC,KSIZE,KPROCMIN,KSIZE_TASK,OSHADOWS)
!
!
! Modified by B. Decharme  (08/2013): bug in KSIZE_TASK
!
! Modif Matthieu Lafaysse 04/2014
! For shadows routines, we need strictly rectangular subdomains

!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
#ifdef SFX_OL
USE modd_slope_effect, ONLY : nix,niy
USE modn_io_offline, ONLY : csurf_filetype
#endif
USE modi_init_io_surf_n
USE modi_read_surf
USE modi_read_gridtype
USE modi_get_grid_dim
!RJ: missing modi
USE modi_end_io_surf_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
!
INTEGER, INTENT(IN) :: KPROC
INTEGER, INTENT(IN) :: KSIZE
INTEGER, INTENT(IN) :: KPROCMIN
LOGICAL, INTENT(IN),OPTIONAL :: OSHADOWS

LOGICAL::GSHADOWS

LOGICAL :: GRECT

INTEGER, DIMENSION(0:KPROC-1), INTENT(OUT) :: KSIZE_TASK
!

INTEGER::IRESP

INTEGER :: ISIZE, IRESTE, INRESTE
INTEGER :: J, IPROC
INTEGER :: ISIZE_Y,INY_THREAD,INY_RESTE

REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('GET_SIZES_PARALLEL',0,zhook_handle)
!

IF (PRESENT(oshadows)) THEN
  gshadows=oshadows
ELSE
  gshadows=.false.
ENDIF

IF (gshadows) THEN
  ! We want only rectangular subdomains
  
  ! Get x and y dimension lengths
#ifdef SFX_OL
  IF (nix==0) THEN

    !CALL SET_SURFEX_FILEIN(CSURF_FILETYPE,'PREP ') ! not necessary, it works with PGD or PREP file
 CALL init_io_surf_n(dtco, u, &
                        csurf_filetype,'FULL  ','SURF  ','READ ')
    CALL read_surf(&
                   csurf_filetype,'GRID_TYPE',ug%G%CGRID,iresp,hdir='A')
    CALL read_gridtype(&
                       csurf_filetype,ug%G%CGRID,ug%NGRID_FULL_PAR,u%NDIM_FULL,.false.,hdir="A")
    ALLOCATE(ug%XGRID_FULL_PAR(ug%NGRID_FULL_PAR))
    CALL read_gridtype(&
                       csurf_filetype,ug%G%CGRID,ug%NGRID_FULL_PAR,u%NDIM_FULL,.true.,ug%XGRID_FULL_PAR,iresp,hdir="A")  
    CALL end_io_surf_n(csurf_filetype)
    CALL get_grid_dim(ug%G%CGRID,SIZE(ug%XGRID_FULL_PAR),ug%XGRID_FULL_PAR,grect,nix,niy)  
    ug%XGRID_FULL_PAR=>null()
  ENDIF

  !If get_sizes_parallel is called by init_index_mpi
  !ISIZE_Y represents the number of lines of the total domain
  !INY_THREAD represents the number of lines for 1 MPI thread
  !If get_sizes_parallel is called by offline
  !ISIZE_Y represents the number of lines of 1 MPI thread
  !INY_THREAD represent the number of lines for 1 OPEN-MP thread
  
  isize_y=ksize/nix

  ! Number of lines (y) for one thread
  iny_thread=isize_y/kproc
  iny_reste=isize_y-kproc*iny_thread
  
  ksize_task(:)=iny_thread*nix
  
  DO j=kprocmin+kproc-iny_reste,kprocmin+kproc-1
    ksize_task(mod(j,kproc))=ksize_task(mod(j,kproc))+nix
  END DO
#endif
ELSE
  isize = ceiling(ksize*1./kproc) !nb of points by task

  inreste = kproc*isize - ksize ! nb of tasks containing ireste points
  IF (inreste>0) THEN
    ireste = isize - 1
  ELSE
    ireste = isize
  ENDIF
!
  ksize_task(:) = isize
  IF (inreste>0) THEN
    DO j = kprocmin+kproc-inreste,kprocmin+kproc-1
      ksize_task(mod(j,kproc)) = ireste
    ENDDO
  ENDIF
!
!so:
!(nproc-nreste)*isize + nreste*ireste = ndim_full
!if nreste==1: 
!(nproc-1)*isize + ireste = 
!(nproc-1)*isize + NDIM_FULL - (nproc-1)*isize = NDIM_FULL
!if (ireste==isize-1):
!nproc*isize - nreste*isize + nreste*isize - nreste = 
!nproc*isize - nreste = NDIM_FULL


ENDIF
!
IF (lhook) CALL dr_hook('GET_SIZES_PARALLEL',1,zhook_handle)
!
END SUBROUTINE get_sizes_parallel