ecoclimap2_lai.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################
      SUBROUTINE ecoclimap2_lai (KYEAR)
!     #########################
!
!!**** *ECOCLIMAP2_LAI* initializes cover-field correspondance arrays
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    09/2008
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_surf_par,       ONLY : xundef
!
USE modd_data_cover,     ONLY : xdata_lai, xdata_lai_all_years, lclim_lai, &
                                  neco2_start_year, neco2_end_year  
USE modd_data_cover_par, ONLY : nvegtype, jpcover

!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER, INTENT(IN) :: KYEAR
!
REAL, DIMENSION(36) :: ZLAI
!
INTEGER :: IYEAR           ! year index
INTEGER :: JCOVER,JVEGTYPE ! loop counters on covers and decades
INTEGER :: JYEAR           ! loop counter on years
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!*       1. definition of LAI data
!           ----------------------
!
IF (lhook) CALL dr_hook('ECOCLIMAP2_LAI',0,zhook_handle)
xdata_lai(301:,:,:) = xundef
!
!*       2. if averaged LAI
!           ---------------
!
IF (lclim_lai .OR. kyear<neco2_start_year .OR. kyear>neco2_end_year) THEN
!
  DO jcover=301,jpcover
    DO jvegtype=1,nvegtype
      zlai(:) = 0.
      DO jyear=1,5
        zlai(:) = zlai(:) + xdata_lai_all_years(jcover,(jyear-1)*36+1:jyear*36,jvegtype)/5.  
      END DO
      xdata_lai(jcover,:,jvegtype) = zlai(:)
    END DO
  END DO

!
!*       3. if LAI of a specific year
!           -------------------------
ELSE
!
  iyear = kyear - neco2_start_year
  DO jcover=301,jpcover
    DO jvegtype=1,nvegtype
      xdata_lai(jcover,:,jvegtype)=xdata_lai_all_years(jcover,iyear*36+1:(iyear+1)*36,jvegtype)
    ENDDO
  ENDDO
!
END IF
IF (lhook) CALL dr_hook('ECOCLIMAP2_LAI',1,zhook_handle)
!
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE ecoclimap2_lai