get_adj_mes_lonlat_rot.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_adj_mes_lonlat_rot(KGRID_PAR,KL,PGRID_PAR,KLEFT,KRIGHT,KTOP,KBOTTOM)
!     ##############################################################
!
!!**** *GET_ADJ_MES_LONLAT_ROT* get the near grid mesh indices
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    P. Samuelsson  SMHI
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    12/2012
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_lonlat_rot
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                         INTENT(IN)    :: KGRID_PAR ! size of PGRID_PAR
INTEGER,                         INTENT(IN)    :: KL        ! number of points
REAL,    DIMENSION(KGRID_PAR),   INTENT(IN)    :: PGRID_PAR ! grid parameters
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KLEFT     ! left   mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KRIGHT    ! right  mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KTOP      ! top    mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KBOTTOM   ! bottom mesh index
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER :: ILON    ! number of points in longitude
INTEGER :: ILAT    ! number of points in latitude
INTEGER :: JLAT, JLON
INTEGER :: JL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_ADJ_MES_LONLAT_ROT',0,zhook_handle)
 CALL get_gridtype_lonlat_rot(pgrid_par,             &
                               klon=ilon,klat=ilat  )  
!
kleft(:) = 0
kright(:) = 0
ktop(:) = 0
kbottom(:) = 0
!
IF (ilon*ilat==kl) THEN
  DO jlat=1,ilat
    DO jlon=1,ilon
      jl = jlon + ilon * (jlat-1)
      IF (jlon>1   ) kleft(jl) = jl-1
      IF (jlon<ilon) kright(jl) = jl+1
      IF (jlat>1   ) kbottom(jl) = jl-ilon
      IF (jlat<ilat) ktop(jl) = jl+ilon
    END DO
  END DO
END IF
IF (lhook) CALL dr_hook('GET_ADJ_MES_LONLAT_ROT',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_adj_mes_lonlat_rot