extend_grid_on_halo_cartesian.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################
      SUBROUTINE extend_grid_on_halo_cartesian(HPROGRAM,KDIM_FULL,KSIZE_FULL,KGRID_PAR,PGRID_PAR)
!     ###########################################################
!!
!!    PURPOSE
!!    -------
!!   This program extends a splitted PGD grid on the SURFEX halo
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    M.Moge                   CNRS - LA
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original     01/03/2015
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_cartesian
USE mode_extend_grid_parameter
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
!
IMPLICIT NONE
!
!*    0.1    Declaration of dummy arguments
!            ------------------------------
!
 CHARACTER(LEN=6),   INTENT(IN)    :: HPROGRAM  ! host program 
INTEGER,            INTENT(IN)    :: KDIM_FULL ! total number of points
INTEGER,            INTENT(OUT)   :: KSIZE_FULL! number of points on this processor
INTEGER,            INTENT(INOUT) :: KGRID_PAR ! size of PGRID_PAR pointer
REAL, DIMENSION(:), POINTER       :: PGRID_PAR ! parameters defining this grid
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!* original grid
REAL                            :: ZLAT0, ZLON0
INTEGER                         :: IIMAX, IJMAX
REAL, DIMENSION(KDIM_FULL)      :: ZX, ZY, ZDX, ZDY
!
!* extended grid
INTEGER                         :: IIMAX_EXTENDED, IJMAX_EXTENDED
REAL, DIMENSION(:), ALLOCATABLE :: ZX_EXTENDED, ZY_EXTENDED, ZDX_EXTENDED, ZDY_EXTENDED
!
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('EXTEND_GRID_CARTESIAN',0,zhook_handle)
!
!*    1.      Gets Parameters of the Grid
!
 CALL get_gridtype_cartesian(pgrid_par,zlat0,zlon0,           &
                            iimax,ijmax,                     &
                            zx,zy,zdx,zdy                    )
!
!
!*    2.      Splits the (pertinent) parameters of the grid
!
 CALL extend_grid_parametern0(hprogram,'CARTESIAN ','IMAX  ',iimax,iimax_extended)
 CALL extend_grid_parametern0(hprogram,'CARTESIAN ','JMAX  ',ijmax,ijmax_extended)
!
ksize_full = iimax_extended * ijmax_extended
!
ALLOCATE(zx_extended(ksize_full))
ALLOCATE(zy_extended(ksize_full))
ALLOCATE(zdx_extended(ksize_full))
ALLOCATE(zdy_extended(ksize_full))
 CALL extend_grid_parameterx1(hprogram,'CARTESIAN ','XX    ',SIZE(zx),ksize_full,iimax,ijmax,zx,zx_extended)
 CALL extend_grid_parameterx1(hprogram,'CARTESIAN ','YY    ',SIZE(zy),ksize_full,iimax,ijmax,zy,zy_extended)
 CALL extend_grid_parameterx1(hprogram,'CARTESIAN ','DX    ',SIZE(zdx),ksize_full,iimax,ijmax,zdx,zdx_extended)
 CALL extend_grid_parameterx1(hprogram,'CARTESIAN ','DY    ',SIZE(zdy),ksize_full,iimax,ijmax,zdy,zdy_extended)
!
!
!*    3.      Stores Parameters of the Grid in grid pointer
!
NULLIFY(pgrid_par)
 CALL put_gridtype_cartesian(pgrid_par,zlat0,zlon0,                  &
                            iimax_extended,ijmax_extended,                &
                            zx_extended,zy_extended,zdx_extended,zdy_extended   )
                            !
!
kgrid_par = SIZE(pgrid_par)
!
DEALLOCATE(zx_extended )
DEALLOCATE(zy_extended )
DEALLOCATE(zdx_extended)
DEALLOCATE(zdy_extended)
!
IF (lhook) CALL dr_hook('EXTEND_GRID_CARTESIAN',1,zhook_handle)
!_______________________________________________________________________________
!
END SUBROUTINE extend_grid_on_halo_cartesian