facon1.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE facon1_fort                                              &
&                     (fa,  krep,   knumer, cdpref, knivau, cdsuff, &
&                      pchamp, ldcosp, cdnoma, klnoma, kvalco,      &
&                      klongd, ldundf, pundf, ydgr1tab)
USE fa_mod, ONLY : fa_com, fagr1tab
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!      Sous-programme de CODAGE d'un CHAMP HORIZONTAL destine a etre
!      ecrit sur un fichier ARPEGE/ALADIN.
!       ( COdage de (Nouvelles ?) Donnees )
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KNUMER (Entree) ==> Numero de l'unite logique;
!                CDPREF (Entree) ==> Prefixe eventuel du nom d'article;
!                KNIVAU (Entree) ==> Niveau vertical eventuel;
!                CDSUFF (Entree) ==> Suffixe eventuel du nom d'article;
!    ( Tableau ) PCHAMP (Entree) ==> Valeurs REELLES du champ a ecrire;
!                LDCOSP (Entree) ==> Vrai si le champ est represente
!                                    par des coefficients spectraux;
!                CDNOMA (Sortie) ==> Nom de l'article-champ a ecrire;
!                KLNOMA (Sortie) ==> Nombre de caracteres utiles dans
!                                    CDNOMA;
!    ( Tableau ) KVALCO (Sortie) ==> Donnees destinees a l'ecriture;
!                KLONGD (Sortie) ==> Nombre de valeurs (mots de 64 bits
!                                    en principe) a ecrire.
!                LDUNDF (Entree) ==> Vrai si ce champ a des valeurs 
!                                    indefinies
!                PUNDF  (Entree) ==> Dans le cas ou LDUNDF est vrai,
!                                    valeur non definie
!
!    Remarques:
!
!    - KVALCO doit avoir une longueur
!      suffisante pour stocker les donnees codees. Le dimensionnement
!      "tous terrains" est (2+ILCHAM), qui permet le cas echeant de
!      stocker un champ a pleine resolution sans codage effectif.
!      (ILCHAM est le nombre de valeurs du champ a ecrire)
!
!    - CDNOMA doit avoir au moins FA%JPXNOM caracteres.
!
!
TYPE(fa_com)   :: FA
TYPE(fagr1tab) :: YDGR1TAB
INTEGER (KIND=JPLIKB) KREP, KNUMER, KNIVAU, KLNOMA, KLONGD
!
REAL (KIND=JPDBLR) PCHAMP (*), PUNDF
INTEGER (KIND=JPLIKB) KVALCO (*)
!
CHARACTER CDPREF*(*), CDSUFF*(*), CDNOMA*(*)
!
INTEGER (KIND=JPLIKB) IREP, ILPRFU, ILSUFU, ILNOMU
INTEGER (KIND=JPLIKB) IRANG, INIMES
INTEGER (KIND=JPLIKB) ILPREF, ILSUFF, ILCDNO, IRANGC
INTEGER (KIND=JPLIKB) IB1PAR (fa%jplb1p), INGRIB
!
LOGICAL LLVERF, LLRLFI, LDCOSP, LLNOMU, LLNOPA, LDUNDF
!
CHARACTER CLPREF*(fa%jpxnom), CLSUFF*(fa%jpxsuf)
!
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     1.  -  CONTROLES ET INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FACON1_MT',0,zhook_handle)
llverf=.false.
llrlfi=.false.
llnomu=.false.
llnopa=.false.
ilprfu=int(len(cdpref), jplikb)
ilsufu=int(len(cdsuff), jplikb)
ilcdno=int(len(cdnoma), jplikb)
klnoma=0
CALL fanumu_fort                 &
&               (fa, knumer,irang)
!
IF (irang.EQ.0) THEN
  irep=-51
  GOTO 1001
ELSEIF (ilcdno.LT.fa%JPXNOM) THEN
  irep=-65
  GOTO 1001
ELSE
  cdnoma=' '
ENDIF
!
!         Verrouillage eventuel du fichier.
!
IF (fa%LFAMUL) CALL lfiver_fort                               &
&                              (fa%LFI, fa%FICHIER(irang)%VRFICH,'ON')
llverf=fa%LFAMUL
!
IF (fa%FICHIER(irang)%LCREAF) THEN
  irep=-85
  GOTO 1001
