get_adj_mes_ign.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_adj_mes_ign(KGRID_PAR,KL,PGRID_PAR,KLEFT,KRIGHT,KTOP,KBOTTOM)
!     ##############################################################
!
!!**** *GET_ADJACENT_MESHES_IGN* get the near grid mesh indices
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    E. Martin         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/2007
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_ign
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                         INTENT(IN)    :: KGRID_PAR ! size of PGRID_PAR
INTEGER,                         INTENT(IN)    :: KL        ! number of points
REAL,    DIMENSION(KGRID_PAR),   INTENT(IN)    :: PGRID_PAR ! grid parameters
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KLEFT     ! left   mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KRIGHT    ! right  mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KTOP      ! top    mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KBOTTOM   ! bottom mesh index
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL,DIMENSION(KL)    :: ZX
REAL,DIMENSION(KL)    :: ZY
REAL,DIMENSION(KL)    :: ZDX
REAL,DIMENSION(KL)    :: ZDY
REAL :: ZECX, ZECY, ZECDX, ZECDY
INTEGER :: JX, JY
INTEGER :: IL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_ADJ_MES_IGN',0,zhook_handle)
!
 CALL get_gridtype_ign(pgrid_par,px=zx,py=zy,pdx=zdx,pdy=zdy)
!
kleft(:) = 0
kright(:) = 0
ktop(:) = 0
kbottom(:) = 0
!
DO jx=1,kl
  !
  DO jy=1,kl
    !
    zecx = abs(zx(jy)-zx(jx))
    zecy = abs(zy(jy)-zy(jx))
    !
    zecdx = (zdx(jy)+zdx(jx))/2.
    zecdy = (zdy(jy)+zdy(jx))/2.
    !
    IF ( zecx <= zecdx .AND. zecy <= zecdy ) THEN ! points overlap or are next to each other in x and y directions
      !
      IF ( zecdy-zecy <= zecdx-zecx .AND. zecx/=zecdx ) THEN ! overlap smaller in y than in x
        !
        IF ( zy(jy) < zy(jx) .AND. &                       ! Y under X in y direction
           ( kbottom(jx)==0                     .OR. &     ! bottom not assigned yet
             zecy < abs(zy(max(1,kbottom(jx)))-zy(jx)) .OR. &     ! this y point is closer to x in y direction
             zecx < abs(zx(max(1,kbottom(jx)))-zx(jx)) ) ) THEN   ! this y point is closer to x in x direction
          !
          kbottom(jx) = jy
          !
        ELSEIF ( zy(jy) > zy(jx) .AND. &                   ! Y above X in y direction
               ( ktop(jx)==0                     .OR. &    ! top not assigned yet
                 zecy < abs(zy(max(1,ktop(jx)))-zy(jx)) .OR. &    ! this y point is closer to x in y direction
                 zecx < abs(zx(max(1,ktop(jx)))-zx(jx)) ) ) THEN  ! this y point is closer to x in x direction
          !
          ktop(jx) = jy
          !
        ENDIF
        !
      ELSEIF (zecdx-zecx < zecdy-zecy ) THEN ! overlap smaller in x than in y
        !
        IF ( zx(jy) < zx(jx) .AND. &                     ! Y left X in x direction
           ( kleft(jx)==0                     .OR. &     ! left not assigned yet
             zecy < abs(zy(max(1,kleft(jx)))-zy(jx)) .OR. &     ! this y point is closer to x in y direction
             zecx < abs(zx(max(1,kleft(jx)))-zx(jx)) ) ) THEN   ! this y point is closer to x in x direction            
          !
          kleft(jx)=jy
          !
        ELSEIF ( zx(jy) > zx(jx) .AND. &                     ! Y right X in x direction
               ( kright(jx)==0                     .OR. &    ! right not assigned yet
                 zecy < abs(zy(max(1,kright(jx)))-zy(jx)) .OR. &    ! this y point is closer to x in y direction
                 zecx < abs(zx(max(1,kright(jx)))-zx(jx)) ) ) THEN  ! this y point is closer to x in x direction
          !
          kright(jx)=jy
          !
        ENDIF
        !
      ENDIF  
      !
    ENDIF
    !
  ENDDO
  !
ENDDO
!
IF (lhook) CALL dr_hook('GET_ADJ_MES_IGN',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_adj_mes_ign