diag_townn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE diag_town_n (DLO, DL, DLC, TD, HTOWN, HPROGRAM, DUP, DUPC, KMASK )
!     ######################################################################
!
!!****  *DIAG_TOWN_n * - Chooses the surface schemes for town diagnostics
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      Modified    01/2006 : sea flux parameterization.
!!      Modified    08/2009 : new diag
!!      Modified    09/2012 : new PLEI diag required by atmospheric model
!       B. decharme 04/2013 : Add EVAP and SUBL diag
!!------------------------------------------------------------------
!
USE mode_diag
!
USE modd_diag_n, ONLY : diag_t, diag_options_t
USE modd_surfex_n, ONLY : teb_diag_t
!
USE modd_surf_par,   ONLY : xundef
USE modd_csts,       ONLY : xtt, xlstt, xlvtt
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_options_t), INTENT(INOUT) :: DLO
TYPE(diag_t), INTENT(INOUT) :: DL
TYPE(diag_t), INTENT(INOUT) :: DLC
TYPE(teb_diag_t), INTENT(INOUT) :: TD
!
 CHARACTER(LEN=*), INTENT(IN) :: HTOWN
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM ! program calling surf. schemes
!
TYPE(diag_t), INTENT(INOUT) :: DUP
TYPE(diag_t), INTENT(INOUT) :: DUPC
!
INTEGER, DIMENSION(:), INTENT(IN) :: KMASK
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(DUP%XRN)) :: ZDELTA
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_TOWN_N',0,zhook_handle)
IF (htown=='TEB   ') THEN

  CALL diag(td%O, td%D, hprogram, dup, kmask)
!
!!!!! important, diagd should be computed in teb !!!!!!
!
! diag not yet inplemeted for TEB (these diag are required for the climate model)
!
! Ok with atmospheric model but LEI (latent heat of sublimation w/m2), EVAP (total evapotranspiration kg/m2/s),
! and SUBL (sublimation kg/m2/s) must by implemented in TEB as well as theirs cumulative values
! Not good if LCPL_ARP = TRUE in ISBA (ALARO)
!
  IF (SIZE(dup%XLEI)>0) THEN
    dup%XLEI (:) = xundef
    dup%XEVAP(:) = xundef
    dup%XSUBL(:) = xundef
    WHERE(dup%XLE(:)/=xundef)
      zdelta(:) = max(0.0,sign(1.0,xtt-dup%XTS(:)))
      dup%XEVAP (:) = (dup%XLE(:) * zdelta(:))/xlstt + (dup%XLE(:) * (1.0-zdelta(:)))/xlvtt
      dup%XLEI  (:) = dup%XLE(:) * zdelta(:)
      dup%XSUBL (:) = dup%XLEI(:)/xlstt
    ENDWHERE
  ENDIF
!
  IF (td%O%LSURF_BUDGETC) THEN
    CALL init_surf_bud(dupc,xundef)
    dupc%XEVAP = xundef
    dupc%XSUBL = xundef
  ENDIF
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!      
ELSE IF (htown=='FLUX  ') THEN
  CALL diag_evap(dlo, dl, dlc, hprogram, dup, dupc, kmask)          
ELSE IF (htown=='NONE  ') THEN
  CALL init_bud(td%O, dup, dupc, xundef)         
END IF
IF (lhook) CALL dr_hook('DIAG_TOWN_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_town_n