ch_init_depconst.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE ch_init_depconst(HPROGRAM,HCHEM_SURF_FILE,KLUOUT,HSV)
!!    ##################################################
!!
!!*** *CH_INIT_DEPCONST*
!!
!!    PURPOSE
!!    -------
!      Read Henry Specific constant,  Molecular Mass and Biological reactivity
!!     factor.
!!     
!!
!!**  METHOD
!!    ------
!
!!    Chemical constant will be read from
!!    the general purpose input file . 
!!
!!       chemical molecular diffusivity MASS_MOL
!!       molecular reactivity factor REA_FACT     
!!       molecular effective Henry constant HENRY_SP
!!
!!
!!    REFERENCE
!!    ---------
!!    
!!    AUTHOR
!!    ------
!!    P. Tulet    *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!    Original 16/02/01

!!    EXTERNAL
!!    --------
!!
! open the general purpose ASCII input file
USE modi_open_namelist
USE modi_close_namelist
!
USE modi_ch_open_inputb
USE modd_ch_surf
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! Program name
 CHARACTER(LEN=28), INTENT(IN)  :: HCHEM_SURF_FILE ! ascii file for chemistry aggregation
INTEGER,                  INTENT(IN)  :: KLUOUT   ! output listing channel
 CHARACTER(LEN=*), DIMENSION(:),  INTENT(IN)  :: HSV      ! name of chemical species
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=40) :: YFORMAT    
                          ! format for input
 CHARACTER(LEN=40) :: YOUTFORMAT = '(A32,2E15.5)'
                          ! format for output
!
INTEGER :: IMASS          ! number of molecular diffusivity to be read
 CHARACTER(LEN=40), DIMENSION(:), ALLOCATABLE :: YMASSMOLNAME !species names
REAL             , DIMENSION(:), ALLOCATABLE :: ZMASSMOLVAL
                          ! molecular diffusivity value
!
INTEGER :: IREACT         ! number of chemical reactivity factor to be read
 CHARACTER(LEN=40), DIMENSION(:), ALLOCATABLE :: YREACTNAME !species names
REAL             , DIMENSION(:), ALLOCATABLE :: ZREACTVAL 
                          ! chemical reactivity factor value
!
INTEGER :: IHENRY         ! number of chemical Henry constant to be read
 CHARACTER(LEN=40), DIMENSION(:), ALLOCATABLE :: YHENRYNAME !species names
 character(len=50) :: yname
REAL             , DIMENSION(:,:), ALLOCATABLE :: ZHENRYVAL
                          !chemical Henry constant value
!
INTEGER :: ICH      ! unit of input chemical file
!
INTEGER :: JI, JN, JNREAL ! loop control variables
INTEGER :: INACT          ! array pointer
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!*       1.    ALLOCATE FIELD
!              --------------
!
IF (lhook) CALL dr_hook('CH_INIT_DEPCONST',0,zhook_handle)
IF(.NOT. ALLOCATED(xsrealmassmolval)) ALLOCATE( xsrealmassmolval(SIZE(hsv,1)) )
IF(.NOT. ALLOCATED(xsrealreactval)  ) ALLOCATE( xsrealreactval(SIZE(hsv,1)) )
IF(.NOT. ALLOCATED(xsrealhenryval)  ) ALLOCATE( xsrealhenryval(SIZE(hsv,1),2) )
!
 CALL open_namelist(hprogram,ich,hfile=hchem_surf_file)
!
!*       2.  read chemical molecular diffusivity MASS_MOL
!
! open input file
  WRITE(kluout,*) &
       "CH_INIT_CONST: reading  molar mass" 
  CALL ch_open_inputb("MASS_MOL", ich, kluout)
!
! read number of molecular diffusivity IMASS
  READ(ich, *) imass
  WRITE(kluout,*) "number of molecular diffusivity: ", imass
!
! read data input format
  READ(ich,"(A)") yformat
  WRITE(kluout,*) "input format is: ", yformat
!
! allocate fields
  ALLOCATE(ymassmolname(imass))
  ALLOCATE(zmassmolval(imass))
!
! read molecular diffusivity
  DO ji = 1, imass
    READ(ich,yformat) ymassmolname(ji), zmassmolval(ji)
    WRITE(kluout,yformat) ymassmolname(ji), zmassmolval(ji)
  END DO
!
!
    WRITE(kluout,'(A)') '----------------------------------------------------'
    WRITE(kluout,'(A)') 'MASS_MOL'
    WRITE(kluout,'(A)') 'molecular mass (in g/mol) for molecular diffusion'
    WRITE(kluout,'(I4)') SIZE(hsv,1)
    WRITE(kluout,'(A)') youtformat
