faisc1.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE faisc1_fort                  &
&                     (fa,  krep, krang )
USE fa_mod, ONLY : fa_com, jpniil
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!      Ce sous-programme initialise un tableau "reference" de
!      l'en-tete GRIB, section 1.
!      (routine appelee une seule fois pour un fichier donne)
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KRANG  (Entree) ==> Rang de l'unite logique;
!*
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KRANG
!
INTEGER (KIND=JPLIKB) I, INUMER
INTEGER (KIND=JPLIKB) INIMES, IRANGC
!
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     0.  -  INITIALISATIONS ET CONTROLES
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FAISC1_MT',0,zhook_handle)
krep=0
IF (krang.LE.0.OR.krang.GT.fa%JPNXFA) THEN
  krep=-66
  GOTO 1001
ENDIF
irangc=fa%FICHIER(krang)%NUCADR
!**
!     1.  -  INIT. DU TAB. FA%NSEC1 REPRESENTANT LA SECTION 1 DE GRIBEX
!-----------------------------------------------------------------------
!
!  2: identification of centre
!
! (defaut=85 pour Toulouse; pour en changer, utiliser FAREGU)
fa%FICHIER(krang)%NSEC1(2) = 85
!  3: generating process identification number, alloc by the orig. centre
IF (fa%CADRE(irangc)%LIMLAM) THEN
! Il s'agit du modele Aladin
  fa%FICHIER(krang)%NSEC1(3) = 177
ELSE
! Il s'agit du modele Arpege
  IF (fa%FICHIER(krang)%MADATE(7).GT.0) THEN
!     prevision
    fa%FICHIER(krang)%NSEC1(3) = 211
  ELSE
!     analyse
    fa%FICHIER(krang)%NSEC1(3) = 201
!     analyse initialisee -> prevision
    IF (fa%FICHIER(krang)%MADATE(9).EQ.1) fa%FICHIER(krang)%NSEC1(3) = 211
  ENDIF
ENDIF

fa%FICHIER(krang)%NIDCEN = fa%FICHIER(krang)%NSEC1(2)

!  4: grid definition
!     =255 for a non-catalogued grid (description follows in KSEC2)
fa%FICHIER(krang)%NSEC1(4) = 255
!  5: flag showing whether sections 2 and 3 are present
!     128 --> Section 2 is included, Section 3 is omitted (no bitmap)
fa%FICHIER(krang)%NSEC1(5) = 128
!  6 a 9: to be initialized later (specific to each field)
fa%FICHIER(krang)%NSEC1(6:9) = 0
! 10 a 21: valeurs deduites de FA%MADATE(1:11,KRANG)
!
! rappel :   2000 -->  an 100 (=FA%NSEC1(10))  siecle 20 (=FA%NSEC1(21))
!            2001 -->  an   1  "        "   siecle 21  "        "
!
fa%FICHIER(krang)%NSEC1(10) = 1 + mod(fa%FICHIER(krang)%MADATE(1) - 1 , 100_jplikb )
fa%FICHIER(krang)%NSEC1(21) = 1 + (fa%FICHIER(krang)%MADATE(1) - 1) / 100
DO i=1,10
  fa%FICHIER(krang)%NSEC1(10+i) = fa%FICHIER(krang)%MADATE(1+i)
ENDDO

! FA%NSEC1(18,KRANG)=10 signifie un codage sur 2 octets de l'echeance
! Ce n'est pas le cas, donc on revient a 0 pour GRIBEX
IF (fa%FICHIER(krang)%NSEC1(18)==10) fa%FICHIER(krang)%NSEC1(18)=0
! FA%MADATE(10,KRANG) peut contenir l'echeance precedente dans le cas
! d'un calcul sur une periode (min, max par exemple): c'est une
! convention dans FA (depuis fin 2000) qui est incompatible avec
! GRIBEX. On retire donc cette valeur ici dans FA%NSEC1, sachant
! qu'elle sera utilisee plus tard.
fa%FICHIER(krang)%NSEC1(19) = 0
!
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
llfata=llmoer(krep,krang)
!
IF (fa%LFAMOP.OR.llfata) THEN
  inimes=2
  clnspr='FAISC1'
  inumer=jpniil
!
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KRANG='',I4)') &
&     krep, krang
  CALL faipar_fort                                      &
&                 (fa, inumer,inimes,krep,.false.,clmess, &
&                  clnspr, clnspr,.false.)
ENDIF
!
IF (lhook) CALL dr_hook('FAISC1_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"

END SUBROUTINE faisc1_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE faisc164           &
&           (krep, krang)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KRANG                                  ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL faisc1_fort            &
&           (fa, krep, krang)

END SUBROUTINE faisc164

SUBROUTINE faisc1             &
&           (krep, krang)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KRANG                                  ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL faisc1_mt              &
&           (fa, krep, krang)

END SUBROUTINE faisc1

SUBROUTINE faisc1_mt             &
&           (fa, krep, krang)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KRANG                                  ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  IRANG                                  ! IN   
! Convert arguments

irang      = int(     krang, jplikb)

CALL faisc1_fort            &
&           (fa, irep, irang)

krep       = int(      irep, jplikm)

END SUBROUTINE faisc1_mt

!INTF KREP            OUT 
!INTF KRANG         IN