get_adj_mes_cart.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_adj_mes_cart(KGRID_PAR,KL,PGRID_PAR,KLEFT,KRIGHT,KTOP,KBOTTOM)
!     ##############################################################
!
!!**** *GET_ADJ_MES_CART* get the near grid mesh indices
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_cartesian
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                         INTENT(IN)    :: KGRID_PAR ! size of PGRID_PAR
INTEGER,                         INTENT(IN)    :: KL        ! number of points
REAL,    DIMENSION(KGRID_PAR),   INTENT(IN)    :: PGRID_PAR ! grid parameters
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KLEFT     ! left   mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KRIGHT    ! right  mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KTOP      ! top    mesh index
INTEGER, DIMENSION(KL),          INTENT(OUT)   :: KBOTTOM   ! bottom mesh index
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL, DIMENSION(KL) :: ZX, ZY
INTEGER             :: IIMAX, IJMAX
INTEGER             :: JI, JJ
INTEGER             :: JL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_ADJ_MES_CART',0,zhook_handle)
 CALL get_gridtype_cartesian(pgrid_par,kimax=iimax,kjmax=ijmax,px=zx,py=zy)
!
kleft(:) = 0
kright(:) = 0
ktop(:) = 0
kbottom(:) = 0
!
IF (iimax*ijmax==kl) THEN
  DO jj=1,ijmax
    DO ji=1,iimax
      jl = ji + iimax * (jj-1)
      IF (ji>1    ) kleft(jl) = jl-1
      IF (ji<iimax) kright(jl) = jl+1
      IF (jj>1    ) kbottom(jl) = jl-iimax
      IF (jj<ijmax) ktop(jl) = jl+iimax
    END DO
  END DO
END IF
IF (lhook) CALL dr_hook('GET_ADJ_MES_CART',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_adj_mes_cart