coupling_flake_orographyn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###############################################################################
SUBROUTINE coupling_flake_orography_n (FM, DST, SLT, HPROGRAM, HCOUPLING,                &
                                       PTSTEP, KYEAR, KMONTH, KDAY, PTIME, KI, KSV, KSW, &
                                       PTSUN, PZENITH, PZENITH2, PAZIM, PZREF, PUREF,    &
                                       PZS, PU, PV, PQA, PTA, PRHOA, PSV, PCO2, HSV,     &
                                       PRAIN, PSNOW, PLW, PDIR_SW, PSCA_SW, PSW_BANDS,   &
                                       PPS, PPA, PSFTQ, PSFTH, PSFTS, PSFCO2, PSFU, PSFV,&
                                       PTRAD, PDIR_ALB, PSCA_ALB, PEMIS, PTSURF, PZ0,    &
                                       PZ0H, PQSURF, PPEW_A_COEF, PPEW_B_COEF,           &
                                       PPET_A_COEF, PPEQ_A_COEF, PPET_B_COEF,            &
                                       PPEQ_B_COEF, HTEST                            )  
!     ###############################################################################
!
!!****  *COUPLING_FLAKE_OROGRAPHY_n * - Modifies the input forcing if not
!!           initially at lake level
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      B. Decharme   2008   reset the subgrid topographic effect on the forcing
!!      Modified    09/2012  : J. Escobar , SIZE(PTA) not allowed without-interface , replace by KI
!!      V.Masson     10/2013 Adds min and max 2m parameters
!!      P. Le Moigne 04/2013 New diag, new coupling variables
!!      B. Decharme  04/2013 New diag, new coupling variables
!!                           improve forcing vertical shift
!!-------------------------------------------------------------
!
!
!
USE modd_surfex_n, ONLY : flake_model_t
!
USE modd_dst_n, ONLY : dst_t
USE modd_slt_n, ONLY : slt_t
!
USE modd_surf_par,         ONLY : xundef
USE modd_csts,             ONLY : xcpd, xrd, xp00
!
USE modd_surf_atm, ONLY : lvertshift
!
USE modi_forcing_vert_shift
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_coupling_flake_sbl_n
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(flake_model_t), INTENT(INOUT) :: FM
TYPE(dst_t), INTENT(INOUT) :: DST
TYPE(slt_t), INTENT(INOUT) :: SLT
!
 CHARACTER(LEN=6),    INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=1),    INTENT(IN)  :: HCOUPLING ! type of coupling
                                              ! 'E' : explicit
                                              ! 'I' : implicit
