faquin.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE faquin_fort                                             &
&                     (fa,  krep, knumer, cdpref, knivau, cdsuff,  &
&                      cdnoma, klnoma)
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!      Sous-programme de decomposition du nom d'un article associe a un 
!     champ.
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KNUMER (Entree) ==> Numero de l'unite logique;
!                CDPREF (Sortie) ==> Prefixe eventuel du nom d'article;
!                KNIVAU (Sortie) ==> Niveau vertical eventuel;
!                CDSUFF (Sortie) ==> Suffixe eventuel du nom d'article;
!                CDNOMA (Entree) ==> Nom de l'article LFI
!                KLNOMA (Entree) ==> Longueur du nom de l'article LFI
!     
!    P MARGUINAUD 18/03/2013 CREATION
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER, KNIVAU, KLNOMA
!
INTEGER (KIND=JPLIKB) IREP, ILPRFU, ILSUFU, IRANG, INIMES, INIVAU
INTEGER (KIND=JPLIKB) IB1PAR (fa%jplb1p), ILNOMA
!
LOGICAL LLVERF, LLRLFI
!
CHARACTER CDPREF*(*), CDSUFF*(*), CDNOMA*(*)
!
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
CHARACTER(LEN=FA%JPXNOM) CLNOMA
LOGICAL                  LLFATA

!**
!     1.  -  CONTROLES ET INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FAQUIN_MT',0,zhook_handle)

irep=0

llverf=.false.
llrlfi=.false.
ilprfu=int(len(cdpref), jplikb)
ilsufu=int(len(cdsuff), jplikb)

CALL fanumu_fort (fa, knumer,irang)
!
IF (irang.EQ.0) THEN
  irep=-51
  GOTO 1001
ENDIF
!
!         Verrouillage eventuel du fichier.
!
IF (fa%LFAMUL) CALL lfiver_fort (fa%LFI, fa%FICHIER(irang)%VRFICH,'ON')
llverf=fa%LFAMUL
!
IF (fa%FICHIER(irang)%LCREAF) THEN
  irep=-85
  GOTO 1001
ENDIF

cdpref = ''
cdsuff = ''
knivau = 0

IF (cdnoma(1:8) == 'SPECSURF') THEN
  cdpref = cdnoma(1:8)
  cdsuff = cdnoma(9:klnoma)
ELSEIF (cdnoma(1:4) == 'PROF') THEN
  cdpref = cdnoma(1:4)
  cdsuff = cdnoma(5:klnoma)
ELSEIF (cdnoma(1:4) == 'SURF') THEN
  cdpref = cdnoma(1:4)
  cdsuff = cdnoma(5:klnoma)
ELSEIF (cdnoma(1:4) == 'SOMM') THEN
  cdpref = cdnoma(1:4)
  cdsuff = cdnoma(5:klnoma)
ELSEIF (cdnoma(1:4) == 'ICAO') THEN
  cdpref = cdnoma(1:4)
  cdsuff = cdnoma(5:klnoma)
ELSEIF (cdnoma(1:4) == 'SFX.') THEN
  cdpref = cdnoma(1:4)
  cdsuff = cdnoma(5:klnoma)
ELSEIF (cdnoma(1:3) == 'CLS') THEN
  cdpref = cdnoma(1:3)
  cdsuff = cdnoma(4:klnoma)
ELSEIF (cdnoma(1:3) == 'MSL') THEN
  cdpref = cdnoma(1:3)
  cdsuff = cdnoma(4:klnoma)
ELSEIF (cdnoma(1:3) == 'CLP') THEN
  cdpref = cdnoma(1:3)
  cdsuff = cdnoma(4:klnoma)
ELSEIF (cdnoma(1:3) == 'JET') THEN
  cdpref = cdnoma(1:3)
  cdsuff = cdnoma(4:klnoma)
ELSEIF (cdnoma(1:3) == 'INT') THEN
  cdpref = cdnoma(1:3)
  cdsuff = cdnoma(4:klnoma)
ELSEIF (cdnoma(1:2) == 'KT' .AND. lnum(cdnoma(3:klnoma), inivau, '(I3.3)')) THEN
  cdpref = cdnoma(1:2)
  cdsuff = cdnoma(6:klnoma)
  knivau = inivau
ELSEIF (cdnoma(1:2) == 'KB' .AND. lnum(cdnoma(3:klnoma), inivau, '(I3.3)')) THEN
  cdpref = cdnoma(1:2)
  cdsuff = cdnoma(6:klnoma)
  knivau = inivau
ELSEIF (cdnoma(1:1) == 'P' .AND. lnum(cdnoma(2:klnoma), inivau, '(I5.5)')) THEN
  cdpref = cdnoma(1:1)
  cdsuff = cdnoma(7:klnoma)
  knivau = inivau
  IF (knivau == 0) knivau = 100000
ELSEIF (cdnoma(1:1) == 'H' .AND. lnum(cdnoma(2:klnoma), inivau, '(I5.5)')) THEN
  cdpref = cdnoma(1:1)
  cdsuff = cdnoma(7:klnoma)
  knivau = inivau
