floor_layer_e_budget.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!   ##########################################################################
    SUBROUTINE floor_layer_e_budget(B, PTSTEP, PFLX_BLD_FL, PDQS_FL, PIMB_FL, PRADHT_IN,  &
                                    PRAD_WL_FL, PRAD_RF_FL, PRAD_WIN_FL, PLOAD_FL,        &
                                    PRAD_FL_MA, PCONV_FL_BLD                  )
!   ##########################################################################
!
!!****  *FLOOR_LAYER_E_BUDGET*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the evoultion of building floor temperatures
!         
!     
!!**  METHOD
!     ------
!
!    6 : equations for evolution of Ts_floor 
!        *************************************************************
!
!     dTf_k(t) / dt = 1/(df_k*Cf_k) * (- 2*Kf_k-1*(Tf_k-Tf_k-1)/(df_k-1 +df_k) 
!                                      - 2*Kf_k  *(Tf_k-Tf_k+1)/(df_k+1 +df_k) )
!
!     dTf_1(t) / dt = 1/(df_1*Cf_1) * (- 2*Kw_1*(Tw_1-Tw_2)/(dw_1 +dw_2))
!
!       with
!
!   K*_k  = (d*_k+ d*_k+1)/(d*_k/k*_k+ d*_k+1/k*_k+1)
!
!
! The system is implicited (or semi-implicited).
!
! ZIMPL=1    ---> implicit system
! ZIMPL=0.5  ---> semi-implicit system
! ZIMPL=0    ---> explicit system
!
!
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      G. Pigeon           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    15/04/09 
!!      G. Pigeon      08/10 computation of residual of energy balance 
!!                           modification of the limit condition for
!!                           the deep temp. from the deep road temp.
!!                           to zero flux condition. idem for sfce T
!!      G. Pigeon      11/11 split in 2 for floor and mass to be flux conservative
!!      G. Pigeon      09/12 modif of conv. coef + implicitation of the exchange
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_bem_n, ONLY : bem_t
!
USE modi_layer_e_budget_get_coef
USE modi_layer_e_budget
USE mode_conv_doe
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(bem_t), INTENT(INOUT) :: B
!
REAL,                 INTENT(IN)    :: PTSTEP       ! time step
REAL, DIMENSION(:),   INTENT(OUT)  :: PFLX_BLD_FL !flux from building to floor
REAL, DIMENSION(:),   INTENT(OUT) :: PDQS_FL !heat storage inside the floor
REAL, DIMENSION(:),   INTENT(OUT) :: PIMB_FL !floor energy residual imbalance for verification
REAL, DIMENSION(:), INTENT(IN)    :: PRADHT_IN      ! Indoor radiant heat transfer coefficient
                                                    ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PRAD_RF_FL ! rad. fluxes from roof to floor[W m-2(roof)]
REAL, DIMENSION(:), INTENT(IN)    :: PRAD_WL_FL ! rad. fluxes from wall to floor[W m-2(wall)]
REAL, DIMENSION(:), INTENT(IN)    :: PRAD_WIN_FL  ! rad. fluxes from win to floor[W m-2(win)]
REAL, DIMENSION(:), INTENT(IN)    :: PLOAD_FL ! solar and internal load to the floor
REAL, DIMENSION(:), INTENT(OUT)   :: PRAD_FL_MA  ! rad. fluxes from floor to mass [W m-2(floor)]
REAL, DIMENSION(:), INTENT(OUT)   :: PCONV_FL_BLD  ! conv. fluxes from floor to bld [W m-2(floor)]
!
!*      0.2    declarations of local variables
!
!
REAL :: ZIMPL=1.0      ! implicit coefficient
REAL :: ZEXPL=0.0      ! explicit coefficient
!
REAL, DIMENSION(SIZE(B%XT_FLOOR,1),SIZE(B%XT_FLOOR,2)) :: ZA,& ! lower diag.
                                                      ZB,& ! main  diag.
                                                      ZC,& ! upper diag.
                                                      ZY   ! r.h.s.