ENDIF
!**
!     2.  -  FABRICATION DU NOM D'ARTICLE VIA LE SOUS-PROGRAMME "FANFAR"
!            ( controles de CDPREF, KNIVAU, CDSUFF inclus )
!-----------------------------------------------------------------------
!
CALL fanfar_fort                                             &
&               (fa, irep,irang,cdpref,knivau,cdsuff,cdnoma, &
&               ib1par(6),ilprfu,ilsufu,ilnomu)
IF (irep.NE.0) GOTO 1001
llnomu=.true.
klnoma=ilnomu
!**
!     3.  -  FABRICATION DE L'ARTICLE A ECRIRE SUR LE FICHIER.
!-----------------------------------------------------------------------
!
!
!  Controle de l'homogeneite du type de rangement des coeff. spectraux
!  parmi les champs lus/ecrits: ces champs compactes avec
!  FA%NIGRIB=-1 ou 3 doivent etre ranges comme dans le modele ("verticalement"
!  soit selon des colonnes JM=cst consecutives) et contrairement si compactes
!  avec FA%NIGRIB= 0,1 ou 2.
! 
irangc=fa%FICHIER(irang)%NUCADR
IF (ldcosp) THEN
  IF (fa%FICHIER(irang)%NFGRIB.EQ.-1.OR.fa%FICHIER(irang)%NFGRIB.EQ.3) THEN
    fa%FICHIER(irang)%NRASVE=fa%FICHIER(irang)%NRASVE+1
    IF (fa%FICHIER(irang)%NRASVE.EQ.1.AND.fa%FICHIER(irang)%NRASHO.GT.0) THEN
      WRITE(fa%NULOUT,*)                                 &
&      '------------------------------------------------'
      WRITE(fa%NULOUT,*)' FACON1 :  WARNING !!!!!           '
      WRITE(fa%NULOUT,*)' Un champ de coeff. spectraux avec'
      WRITE(fa%NULOUT,*)                               &
&      ' rangement type modele va etre ecrit alors que'
      WRITE(fa%NULOUT,*)                                &
&      ' d''autres champs spec. ont un rangt different.'
      WRITE(fa%NULOUT,*)                                 &
&      '------------------------------------------------'
    ENDIF
  ELSEIF (fa%FICHIER(irang)%NFGRIB.GE.0.AND.fa%FICHIER(irang)%NFGRIB.LE.2) THEN
    fa%FICHIER(irang)%NRASHO=fa%FICHIER(irang)%NRASHO+1
    IF (fa%FICHIER(irang)%NRASHO.EQ.1.AND.fa%FICHIER(irang)%NRASVE.GT.0) THEN
      WRITE(fa%NULOUT,*)                                 &
&      '------------------------------------------------'
      WRITE(fa%NULOUT,*)                    &
&      ' FACON1 :  WARNING !!!!!           '
      WRITE(fa%NULOUT,*)                   &
&      ' Un champ de coeff. spectraux avec'
      WRITE(fa%NULOUT,*)                               &
&      ' rangt autre que celui du modele va etre ecrit'
      WRITE(fa%NULOUT,*)                                &
&      ' alors que d''autres champs ont le rangt modele'
      WRITE(fa%NULOUT,*)                                 &
&      '------------------------------------------------'
    ENDIF
  ENDIF
ENDIF
!
500 CONTINUE
!
IF (fa%FICHIER(irang)%NFGRIB.EQ.3) THEN
! Cas d'un champ qu'il faut "griber" avec GRIBEX
  CALL facodx_fort                                            &
&                 (fa,  irep, irang, cdpref, knivau, cdsuff,  &
&                  pchamp, ldcosp, kvalco, klongd,            &
&                  ldundf, pundf, ydgr1tab)
!
! Cas particulier de l'erreur GRIBEX num 710: OUTPUT ARRAY TOO SMALL
! On s'en sert pour detecter un probleme de compactage lie a ce que
! le champ compacte + les descripteurs prennent plus de place que le
! champ non compacte...
! On sort donc du compactage (FACODX) pour demander un codage sans
! compactage (FACINE) avec rangement des valeurs selon le modele:
! FA%NFGRIB=-1.
!
  IF (irep==-1710) THEN
    irep = 0
    fa%FICHIER(irang)%NFGRIB = -1
    llnopa = .true.
    GOTO 500
  ENDIF
