facage.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE facage_fort                     &
&                     (fa,  cdnomc, ldgard )
USE fa_mod, ONLY : fa_com, jpniil
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Sous-programme servant a redefinir l'option de conservation
!     d'un cadre preexistant ( CAdre a Garder Eventuellement... )
!**
!        Arguments : CDNOMC ==> Nom symbolique du cadre;
!  (tous d'Entree)   LDGARD ==> Vrai si le cadre doit etre conserve meme
!                               apres la fermeture du dernier fichier
!                               qui s'y rattache.
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) ILCDNO, ILNOMC, J, IRANGC
INTEGER (KIND=JPLIKB) IREP, INIMES, INUMER
!
LOGICAL LLVERG, LDGARD
!
CHARACTER CDNOMC*(*)
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!
!
!**
!     0.  -  SI PREMIERE UTILISATION, APPEL AU SOUS-PROGRAMME "FARINE".
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FACAGE_MT',0,zhook_handle)
clacti=''
IF (fa%FACAGE_LLPREA) THEN
  CALL farine_fort              &
&                 (fa, 2_jplikb )
  fa%FACAGE_LLPREA=.false.
ENDIF
!**
!     1.  -  CONTROLE DE L'ARGUMENT "CDNOMC".
!-----------------------------------------------------------------------
!
llverg=.false.
ilcdno=int(len(cdnomc), jplikb)
ilnomc=1
!
IF (ilcdno.LE.0) THEN
  irep=-65
  GOTO 1001
ELSEIF (cdnomc.EQ.' ') THEN
  irep=-68
  GOTO 1001
ENDIF
!
DO j=ilcdno,1,-1
!
IF (cdnomc(j:j).NE.' ') THEN
  ilnomc=j
  GOTO 102
ENDIF
!
ENDDO
!
102 CONTINUE
!
IF (ilnomc.GT.fa%NCPCAD) THEN
  irep=-65
  GOTO 1001
ENDIF
!**
!     2.  -  RECHERCHE DU CADRE DANS LES TABLES.
!-----------------------------------------------------------------------
!
!             Verrouillage global prealable, si necessaire.
!
IF (fa%LFAMUL) CALL lfiver_fort                        &
&                              (fa%LFI, fa%VRGLAS,'ON')
llverg=fa%LFAMUL
!
CALL fanuca_fort                          &
&               (fa, cdnomc,irangc,.false.)
!
IF (irangc.EQ.0) THEN
  irep=-51
  GOTO 1001
ENDIF
!**
!     3.  -  MISE A JOUR DU NIVEAU DE CONSERVATION.
!-----------------------------------------------------------------------
!
IF (ldgard) THEN
  fa%CADRE(irangc)%NGARDE=2
ELSE
  fa%CADRE(irangc)%NGARDE=0
ENDIF
!
irep=0
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE sous-programme "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
!
!          Deverrouillage global eventuel.
!
IF (llverg) CALL lfiver_fort                         &
&                           (fa%LFI, fa%VRGLAS,'OFF')
!
llfata=irep.NE.0.AND.fa%NRFAGA.NE.2
!
IF (llfata.OR.fa%NIMSGA.EQ.2) THEN
  inimes=2
  clnspr='FACAGE'
!
  IF (irep.EQ.-65.AND.ilcdno.LE.0) THEN
    ilnomc=8
    clacti(1:ilnomc)=fa%CHAINC(:ilnomc)
  ELSE
    ilnomc=min(int(len(clacti), jplikb),ilnomc)
    clacti(1:ilnomc)=cdnomc(1:ilnomc)
  ENDIF
!
  ilnomc=min(ilnomc,fa%NCPCAD)
  WRITE (unit=clmess,                                 &
&         fmt='(''CDNOMC= '''''',A,'''''', LDGARD= '', &
&         L1,'', CODE INTERNE='',I4)')                 &
&         clacti(1:ilnomc),ldgard,irep
  inumer=jpniil
  CALL faipar_fort                                     &
&                 (fa, inumer,inimes,irep,llfata,clmess, &
&               clnspr,clacti(1:ilnomc),.false.)
ENDIF
!
IF (lhook) CALL dr_hook('FACAGE_MT',1,zhook_handle)
END SUBROUTINE facage_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE facage64           &
&           (cdnomc, ldgard)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
CHARACTER (LEN=*)      CDNOMC                                 ! IN   
LOGICAL                LDGARD                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL facage_fort               &
&           (fa, cdnomc, ldgard)

END SUBROUTINE facage64

SUBROUTINE facage             &
&           (cdnomc, ldgard)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
CHARACTER (LEN=*)      CDNOMC                                 ! IN   
LOGICAL                LDGARD                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL facage_mt                 &
&           (fa, cdnomc, ldgard)

END SUBROUTINE facage

SUBROUTINE facage_mt             &
&           (fa, cdnomc, ldgard)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
CHARACTER (LEN=*)      CDNOMC                                 ! IN   
LOGICAL                LDGARD                                 ! IN   
! Local integers
! Convert arguments


CALL facage_fort               &
&           (fa, cdnomc, ldgard)


END SUBROUTINE facage_mt

!INTF CDNOMC        IN    
!INTF LDGARD        IN