!
REAL, DIMENSION(SIZE(B%XT_FLOOR,1)) :: ZTS_FL ! surf. floor temp.  used for rad. exchanges
REAL, DIMENSION(SIZE(B%XT_FLOOR,1)) :: ZTS_FL_CONV ! surf. floor temp. used for conv exchanges
                                               ! used during calculation
REAL, DIMENSION(SIZE(B%XT_FLOOR,1)) :: ZCHTC_IN_FL   ! Indoor floor convec heat transfer coefficient
                                                    ! [W K-1 m-2(bld)]

REAL(KIND=JPRB) :: ZHOOK_HANDLE
INTEGER :: JJ
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('FLOOR_LAYER_E_BUDGET',0,zhook_handle)
!
! *Convection heat transfer coefficients [W m-2 K-1]
!  From EP Engineering Reference
zchtc_in_fl(:) = chtc_up_doe(b%XT_FLOOR(:,1), b%XTI_BLD(:))
DO jj=1,SIZE(zchtc_in_fl)
   zchtc_in_fl(jj) = max(1., zchtc_in_fl(jj))
ENDDO


!
 CALL layer_e_budget_get_coef( b%XT_FLOOR, ptstep, zimpl, b%XHC_FLOOR, b%XTC_FLOOR, b%XD_FLOOR, &
                              za, zb, zc, zy )
!
zts_fl(:) = b%XT_FLOOR(:,1) 

zb(:,1) = zb(:,1) + zimpl * (zchtc_in_fl(:)*4./3. + pradht_in(:) * b%XF_FLOOR_MASS(:))


zy(:,1) = zy(:,1)  &
   + zchtc_in_fl(:) * (b%XTI_BLD(:) - 1./3. * b%XT_FLOOR(:, 1) * (4* zexpl -1))  &
   + b%XF_FLOOR_WIN  (:) * prad_win_fl(:) + b%XF_FLOOR_WALL (:) * prad_wl_fl(:)  &
   + b%XF_FLOOR_ROOF (:) * prad_rf_fl(:)                   &
   + pradht_in(:) * b%XF_FLOOR_MASS (:) * (b%XT_MASS(:,1) - zexpl * b%XT_FLOOR(:,1))  &
   + pload_fl(:)
!
 CALL layer_e_budget( b%XT_FLOOR, ptstep, zimpl, b%XHC_FLOOR, b%XTC_FLOOR, b%XD_FLOOR, &
                     za, zb, zc, zy, pdqs_fl )
!
!*      floor surface temperature used in the implicit formulation
!       ----------------------------------------------------------
zts_fl_conv(:) = 4./3. * zimpl * b%XT_FLOOR(:,1) + 1./3. * zts_fl(:) * (4 * zexpl - 1.)
zts_fl(:) = zexpl * zts_fl(:) + zimpl * b%XT_FLOOR(:,1)
!
!*      fluxes with mass and indoor air
!       ----------------------------------------------------------
prad_fl_ma(:) = pradht_in(:)     * (zts_fl(:) - b%XT_MASS(:,1))
pconv_fl_bld(:) = zchtc_in_fl(:) * (zts_fl_conv(:) - b%XTI_BLD (:))
!
!*     Flux between floor and indoor surfaces and air
!       ------------------------------------------------
pflx_bld_fl(:) = - pconv_fl_bld(:) + b%XF_FLOOR_WIN  (:) * prad_win_fl(:)  &
       + b%XF_FLOOR_WALL (:) * prad_wl_fl(:) + b%XF_FLOOR_ROOF (:) * prad_rf_fl(:) &
       + pradht_in(:) * b%XF_FLOOR_MASS(:) * (b%XT_MASS(:,1)  - zts_fl(:)) &
       + pload_fl(:)
!
!*     Floor residual energy imbalance for verification
!       ------------------------------------------------
pimb_fl(:) = pflx_bld_fl(:) - pdqs_fl(:)
!
IF (lhook) CALL dr_hook('FLOOR_LAYER_E_BUDGET',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE floor_layer_e_budget