falsif.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE falsif_fort                           &
&                     (fa,  krep, knumer, cdiden )
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Sous-programme renvoyant le NOM de l'Identificateur
!     d'un fichier ARPEGE.
!       ( Lecture Specifique de l'Identificateur de Fichier )
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KNUMER (Entree) ==> Numero de l'unite logique;
!                CDIDEN (Sortie) ==> Nom de l'identificateur.
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER
!
INTEGER (KIND=JPLIKB) IREP, ILIDEN, IRANG
INTEGER (KIND=JPLIKB) J, ILONGN, INIMES, ILACTI
!
LOGICAL LLVERF, LLRLFI
!
CHARACTER CDIDEN*(*)
!
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     1.  -  CONTROLES ET INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FALSIF_MT',0,zhook_handle)
clacti=''
llverf=.false.
llrlfi=.false.
iliden=int(len(cdiden), jplikb)
CALL fanumu_fort                 &
&               (fa, knumer,irang)
!
IF (irang.EQ.0) THEN
  irep=-51
  GOTO 1001
ELSEIF (iliden.LE.0) THEN
  irep=-65
  GOTO 1001
ELSE
  irep=0
ENDIF
!
!         Verrouillage eventuel du fichier.
!
IF (fa%LFAMUL) CALL lfiver_fort                               &
&                              (fa%LFI, fa%FICHIER(irang)%VRFICH,'ON')
llverf=fa%LFAMUL
!**
!     2.  -  ON RENVOIE LE NOM D'IDENTIFICATEUR, APRES CONTROLE EVENTUEL
!            D'UNE VARIABLE CARACTERE SUFISAMMENT LONGUE.
!-----------------------------------------------------------------------
!
IF (iliden.GE.fa%NCPCAD) THEN
  cdiden=fa%FICHIER(irang)%CIDENT
ELSE
!
  DO j=fa%NCPCAD,1,-1
!
  IF (fa%FICHIER(irang)%CIDENT(j:j).NE.' ') THEN
    ilongn=j
    GOTO 202
  ENDIF
!
  ENDDO
!
  irep=-66
  GOTO 1001
!
202 CONTINUE
!
  IF (ilongn.GT.iliden) THEN
    irep=-69
  ELSE
    cdiden=fa%FICHIER(irang)%CIDENT(1:ilongn)
  ENDIF
!
ENDIF
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
!        Deverrouillage eventuel du fichier.
!
IF (llverf) CALL lfiver_fort                                &
&                           (fa%LFI, fa%FICHIER(irang)%VRFICH,'OFF')
!
IF (llfata) THEN
  inimes=2
ELSE
  inimes=ixnvms(irang)
ENDIF
!
IF (.NOT.llfata.AND.inimes.NE.2)  THEN 
  IF (lhook) CALL dr_hook('FALSIF_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FALSIF'
!
IF (irep.EQ.0.OR.irep.EQ.-69) THEN
  ilacti=fa%NCPCAD
  clacti=fa%FICHIER(irang)%CIDENT(1:ilacti)
ELSE
  ilacti=8
  clacti(1:ilacti)=fa%CHAINC(:ilacti)
ENDIF
!
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', CDIDEN='''''',A,'''''''')')                  &
&   krep,knumer,clacti(1:ilacti)
CALL faipar_fort                                     &
&               (fa, knumer,inimes,irep,llfata,clmess, &
&                clnspr,clacti(1:ilacti),llrlfi)
!
IF (lhook) CALL dr_hook('FALSIF_MT',1,zhook_handle)
RETURN

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"

END SUBROUTINE falsif_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE falsif64              &
&           (krep, knumer, cdiden)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDIDEN                                 !   OUT

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL falsif_fort                     &
&           (fa, krep, knumer, cdiden)

END SUBROUTINE falsif64

SUBROUTINE falsif                &
&           (krep, knumer, cdiden)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDIDEN                                 !   OUT

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL falsif_mt                       &
&           (fa, krep, knumer, cdiden)

END SUBROUTINE falsif

SUBROUTINE falsif_mt                 &
&           (fa, krep, knumer, cdiden)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDIDEN                                 !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL falsif_fort                     &
&           (fa, irep, inumer, cdiden)

krep       = int(      irep, jplikm)

END SUBROUTINE falsif_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF CDIDEN          OUT