fais2f.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE fais2f_fort                  &
&                     (fa,  krep, krang )
USE fa_mod, ONLY : fa_com, jpniil
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!      Ce sous-programme initialise un tableau "reference" de
!      l'en-tete GRIB, section 2.
!      (routine appelee une seule fois pour un fichier Aladin donne)
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KRANG  (Entree) ==> Rang de l'unite logique;
!*
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KRANG
!
INTEGER (KIND=JPLIKB) IRANGC, JM, JMAX, ILOW
INTEGER (KIND=JPLIKB) IADD, INUMER, INIMES
!
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     0.  -  INITIALISATIONS ET CONTROLES
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FAIS2F_MT',0,zhook_handle)
krep=0
IF (krang.LE.0.OR.krang.GT.fa%JPNXFA) THEN
  krep=-66
  GOTO 1001
ENDIF
irangc=fa%FICHIER(krang)%NUCADR
!**
!     1.  -  INITIALISATION DU TABLEAU FA%NSC2ALF
!-----------------------------------------------------------------------
!
!  Les valeurs de ce tableau representent les nb de pts
! le long de chaque "parallele" (ici, le nb de coeff spectraux
! pour un meme m (nb d'onde zonal), excepte le triangle et les axes non
! compactes). Il s'agit en effet de deguiser un champ spectral 
! Aladin en champ pts de grille (grille lat-lon) pour profiter
! du compactage, voire de la compression, GRIBEX.
! Le rangt des CSP est fait verticalement (par colonne de m=cst)
! et pour chaque couple (m,n) correspond 4 CSP.
!
jmax = (fa%CADRE(irangc)%NOZPAR(6)-fa%CADRE(irangc)%NOZPAR(5)+1)/4 -1
DO jm=1,jmax
  ilow=2+2*jm+1
  iadd=4* max(fa%FICHIER(krang)%NSTROF+1-jm,1_jplikb )
!
  fa%FICHIER(krang)%NSC2ALF(jm)=fa%CADRE(irangc)%NOMPAR(ilow+1)-        &
&                        (fa%CADRE(irangc)%NOMPAR(ilow)+iadd)+1
ENDDO
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
llfata=llmoer(krep,krang)
!
IF (fa%LFAMOP.OR.llfata) THEN
  inimes=2
  clnspr='FAIS2F'
  inumer=jpniil
!
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KRANG='',I4)') &
&     krep, krang
  CALL faipar_fort                                      &
&                 (fa, inumer,inimes,krep,.false.,clmess, &
&                  clnspr,clnspr,.false.)
ENDIF
!
IF (lhook) CALL dr_hook('FAIS2F_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"

END SUBROUTINE fais2f_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE fais2f64           &
&           (krep, krang)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KRANG                                  ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fais2f_fort            &
&           (fa, krep, krang)

END SUBROUTINE fais2f64

SUBROUTINE fais2f             &
&           (krep, krang)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KRANG                                  ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fais2f_mt              &
&           (fa, krep, krang)

END SUBROUTINE fais2f

SUBROUTINE fais2f_mt             &
&           (fa, krep, krang)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KRANG                                  ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  IRANG                                  ! IN   
! Convert arguments

irang      = int(     krang, jplikb)

CALL fais2f_fort            &
&           (fa, irep, irang)

krep       = int(      irep, jplikm)

END SUBROUTINE fais2f_mt

!INTF KREP            OUT 
!INTF KRANG         IN