get_mesh_corner_lonlaval.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###############################################################
      SUBROUTINE get_mesh_corner_lonlatval(KGRID_PAR,KL,KC,PGRID_PAR,PCORNER_LAT,PCORNER_LON)
!     ###############################################################
!
!!**** *GET_MESH_CORNER_LONLATVAL* get the grid mesh where point (lat,lon) is located
!!
!!    PURPOSE
!!    -------
!!
!!    AUTHOR
!!    ------
!!
!!    B. Decharme         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/2013
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_lonlatval
!
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                       INTENT(IN)    :: KGRID_PAR ! size of PGRID_PAR
INTEGER,                       INTENT(IN)    :: KL        ! number of points
INTEGER,                       INTENT(IN)    :: KC        ! number of grid point corner
REAL,    DIMENSION(KGRID_PAR), INTENT(IN)    :: PGRID_PAR ! grid parameters
REAL,    DIMENSION(KL,KC),     INTENT(OUT)   :: PCORNER_LAT ! Grid corner Latitude
REAL,    DIMENSION(KL,KC),     INTENT(OUT)   :: PCORNER_LON ! Grid corner Longitude
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER             :: INI      ! Number of point
!
REAL, DIMENSION(KL) :: ZLON   ! longitude grid
REAL, DIMENSION(KL) :: ZLAT   ! latitude  grid
!
REAL, DIMENSION(KL) :: ZDLON  ! longitude grid size
REAL, DIMENSION(KL) :: ZDLAT  ! latitude  grid size
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_MESH_CORNER_LONLATVAL',0,zhook_handle)
!
!*    1.     Uncode parameters of the grid
!            -----------------------------
!
 CALL get_gridtype_lonlatval(pgrid_par,kl=ini,px=zlon,py=zlat,pdx=zdlon,pdy=zdlat)
!  
IF(kl/=ini)THEN
  CALL abor1_sfx('GET_GRIDTYPE_LONLATVAL: WRONG NUMBER OF POINT')
ENDIF
!
!*    2.     grid cell corner (counterclockwise sense)
!            -----------------------------------------
!
!       4_______3
!       |       |
!       |   .   |
!       |       |
!       |_______|
!       1       2
!
pcorner_lon(:,1) = zlon(:)-zdlon(:)/2.
pcorner_lat(:,1) = zlat(:)-zdlat(:)/2.
!
pcorner_lon(:,3) = zlon(:)+zdlon(:)/2.
pcorner_lat(:,3) = zlat(:)+zdlat(:)/2.
!
pcorner_lon(:,2) = pcorner_lon(:,3)
pcorner_lat(:,2) = pcorner_lat(:,1)
!
pcorner_lon(:,4) = pcorner_lon(:,1)
pcorner_lat(:,4) = pcorner_lat(:,3)
!
IF (lhook) CALL dr_hook('GET_MESH_CORNER_LONLATVAL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_mesh_corner_lonlatval