disph_for_meb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!####################################################################
    SUBROUTINE disph_for_meb(PCHIL,PLAIV,PLW,PH_VEG,PZREF,PZ0_MEBV,PDISPH)
!
! typical values for nordic forest:
!     PH_VEG =   15 m
!     PCHIL =   0.12
!     PLW   =   0.02 m
!
!!****  *DISPH_FOR_MEB*
!!
!!    PURPOSE
!!    -------
!
!     Calculates the displacement height, (PDISPH) 
!     Only used for double energy balance
!
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!
!!      P. Samuelsson/S.Gollvik           * SMHI *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    12/2010
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_csts,     ONLY : xpi
USE modd_isba_par, ONLY : xlimh
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:), INTENT(IN)   :: PCHIL, PLAIV, PLW, PH_VEG, PZREF,PZ0_MEBV  
!                                     PCHIL   = Ross-Goudriaan leaf angle distr
!                                     PLAIV    = leaf area index
!                                     PLW     = leaf width
!                                     PH_VEG = height of the vegetation
!                                     PZREF   = height of the lowest model layer
!                                     PZ0_MEBV = momentum roughness for canopy
!
REAL, DIMENSION(:), INTENT(OUT)   :: PDISPH
!                                      PDISPH = displacement height
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PLAIV)) :: ZREVEG, ZCD
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*      0.3    declarations of local parameters
!
REAL, PARAMETER             :: ZUL    = 1.        ! typical windspeed within the foliage
REAL, PARAMETER             :: ZNY    = 0.15e-04  ! kinematic viscosity for air
REAL, PARAMETER             :: ZFRTOP  = 0.95     ! maximumi displacement heightfraction
!                                                   of vegetation top
!
!---------------------------------------------------------------------------------
!
!*       0.     Initialization:
!               ---------------
!
IF (lhook) CALL dr_hook('DISPH_FOR_MEB',0,zhook_handle)
!
pdisph(:) = 0.
!
! Reynolds number:
!
zreveg(:) = zul*plw(:)/zny
!
!
! Eq. B7, Sellers et.al. 1996:
!
zcd(:)    = 0.
!
WHERE(zreveg>0.)
   zcd(:) =1.328*2./sqrt(zreveg(:)) + 0.45*((1.-pchil(:))/xpi)**1.6
END WHERE
!
! Dispacement height, Eq. 20, Choudhury and Monteith, 1988:
!
pdisph(:) = 1.1*ph_veg(:)*alog(1.+(zcd(:)*plaiv(:))**0.25)
!
! SAFE! Displacement height + PZREF + XLIMH >= PH_VEG
!
pdisph(:) = max(pdisph(:),ph_veg(:)+xlimh-pzref(:))
pdisph(:) = min(pdisph(:),ph_veg(:)*zfrtop)
!
! SAFE assure that PH_VEG-DISPH > PZ0_MEBV+0.01 (see surface_air_meb)
pdisph(:)=min(pdisph(:),ph_veg(:)-pz0_mebv(:)-0.01)
!
IF (lhook) CALL dr_hook('DISPH_FOR_MEB',1,zhook_handle)
!
END SUBROUTINE disph_for_meb