INTEGER,             INTENT(IN)  :: KYEAR     ! current year (UTC)
INTEGER,             INTENT(IN)  :: KMONTH    ! current month (UTC)
INTEGER,             INTENT(IN)  :: KDAY      ! current day (UTC)
REAL,                INTENT(IN)  :: PTIME     ! current time since midnight (UTC, s)
INTEGER,             INTENT(IN)  :: KI        ! number of points
INTEGER,             INTENT(IN)  :: KSV       ! number of scalars
INTEGER,             INTENT(IN)  :: KSW       ! number of short-wave spectral bands
REAL, DIMENSION(KI), INTENT(IN)  :: PTSUN     ! solar time                    (s from midnight)
REAL,                INTENT(IN)  :: PTSTEP    ! atmospheric time-step                 (s)
REAL, DIMENSION(KI), INTENT(IN)  :: PZREF     ! height of T,q forcing                 (m)
REAL, DIMENSION(KI), INTENT(IN)  :: PUREF     ! height of wind forcing                (m)
!
REAL, DIMENSION(KI), INTENT(IN)  :: PTA       ! air temperature forcing               (K)
REAL, DIMENSION(KI), INTENT(IN)  :: PQA       ! air humidity forcing                  (kg/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: PRHOA     ! air density                           (kg/m3)
REAL, DIMENSION(KI,KSV),INTENT(IN) :: PSV     ! scalar variables
!                                             ! chemistry:   first char. in HSV: '#'  (molecule/m3)
!                                             !
 CHARACTER(LEN=6), DIMENSION(KSV),INTENT(IN):: HSV  ! name of all scalar variables
REAL, DIMENSION(KI), INTENT(IN)  :: PU        ! zonal wind                            (m/s)
REAL, DIMENSION(KI), INTENT(IN)  :: PV        ! meridian wind                         (m/s)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: PDIR_SW ! direct  solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: PSCA_SW ! diffuse solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KSW),INTENT(IN)  :: PSW_BANDS ! mean wavelength of each shortwave band (m)
REAL, DIMENSION(KI), INTENT(IN)  :: PZENITH   ! zenithal angle at t      (radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: PZENITH2  ! zenithal angle at t+1    (radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: PAZIM     ! azimuthal angle      (radian from North, clockwise)
REAL, DIMENSION(KI), INTENT(IN)  :: PLW       ! longwave radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI), INTENT(IN)  :: PPS       ! pressure at atmospheric model surface (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: PPA       ! pressure at forcing level             (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: PZS       ! atmospheric model orography           (m)
REAL, DIMENSION(KI), INTENT(IN)  :: PCO2      ! CO2 concentration in the air          (kg/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: PSNOW     ! snow precipitation                    (kg/m2/s)
REAL, DIMENSION(KI), INTENT(IN)  :: PRAIN     ! liquid precipitation                  (kg/m2/s)
!
!
REAL, DIMENSION(KI), INTENT(OUT) :: PSFTH     ! flux of heat                          (W/m2)
REAL, DIMENSION(KI), INTENT(OUT) :: PSFTQ     ! flux of water vapor                   (kg/m2/s)
REAL, DIMENSION(KI), INTENT(OUT) :: PSFU      ! zonal momentum flux                   (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: PSFV      ! meridian momentum flux                (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: PSFCO2    ! flux of CO2                           (m/s*kg_CO2/kg_air)
REAL, DIMENSION(KI,KSV),INTENT(OUT):: PSFTS   ! flux of scalar var.                   (kg/m2/s)
!
REAL, DIMENSION(KI), INTENT(OUT) :: PTRAD     ! radiative temperature                 (K)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: PDIR_ALB! direct albedo for each spectral band  (-)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: PSCA_ALB! diffuse albedo for each spectral band (-)
REAL, DIMENSION(KI), INTENT(OUT) :: PEMIS     ! emissivity                            (-)
!
REAL, DIMENSION(KI), INTENT(OUT) :: PTSURF    ! surface effective temperature         (K)
REAL, DIMENSION(KI), INTENT(OUT) :: PZ0       ! roughness length for momentum         (m)
REAL, DIMENSION(KI), INTENT(OUT) :: PZ0H      ! roughness length for heat             (m)
REAL, DIMENSION(KI), INTENT(OUT) :: PQSURF    ! specific humidity at surface          (kg/kg)
!
REAL, DIMENSION(KI), INTENT(IN) :: PPEW_A_COEF! implicit coefficients
REAL, DIMENSION(KI), INTENT(IN) :: PPEW_B_COEF! needed if HCOUPLING='I'
REAL, DIMENSION(KI), INTENT(IN) :: PPET_A_COEF
REAL, DIMENSION(KI), INTENT(IN) :: PPEQ_A_COEF
REAL, DIMENSION(KI), INTENT(IN) :: PPET_B_COEF
REAL, DIMENSION(KI), INTENT(IN) :: PPEQ_B_COEF
 CHARACTER(LEN=2),    INTENT(IN) :: HTEST ! must be equal to 'OK'
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(KI)  ::  ZPEQ_B_COEF   ! 1st explicit coefficient
REAL, DIMENSION(KI)  ::  ZPET_B_COEF   ! 2nd explicit coefficient
!
REAL, DIMENSION(KI)  :: ZTA    ! Temperature at forcing height above surface orography
REAL, DIMENSION(KI)  :: ZPA    ! Pressure    at forcing height above surface orography
REAL, DIMENSION(KI)  :: ZPS    ! Pressure    at surface orography
REAL, DIMENSION(KI)  :: ZQA    ! Humidity    at forcing height above surface orography
REAL, DIMENSION(KI)  :: ZRHOA  ! Density     at forcing height above surface orography
REAL, DIMENSION(KI)  :: ZLW    ! LW rad      at forcing height above surface orography
REAL, DIMENSION(KI)  :: ZRAIN  ! Rainfall    at forcing height above surface orography
REAL, DIMENSION(KI)  :: ZSNOW  ! Snowfall    at forcing height above surface orography
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
! Preliminaries:
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('COUPLING_FLAKE_OROGRAPHY_N',0,zhook_handle)
!
zpeq_b_coef(:) = ppeq_b_coef(:)
zpet_b_coef(:) = ppet_b_coef(:)
!
IF(lvertshift)THEN
!
  zta(:) = xundef
  zqa(:) = xundef
  zps(:) = xundef
  zpa(:) = xundef
  zrhoa(:) = xundef
  zlw(:) = xundef
  zrain(:) = xundef
  zsnow(:) = xundef
!        
   CALL forcing_vert_shift(pzs,fm%F%XZS,pta,pqa,ppa,prhoa,plw,prain,psnow,&
                           zta,zqa,zpa,zrhoa,zlw,zrain,zsnow         )
!
   zps(:) = zpa(:) + (pps(:) - ppa(:))
!
  IF (hcoupling=='I') THEN
    zpeq_b_coef = ppeq_b_coef + zqa - pqa
    zpet_b_coef = ppet_b_coef + zta/(zpa/xp00)**(xrd/xcpd) - pta/(ppa/xp00)**(xrd/xcpd)
  ENDIF
!
ELSE
!
  zta(:) = pta(:)
  zqa(:) = pqa(:)
  zps(:) = pps(:)
  zpa(:) = ppa(:)
  zrhoa(:) = prhoa(:)
  zlw(:) = plw(:)
  zrain(:) = prain(:)
  zsnow(:) = psnow(:)
!
ENDIF
!
 CALL coupling_flake_sbl_n(fm%SB, fm%CHF, fm%DFO, fm%DF, fm%DFC, fm%DMF, fm%F, dst, slt,     &
                           hprogram, hcoupling, ptstep, kyear, kmonth, kday, ptime,              &
                           ki, ksv, ksw, ptsun, pzenith, pzenith2, pazim, pzref, puref, pu, pv,  &
                           zqa, zta, zrhoa, psv, pco2, hsv, zrain, zsnow, zlw, pdir_sw, psca_sw, &
                           psw_bands, zps, zpa, psftq, psfth, psfts, psfco2, psfu, psfv,         &
                           ptrad, pdir_alb, psca_alb, pemis, ptsurf, pz0, pz0h, pqsurf,          &
                           ppew_a_coef, ppew_b_coef, ppet_a_coef, ppeq_a_coef, zpet_b_coef,      &
                           zpeq_b_coef, htest )
!
IF (lhook) CALL dr_hook('COUPLING_FLAKE_OROGRAPHY_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE coupling_flake_orography_n