get_adj_mes_lonlatval.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_adj_mes_lonlatval(KGRID_PAR,KL,PGRID_PAR,KLEFT,KRIGHT,KTOP,KBOTTOM)
!     ##############################################################
!
!!**** *GET_ADJ_MES_LONLATVAL* get the near grid mesh indices
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_lonlatval
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                         INTENT(IN)    :: KGRID_PAR ! size of PGRID_PAR
INTEGER,                         INTENT(IN)    :: KL        ! number of points
REAL,    DIMENSION(KGRID_PAR),   INTENT(IN)    :: PGRID_PAR ! grid parameters
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KLEFT     ! left   mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KRIGHT    ! right  mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KTOP      ! top    mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KBOTTOM   ! bottom mesh index
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL,DIMENSION(KL)    :: ZX
REAL,DIMENSION(KL)    :: ZY
REAL,DIMENSION(KL)    :: ZDX
REAL,DIMENSION(KL)    :: ZDY
REAL :: ZECX, ZECY, ZECDX, ZECDY
INTEGER :: JLAT, JLON
INTEGER :: IL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_ADJ_MES_LONLATVAL',0,zhook_handle)
!
 CALL get_gridtype_lonlatval(pgrid_par,il,zx,zy,zdx,zdy)
!
kleft(:) = 0
kright(:) = 0
ktop(:) = 0
kbottom(:) = 0
!
DO jlat=1,kl
  !
  DO jlon=1,kl
    !
    zecx = abs(zx(jlon)-zx(jlat))
    zecy = abs(zy(jlon)-zy(jlat))
    !
    zecdx = (zdx(jlon)+zdx(jlat))/2.
    zecdy = (zdy(jlon)+zdy(jlat))/2.
    !
    IF ( zecx <= zecdx .AND. zecy <= zecdy ) THEN ! points overlap or are next to each other in x and y directions
      !
      IF ( zecdy-zecy <= zecdx-zecx .AND. zecx/=zecdx ) THEN ! overlap smaller in y than in x
        !
        IF ( zy(jlon) < zy(jlat) .AND. &                       ! Y under X in y direction
           ( kbottom(jlat)==0                     .OR. &     ! bottom not assigned yet
             zecy < abs(zy(max(1,kbottom(jlat)))-zy(jlat)) .OR. &     ! this y point is closer to x in y direction
             zecx < abs(zx(max(1,kbottom(jlat)))-zx(jlat)) ) ) THEN   ! this y point is closer to x in x direction
          !
          kbottom(jlat) = jlon
          !
        ELSEIF ( zy(jlon) > zy(jlat) .AND. &                   ! Y above X in y direction
               ( ktop(jlat)==0                     .OR. &    ! top not assigned yet
                 zecy < abs(zy(max(1,ktop(jlat)))-zy(jlat)) .OR. &    ! this y point is closer to x in y direction
                 zecx < abs(zx(max(1,ktop(jlat)))-zx(jlat)) ) ) THEN  ! this y point is closer to x in x direction
          !
          ktop(jlat) = jlon
          !
        ENDIF
        !
      ELSEIF (zecdx-zecx < zecdy-zecy ) THEN ! overlap smaller in x than in y
        !
        IF ( zx(jlon) < zx(jlat) .AND. &                     ! Y left X in x direction
           ( kleft(jlat)==0                     .OR. &     ! left not assigned yet
             zecy < abs(zy(max(1,kleft(jlat)))-zy(jlat)) .OR. &     ! this y point is closer to x in y direction
             zecx < abs(zx(max(1,kleft(jlat)))-zx(jlat)) ) ) THEN   ! this y point is closer to x in x direction            
          !
          kleft(jlat)=jlon
          !
        ELSEIF ( zx(jlon) > zx(jlat) .AND. &                     ! Y right X in x direction
               ( kright(jlat)==0                     .OR. &    ! right not assigned yet
                 zecy < abs(zy(max(1,kright(jlat)))-zy(jlat)) .OR. &    ! this y point is closer to x in y direction
                 zecx < abs(zx(max(1,kright(jlat)))-zx(jlat)) ) ) THEN  ! this y point is closer to x in x direction
          !
          kright(jlat)=jlon
          !
        ENDIF
        !
      ENDIF  
      !
    ENDIF
    !
  ENDDO
  !
ENDDO
!
IF (lhook) CALL dr_hook('GET_ADJ_MES_LONLATVAL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_adj_mes_lonlatval