diag_surf_budget_isba.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_surf_budget_isba (PDIR_SW, PSCA_SW, PLW, K, DK )  
!     ###############################################################################
!
!!****  *DIAG_SURF_BUDGET_ISBA * - Computes diagnostics over ISBA
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     P. Le Moigne 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    04/2006
!!      Modified    08/2008 (B. Decharme) LWU diag
!!------------------------------------------------------------------
!
USE modd_diag_n, ONLY : diag_t
USE modd_isba_n, ONLY : isba_k_t
!
USE modd_csts,           ONLY : xstefan
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:,:),INTENT(IN)  :: PDIR_SW   ! direct  solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN)  :: PSCA_SW   ! diffuse solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN)   :: PLW       ! longwave radiation (on horizontal surf.)
!
TYPE(isba_k_t), INTENT(INOUT) :: K
TYPE(diag_t), INTENT(INOUT) :: DK
!
!*      0.2    declarations of local variables
!
INTEGER                          :: ISWB      ! number of SW bands
INTEGER                          :: JSWB      ! loop counter on number of SW bands
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
!
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_ISBA',0,zhook_handle)
iswb = SIZE(pdir_sw,2)
! 
!* total incoming and outgoing SW
!
DO jswb=1,iswb
  dk%XSWBD(:,jswb) = pdir_sw(:,jswb) + psca_sw(:,jswb)
  dk%XSWBU(:,jswb) = pdir_sw(:,jswb) * k%XDIR_ALB_WITH_SNOW(:,jswb) + &
                     psca_sw(:,jswb) * k%XSCA_ALB_WITH_SNOW(:,jswb) 
ENDDO
!
dk%XSWD(:) = 0.
dk%XSWU(:) = 0.
DO jswb=1,iswb
   dk%XSWD(:) = dk%XSWD(:) + dk%XSWBD(:,jswb)
   dk%XSWU(:) = dk%XSWU(:) + dk%XSWBU(:,jswb)
ENDDO
!
!*incoming outgoing LW
!
!Wrong old diag : LWU=EMIS*STEFAN*Ts**4 + (1.-EMIS)*LW
!Due to e_budget.f90 linearization, LWU can not be calculated using actual Ts
!
dk%XLWD(:) = plw(:)
dk%XLWU(:) = dk%XSWD(:) - dk%XSWU(:) + dk%XLWD(:) - dk%XRN(:)
!
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_ISBA',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_surf_budget_isba