fadies.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE fadies_fort                           &
&                     (fa,  krep, knumer, kdatef )
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!      Sous-programme permettant d'obtenir la date d'un fichier ouvert
!     pour le logiciel de Fichiers ARPEGE, et deja muni d'une date.
!     ( "DIES" = jour en latin... )
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KNUMER (Entree) ==> Numero de l'unite logique;
!     (Tableau)  KDATEF (Sortie) ==> Date elle-meme (FA%JPLDAT mots).
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER
INTEGER (KIND=JPLIKB) KDATEF (fa%jpldat)
!
INTEGER (KIND=JPLIKB) IRANG, J, IREP, INIMES
!
LOGICAL LLVERF
!
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, ET INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FADIES_MT',0,zhook_handle)
clacti=''
llverf=.false.
CALL fanumu_fort                 &
&               (fa, knumer,irang)
!
IF (irang.EQ.0) THEN
  irep=-51
  GOTO 1001
ENDIF
!
!         Verrouillage eventuel du fichier.
!
IF (fa%LFAMUL) CALL lfiver_fort                               &
&                              (fa%LFI, fa%FICHIER(irang)%VRFICH,'ON')
llverf=fa%LFAMUL
!**
!     2.  -  CONTROLE DE DEFINITION PREALABLE DE LA DATE.
!-----------------------------------------------------------------------
!
IF (fa%FICHIER(irang)%LCREAF) THEN
  irep=-85
  GOTO 1001
ENDIF
!**
!     3.  -  TRANSFERT DE LA TABLE "FA%MADATE" DANS LE TABLEAU ARGUMENT.
!-----------------------------------------------------------------------
!
DO j=1,fa%JPLDAT
kdatef(j)=fa%FICHIER(irang)%MADATE(j)
ENDDO
!
irep=0
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
!        Deverrouillage eventuel du fichier.
!
IF (llverf) CALL lfiver_fort                                &
&                           (fa%LFI, fa%FICHIER(irang)%VRFICH,'OFF')
!
IF (llfata.OR.ixnvms(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('FADIES_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FADIES'
!
IF (inimes.EQ.2) THEN
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', KDATEF(1:5)='',I5,2(''/'',I2),I3,'':'',I2.2,   &
&       '', KDATEF(7:8)='',I6,''-'',I6)') krep,knumer,     &
&     (kdatef(j),j=1,5),(kdatef(j),j=7,8)
  CALL faipar_fort                                     &
&                 (fa, knumer,inimes,irep,llfata,clmess, &
&               clnspr,clacti,.false.)
ENDIF
!
IF (lhook) CALL dr_hook('FADIES_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"

END SUBROUTINE fadies_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE fadies64              &
&           (krep, knumer, kdatef)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  KDATEF     (*)                 !   OUT

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fadies_fort                     &
&           (fa, krep, knumer, kdatef)

END SUBROUTINE fadies64

SUBROUTINE fadies                &
&           (krep, knumer, kdatef)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KDATEF     (*)                 !   OUT

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fadies_mt                       &
&           (fa, krep, knumer, kdatef)

END SUBROUTINE fadies

SUBROUTINE fadies_mt                 &
&           (fa, krep, knumer, kdatef)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KDATEF     (fa%jpldat)                 !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  IDATEF     (fa%jpldat)                 !   OUT
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL fadies_fort                     &
&           (fa, irep, inumer, idatef)

krep       = int(      irep, jplikm)
kdatef     = int(    idatef, jplikm)

END SUBROUTINE fadies_mt

!INTF KREP            OUT                               
!INTF KNUMER        IN                                  
!INTF KDATEF          OUT DIMS=FA%JPLDAT