ELSEIF (falgra(fa%FICHIER(irang)%NFGRIB)) THEN
! Cas d'un champ qu'il faut "griber" avec GRIB_API
  IF (ldcosp .AND. (falgra_sp(fa%FICHIER(irang)%NFGRIB) == 102)) THEN
    ingrib = fa%FICHIER(irang)%NFGRIB
    fa%FICHIER(irang)%NFGRIB = 2_jplikb
    CALL facine_fort                                             &
&                   (fa,  irep, irang, cdnoma(1:ilnomu), pchamp, &
&                    ldcosp, kvalco, klongd, ib1par,             &
&                    ldundf, pundf)
    fa%FICHIER(irang)%NFGRIB = ingrib
  ELSE
    CALL facgra_fort (fa,  irep, irang, cdpref, knivau, cdsuff,  &
                    & pchamp(1), ldcosp, kvalco, klongd,         &
                    & ldundf, pundf)
  ENDIF
ELSEIF (fa%FICHIER(irang)%NFGRIB.EQ.4) THEN
  CALL faccpl_fort                                            &
&                 (fa,  irep, irang, cdpref, knivau, cdsuff,  &
&                  pchamp, ldcosp, kvalco, klongd, ib1par)
ELSE
  CALL facine_fort                                             &
&                 (fa,  irep, irang, cdnoma(1:ilnomu), pchamp, &
&                  ldcosp, kvalco, klongd, ib1par,             &
&                  ldundf, pundf)
  IF (llnopa) fa%FICHIER(irang)%NFGRIB = 3
!  Le codage num 3 avait ete demande mais se revelait etre
!  plus gourmand en place que le num -1: on avait donc force
!  l'absence de compactage (-1). On revient maintenant au codage
!  num 3 pour ce cadre IRANG et les eventuels codages suivants.
!
ENDIF
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
!        Deverrouillage eventuel du fichier.
!
IF (llverf) CALL lfiver_fort                                &
&                           (fa%LFI, fa%FICHIER(irang)%VRFICH,'OFF')
!
IF (llfata) THEN
  inimes=2
ELSE
  inimes=ixnvms(irang)
ENDIF
!
IF (.NOT.llfata.AND.inimes.NE.2)  THEN 
  IF (lhook) CALL dr_hook('FACON1_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FACON1'
!
IF (ilprfu.GE.1) THEN
  ilpref=min(ilprfu,int(len(clpref), jplikb))
  clpref(1:ilpref)=cdpref(1:ilpref)
ELSE
  ilpref=8
  clpref(1:ilpref)=fa%CHAINC(:ilpref)
ENDIF
!
IF (ilsufu.GE.1) THEN
  ilsuff=min(ilsufu,int(len(clsuff), jplikb))
  clsuff(1:ilsuff)=cdsuff(1:ilsuff)
ELSE
  ilsuff=8
  clsuff(1:ilsuff)=fa%CHAINC(:ilsuff)
ENDIF
!
IF (.NOT.llnomu) THEN
  ilnomu=min(ilpref,fa%NCPCAD)
  cdnoma(1:ilnomu)=clpref(1:ilpref)
ENDIF
!
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3,         &
&       '', CDPREF='''''',A,'''''', KNIVAU='',I6,               &
&       '', CDSUFF='''''',A,'''''', LDCOSP= '',L1)')            &
&   krep,knumer,clpref(1:ilpref),knivau,clsuff(1:ilsuff),ldcosp
CALL faipar_fort                                       &
&               (fa, knumer,inimes,irep,llfata,clmess, &
&                clnspr,cdnoma(1:ilnomu),llrlfi)
!
IF (lhook) CALL dr_hook('FACON1_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"
#include "falgra.h"

END SUBROUTINE facon1_fort