!
  xsrealmassmolval(:) = 50. ! default molecular mass 
  DO jnreal = 1, SIZE(hsv,1)
    inact = 0
    search_loop3 : DO jn = 1, imass
      IF (hsv(jnreal) .EQ. ymassmolname(jn)) THEN
        inact = jn
        EXIT search_loop3
      END IF
    END DO search_loop3
    IF (inact .NE. 0) xsrealmassmolval(jnreal) = zmassmolval(inact)
      WRITE(kluout,youtformat) hsv(jnreal), xsrealmassmolval(jnreal)
  END DO
!
!
!-----------------------------------------------------------------------------
!
!*       3.  read molecular reactivity factor REA_FACT
!
! open input file
   WRITE(kluout,*) &
       "CH_INIT_CONST: reading  reactivity factor "  
  CALL ch_open_inputb("REA_FACT", ich, kluout)
!
! read number of molecular diffusivity IREACT
  READ(ich, *) ireact
  WRITE(kluout,*) "number of reactivity factor : ", ireact
!
! read data input format
  READ(ich,"(A)") yformat
  WRITE(kluout,*) "input format is: ", yformat
!
! allocate fields
  ALLOCATE(yreactname(ireact))
  ALLOCATE(zreactval(ireact))
! read reactivity factor 
  DO ji = 1, ireact
    READ(ich,yformat) yreactname(ji), zreactval(ji)
    WRITE(kluout,yformat) yreactname(ji), zreactval(ji)
  END DO
!
    WRITE(kluout,'(A)') '----------------------------------------------------'
    WRITE(kluout,'(A)') 'REA_FACT'
    WRITE(kluout,'(A)') 'reactivity factor'
    WRITE(kluout,'(I4)') SIZE(hsv,1)
    WRITE(kluout,'(A)') youtformat
!    
  xsrealreactval(:) = 0.0 ! default (high surface resistance)
  DO jnreal = 1, SIZE(hsv,1)
    inact = 0
    search_loop4 : DO jn = 1, ireact
      IF (hsv(jnreal) .EQ. yreactname(jn)) THEN
        inact = jn
        EXIT search_loop4
      END IF
    END DO search_loop4
    IF (inact .NE. 0) xsrealreactval(jnreal) = zreactval(inact)
      WRITE(kluout,youtformat) hsv(jnreal), xsrealreactval(jnreal)
  END DO
!
!
!-----------------------------------------------------------------------------
!
!*       4.  read molecular effective  Henry constant HENRY_SP
!
! open input file
  WRITE(kluout,*) &
       "CH_INIT_CONST: reading effective Henry constant", &
       " and its temperature correction "  
  CALL ch_open_inputb("HENRY_SP", ich, kluout)
!
! read number of molecular diffusivity IHENRY
  READ(ich, *) ihenry
  WRITE(kluout,*) "number of reactivity factor : ", ihenry
!
! read data input format
  READ(ich,"(A)") yformat
  WRITE(kluout,*) "input format is: ", yformat
!
! allocate fields
  ALLOCATE(yhenryname(ihenry))
  ALLOCATE(zhenryval(ihenry,2))
!
! read reactivity factor 
  DO jnreal = 1, ihenry
    READ(ich,yformat) yhenryname(jnreal), zhenryval(jnreal,1),&
                             zhenryval(jnreal,2)  
    WRITE(kluout,yformat) yhenryname(jnreal), zhenryval(jnreal,1),&
                             zhenryval(jnreal,2)  
  END DO
!
  WRITE(kluout,'(A)') '----------------------------------------------------'
  WRITE(kluout,'(A)') 'HENRY_SP'
  WRITE(kluout,'(A)') 'Henrys law constants factor / exponent'
  WRITE(kluout,'(I4)') SIZE(hsv,1)
  WRITE(kluout,'(A)') youtformat
!  
  xsrealhenryval(:,1) = 1e-8 ! no deposition; low Henry constant
  xsrealhenryval(:,2) = 0. ! 
  DO jnreal = 1, SIZE(hsv,1)
    inact = 0
    search_loop5 : DO jn = 1, ihenry
      IF (hsv(jnreal) .EQ. yhenryname(jn)) THEN
        inact = jn
        EXIT search_loop5
      END IF
    END DO search_loop5
    IF (inact .NE. 0) xsrealhenryval(jnreal,1) = zhenryval(inact,1)
    IF (inact .NE. 0) xsrealhenryval(jnreal,2) = zhenryval(inact,2)
    WRITE(kluout,youtformat) hsv(jnreal), &
                      xsrealhenryval(jnreal,1),&
                      xsrealhenryval(jnreal,2)  
  END DO

 CALL close_namelist(hprogram,ich)

IF (lhook) CALL dr_hook('CH_INIT_DEPCONST',1,zhook_handle)
!
END SUBROUTINE ch_init_depconst