get_near_meshes_gauss.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_near_meshes_gauss(KGRID_PAR,KL,PGRID_PAR,KNEAR_NBR,KNEAR)
!     ##############################################################
!
!!**** *GET_NEAR_MESHES_GAUSS* get the near grid mesh indices
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE mode_gridtype_gauss
!
USE modd_surfex_mpi, ONLY : nindex, nrank, nnum
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                         INTENT(IN)    :: KGRID_PAR ! size of PGRID_PAR
INTEGER,                         INTENT(IN)    :: KL        ! number of points
INTEGER,                         INTENT(IN)    :: KNEAR_NBR ! number of nearest points wanted
REAL,    DIMENSION(KGRID_PAR),   INTENT(IN)    :: PGRID_PAR ! grid parameters
INTEGER, DIMENSION(:,:),POINTER :: KNEAR     ! near mesh indices
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL, DIMENSION(KL) :: ZDIS
REAL,DIMENSION(KL)    :: ZLON
REAL,DIMENSION(KL)    :: ZLAT
REAL :: ZDMAX
INTEGER :: ID0
INTEGER :: JP1, JP2, JN, IL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_NEAR_MESHES_GAUSS',0,zhook_handle)
!
 CALL get_gridtype_gauss(pgrid_par,kl=il,plon_xy=zlon,plat_xy=zlat)
!
knear(:,:) = 0
!
! calcul de la distance de tous les points 2 à 2
!
zdis = 1.e20
!
DO jp1=1,kl
  !
  IF (nindex(jp1)==nrank) THEN
    !
    DO jp2=1,kl
      zdis(jp2) = sqrt((zlon(jp1)-zlon(jp2))**2+(zlat(jp1)-zlat(jp2))**2)
    ENDDO
    zdmax = maxval(zdis(:)) + 1.
    zdis(jp1) = zdmax
    !
    ! on prend les knear_nbr premiers, pour chaque
    !
    DO jn=1,min(kl-1,knear_nbr)
      !
      id0 = maxval(minloc(zdis(:)))       
      !
      knear(nnum(jp1),jn) = id0
      zdis(id0) = zdmax
      !
    ENDDO
    !
  ENDIF
  !
ENDDO
!
IF (lhook) CALL dr_hook('GET_NEAR_MESHES_GAUSS',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_near_meshes_gauss