ELSEIF (cdnoma(1:1) == 'V' .AND. lnum(cdnoma(2:klnoma), inivau, '(I3.3)')) THEN
  cdpref = cdnoma(1:1)
  cdsuff = cdnoma(5:klnoma)
  knivau = inivau
ELSEIF (cdnoma(1:1) == 'T' .AND. lnum(cdnoma(2:klnoma), inivau, '(I3.3)')) THEN
  cdpref = cdnoma(1:1)
  cdsuff = cdnoma(5:klnoma)
  knivau = inivau
ELSEIF (cdnoma(1:1) == 'S' .AND. lnum(cdnoma(2:klnoma), inivau, '(I3.3)')) THEN
  cdpref = cdnoma(1:1)
  cdsuff = cdnoma(5:klnoma)
  knivau = inivau
ELSEIF (cdnoma(1:1) == 'X' .AND. lnum(cdnoma(2:klnoma), inivau, '(I3.3)')) THEN
  cdpref = cdnoma(1:1)
  cdsuff = cdnoma(5:klnoma)
  knivau = inivau
ELSE
  cdpref = cdnoma(1:4)
  cdsuff = cdnoma(5:)
ENDIF

ilnoma=fa%JPXNOM
CALL fanfan_fort                                          &
&            (fa,  irep, knumer, cdpref, knivau, cdsuff,  &
&             clnoma, ilnoma)

IF (irep.NE.0) GOTO 1001

IF (clnoma(1:ilnoma) /= cdnoma(1:klnoma)) THEN
  irep=-65
ENDIF

1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
!        Deverrouillage eventuel du fichier.
!
IF (llverf) CALL lfiver_fort (fa%LFI, fa%FICHIER(irang)%VRFICH,'OFF')

IF (llfata) THEN
  inimes=2
ELSE
  inimes=ixnvms(irang)
ENDIF
!
IF (.NOT.llfata.AND.inimes.NE.2)  THEN 
  IF (lhook) CALL dr_hook('FAQUIN_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FAQUIN'
!
WRITE (unit=clmess,fmt='(''KREP='',I5,'', KNUMER='',I3, &
&       '', CDPREF='''''',A,'''''', KNIVAU='',I6,       &
&       '', CDSUFF='''''',A,'''')')                     &
&   krep,knumer,cdpref(1:ilprfu),knivau,cdsuff(1:ilsufu)
CALL faipar_fort                                       &
&               (fa, knumer,inimes,irep,llfata,clmess, &
&                clnspr, cdnoma(1:klnoma),llrlfi)
!
IF (lhook) CALL dr_hook('FAQUIN_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"

LOGICAL FUNCTION lnum (CDST, KNUM, CDFMT)

CHARACTER (LEN=*) :: CDST, CDFMT
INTEGER (KIND=JPLIKB) :: KNUM
INTEGER :: IREP

irep = 0
READ (unit=cdst, fmt=cdfmt, iostat=irep) knum

IF (irep == 0) THEN
  lnum = .true.
ELSE
  lnum = .false.
  knum = 0
ENDIF

END FUNCTION lnum

END SUBROUTINE faquin_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE faquin64                                        &
&           (krep, knumer, cdpref, knivau, cdsuff, cdnoma, &
&            klnoma)
USE fa_mod, ONLY : fa => fa_com_default, &
&                  fa_com_default_init,  &
&                  new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDPREF                                 !   OUT
INTEGER (KIND=JPLIKB)  KNIVAU                                 !   OUT
CHARACTER (LEN=*)      CDSUFF                                 !   OUT
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKB)  KLNOMA                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL faquin_fort                                               &
&           (fa, krep, knumer, cdpref, knivau, cdsuff, cdnoma, &
&            klnoma)

END SUBROUTINE faquin64

SUBROUTINE faquin                                          &
&           (krep, knumer, cdpref, knivau, cdsuff, cdnoma, &
&            klnoma)
USE fa_mod, ONLY : fa => fa_com_default, &
&                  fa_com_default_init,  &
&                  new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDPREF                                 !   OUT
INTEGER (KIND=JPLIKM)  KNIVAU                                 !   OUT
CHARACTER (LEN=*)      CDSUFF                                 !   OUT
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLNOMA                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL faquin_mt                                                 &
&           (fa, krep, knumer, cdpref, knivau, cdsuff, cdnoma, &
&            klnoma)

END SUBROUTINE faquin

SUBROUTINE faquin_mt                                           &
&           (fa, krep, knumer, cdpref, knivau, cdsuff, cdnoma, &
&            klnoma)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDPREF                                 !   OUT
INTEGER (KIND=JPLIKM)  KNIVAU                                 !   OUT
CHARACTER (LEN=*)      CDSUFF                                 !   OUT
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLNOMA                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  INIVAU                                 !   OUT
INTEGER (KIND=JPLIKB)  ILNOMA                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
ilnoma     = int(    klnoma, jplikm)

CALL faquin_fort                                               &
&           (fa, irep, inumer, cdpref, inivau, cdsuff, cdnoma, &
&            ilnoma)

krep       = int(      irep, jplikm)
knivau     = int(    inivau, jplikb)

END SUBROUTINE faquin_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF CDPREF          OUT 
!INTF KNIVAU          OUT 
!INTF CDSUFF          OUT 
!INTF CDNOMA        IN    
!INTF KLNOMA        IN