factui.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE factui_fort                   &
&                     (fa,  krep, krangc )
USE fa_mod, ONLY : fa_com, free_cadre, jpniil
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Sous-programme A USAGE INTERNE AU LOGICIEL. Fait la suppression
!     d'un cadre ( vis-a-vis des tables du logiciel ) .
!        En mode multi-taches, il doit y avoir verrouillage global
!     de la zone d'appel au sous-programme.
!**
!        Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                    KRANGC (Entree) ==> Rang du cadre dans les tables.
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KRANGC
!
INTEGER (KIND=JPLIKB) J, IPOSCA, INIMES, INUMER
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     1.  -  CONTROLE PREALABLE DE COHERENCE.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FACTUI_MT',0,zhook_handle)
clacti=''
IF (krangc.LE.0.OR.krangc.GT.fa%JPNXCA) THEN
  krep=-66
  GOTO 1001
ENDIF
!**
!     2.  -  RECHERCHE DU CADRE DANS LA TABLE "FA%NCAIND".
!-----------------------------------------------------------------------
!
DO j=1,fa%NCADEF
!
IF (fa%NCAIND(j).EQ.krangc) THEN
  iposca=j
  GOTO 202
ENDIF
!
ENDDO
!
krep=-66
GOTO 1001
!
202 CONTINUE
!
IF (fa%CADRE(krangc)%NULCAD.NE.0) THEN
  krep=-67
  GOTO 1001
ENDIF
!**
!     3.  -  MISE A JOUR DES TABLES.
!-----------------------------------------------------------------------
!
CALL free_cadre (fa%CADRE(krangc))

fa%CADRE(krangc)%CNOMCA=' '
fa%NCADEF=fa%NCADEF-1
!
DO j=iposca,fa%NCADEF
fa%NCAIND(j)=fa%NCAIND(j+1)
ENDDO

!
krep=0
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE EVENTUELLE,
!            VIA LE sous-programme "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
!
llfata=krep.EQ.-66.OR.(krep.NE.0.AND.fa%NRFAGA.NE.2)
!
IF (fa%LFAMOP.OR.llfata) THEN
  inimes=2
  clnspr='FACTUI'
  inumer=jpniil
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KRANGC='',I4)') &
&     krep,krangc
  CALL faipar_fort                                      &
&                 (fa, inumer,inimes,krep,.false.,clmess, &
&               clnspr,clacti,.false.)
ENDIF
!
IF (lhook) CALL dr_hook('FACTUI_MT',1,zhook_handle)
END SUBROUTINE factui_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE factui64           &
&           (krep, krangc)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KRANGC                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL factui_fort             &
&           (fa, krep, krangc)

END SUBROUTINE factui64

SUBROUTINE factui             &
&           (krep, krangc)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KRANGC                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL factui_mt               &
&           (fa, krep, krangc)

END SUBROUTINE factui

SUBROUTINE factui_mt             &
&           (fa, krep, krangc)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KRANGC                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  IRANGC                                 ! IN   
! Convert arguments

irangc     = int(    krangc, jplikb)

CALL factui_fort             &
&           (fa, irep, irangc)

krep       = int(      irep, jplikm)

END SUBROUTINE factui_mt

!INTF KREP            OUT 
!INTF KRANGC        IN