carbon_evol.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE carbon_evol(IO, KK, PK, PEK, DEK, PTSTEP, PRHOA, PRESP_BIOMASS_INST )
!   ###############################################################
!!****  *CARBON EVOL*
!!
!!    PURPOSE
!!    -------
!!
!!    Diagnoses respiration carbon fluxes and performs the time evolution of 
!!    carbon pools in the case of 'CNT' option (ISBA-CC) 
!!            
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      Gibelin et al. 2008, AFM
!!        Modelling energy and CO2 fluxes with an interactive vegetation land surface model -
!!        Evaluation at high and middle latitudes.
!!      
!!    AUTHOR
!!    ------
!!
!!      A.L. Gibelin       * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    22/06/09
!!      S.QUEGUINER 09/2011 Cas 'DEF'- condition si LAI=UNDEF->ZRESP_SOIL_TOT=0
!!      C.   Delire 04/2012 : spinup soil carbon
!!      B. Decharme 05/2012 : Optimization and ISBA-DIF coupling
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_k_t, isba_p_t, isba_pe_t
USE modd_diag_evap_isba_n, ONLY : diag_evap_isba_t
!
USE modd_co2v_par,       ONLY : xmc, xmco2, xpcco2
USE modd_csts,           ONLY : xday, xtt
USE modd_surf_par,       ONLY : xundef
!
USE modi_control_moist_func
USE modi_control_temp_func
USE modi_carbon_litter
USE modi_carbon_soil

!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_k_t), INTENT(INOUT) :: KK
TYPE(isba_p_t), INTENT(INOUT) :: PK
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
TYPE(diag_evap_isba_t), INTENT(INOUT) :: DEK
!
REAL, INTENT(IN)             :: PTSTEP                 ! time step
REAL, DIMENSION(:), INTENT(IN)        :: PRHOA         ! air density (kg/m3)
REAL, DIMENSION(:,:), INTENT(IN)      :: PRESP_BIOMASS_INST ! instantaneous respiration of biomass (kgCO2/kgair m/s)
!
!*      0.2    declarations of local variables
!  
REAL, PARAMETER                  :: ZCOEF1 = 4.4e-8
REAL, PARAMETER                  :: ZCOEF2 = 13.5
REAL, PARAMETER                  :: ZCOEF3 = 5.4
REAL, PARAMETER                  :: ZCOEF4 = 0.1
REAL, PARAMETER                  :: ZCOEF5 = 25.0
!
REAL, PARAMETER                  :: ZDTOP  = 0.1   !Top depth m
REAL, PARAMETER                  :: ZDSUB  = 1.0   !Sub depth m
!
REAL, DIMENSION(SIZE(PEK%XTG,1))     :: ZRESP_SOIL_TOT     ! total soil respiration (kgCO2/kgair m/s)
REAL, DIMENSION(SIZE(PEK%XTG,1))     :: ZRESP_AUTO_ABOVE   ! total above ground biomass respiration (kgCO2/kgair m/s)
REAL, DIMENSION(SIZE(PEK%XTG,1))     :: ZRESP_HETERO       ! total heterotrophic respiration (kgCO2/kgair m/s)
!
!
REAL, DIMENSION(SIZE(PEK%XSOILCARB,1),SIZE(PEK%XSOILCARB,2)) :: ZSOILCARBON_INPUT
!                  quantity of carbon going into carbon pools 
!                  from litter decomposition (gC/m2/day)
!
REAL, DIMENSION(SIZE(PEK%XSOILCARB,1)) :: ZRESP_HETERO_DAY_LITTER 
!                  litter heterotrophic respiration (gC/m2/day)
REAL, DIMENSION(SIZE(PEK%XSOILCARB,1)) :: ZRESP_HETERO_DAY_SOIL   
!                  soil heterotrophic respiration (gC/m2/day)
!
REAL, DIMENSION(SIZE(PEK%XLIGNIN_STRUC,1),SIZE(PEK%XLIGNIN_STRUC,2)) :: ZCONTROL_MOIST, &
                                                                ZCONTROL_TEMP
!                  ZCONTROL_MOIST = moisture control of heterotrophic respiration
!                  ZCONTROL_TEMP = temperature control of heterotrophic respiration
!
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZTG_TOP     ! Top soil temperature   (C)
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZTG_SUB     ! Sub soil temperature   (C)
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZSAND_SUB   ! Sub soil sand fraction (-)
!
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZMOIST_TOP  ! Top soil moisture index (-)
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZMOIST_SUB  ! Sub soil moisture index (-)
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZSAT_TOP    ! Top soil saturated index(-)
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZSAT_SUB    ! Sub soil saturated index(-)
!
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZDG_TOP     ! Top soil depth for DIF (m)
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZDG_SUB     ! Sub soil depth for DIF (m)
!
REAL, DIMENSION(SIZE(PEK%XTG,1),SIZE(PEK%XTG,2))  :: ZWGHT_TOP   ! Weight top for DIF (m)    
REAL, DIMENSION(SIZE(PEK%XTG,1),SIZE(PEK%XTG,2))  :: ZWGHT_SUB   ! Weight sub for DIF (m)  
!
REAL, DIMENSION(SIZE(PEK%XTG,1))              :: ZWORK  ! work array
!
REAL     :: ZMOISTL, ZSATL, ZLOG2
!
INTEGER  :: JNBIOMASS
INTEGER  :: ITCSPIN
!
INTEGER  :: INI, INL, JI, JL, IDEKTH, INBIOMASS
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!*      1.     Preliminaries
!              -------------
!
IF (lhook) CALL dr_hook('CARBON_EVOL',0,zhook_handle)
!
dek%XRESP_AUTO    = 0.0
dek%XRESP_ECO     = 0.0
!
ini=SIZE(pek%XTG,1)
inl=SIZE(pek%XTG,2)
inbiomass=SIZE(presp_biomass_inst,2)
!
zresp_soil_tot(:)          = xundef
zresp_auto_above(:)        = xundef
zresp_hetero(:)            = xundef
zsoilcarbon_input(:,:)     = xundef
zresp_hetero_day_litter(:) = xundef
zresp_hetero_day_soil(:)   = xundef
zcontrol_moist(:,:)        = xundef
zcontrol_temp(:,:)         = xundef
zwght_top(:,:)             = xundef
zwght_sub(:,:)             = xundef
!
ztg_top(:) = 0.0
ztg_sub(:) = 0.0
!
zlog2  = log(2.0)
!
! convert soil temperature from K to C (over 1m depth for DIF)
!
IF(io%CISBA/='DIF')THEN        
  ztg_top(:) = pek%XTG(:,1)-xtt  
  ztg_sub(:) = pek%XTG(:,2)-xtt  
ELSE       
  DO ji=1,ini
     idekth=pk%NWG_LAYER(ji)
     zdg_top(ji)=min(zdtop,pk%XDG(ji,idekth))
     zdg_sub(ji)=min(zdsub,pk%XDG(ji,idekth))
  ENDDO  
  DO jl=1,inl
     DO ji=1,ini     
        zwght_top(ji,jl)=min(pk%XDZG(ji,jl),max(0.0,zdg_top(ji)-pk%XDG(ji,jl)+pk%XDZG(ji,jl)))
        zwght_sub(ji,jl)=min(pk%XDZG(ji,jl),max(0.0,zdg_sub(ji)-pk%XDG(ji,jl)+pk%XDZG(ji,jl)))        
        ztg_top(ji)=ztg_top(ji)+(pek%XTG(ji,jl)-xtt)*zwght_top(ji,jl)/zdg_top(ji)
        ztg_sub(ji)=ztg_sub(ji)+(pek%XTG(ji,jl)-xtt)*zwght_sub(ji,jl)/zdg_sub(ji)
     ENDDO
  ENDDO 
ENDIF
!
!
!*      2.     Autotrophic respiration
!              -----------------------
!
zresp_auto_above(:)=0.
!
IF (io%CPHOTO=='NIT') THEN
!        
  DO jnbiomass=1,2
    zresp_auto_above(:) = zresp_auto_above(:) + presp_biomass_inst(:,jnbiomass)
  ENDDO
!  
ELSE IF (io%CPHOTO=='NCB') THEN
!        
  DO jnbiomass=1,3
    zresp_auto_above(:) = zresp_auto_above(:) + presp_biomass_inst(:,jnbiomass)
  ENDDO
!  
ELSE IF (io%CPHOTO=='AST') THEN
!        
  zresp_auto_above(:) = presp_biomass_inst(:,1)
!  
ENDIF
!
DO jnbiomass=1,inbiomass
   dek%XRESP_AUTO(:) = dek%XRESP_AUTO (:) + presp_biomass_inst(:,jnbiomass)
ENDDO
!
!
!*      3.     Soil and ecosystem respiration
!              ------------------------------
!
IF (io%CRESPSL == 'DEF') THEN
!
   zwork(:)=0.0
!   
   IF(io%CISBA/='DIF')THEN            
      zwork(:) = pek%XWG(:,1)  
   ELSE
      DO jl=1,inl
         DO ji=1,ini        
            zwork(ji)=zwork(ji)+pek%XWG(ji,jl)*zwght_top(ji,jl)/zdg_top(ji)
         ENDDO
      ENDDO  
   ENDIF
!
! Soil respiration from Norman et al 1992 (kgCO2/kgair m/s)
!
  WHERE (pek%XLAI(:) == xundef)
    zresp_soil_tot(:) = 0.0
  ELSEWHERE
! Before optimization = (ZCOEF1/PRHOA)*(ZCOEF2+ZCOEF3*PEK%XLAI(:))*PEK%XWG(:,1)*2.**(ZCOEF4*(ZT2(:)-ZCOEF5))        
    zresp_soil_tot(:) = (zcoef1/prhoa)*(zcoef2+zcoef3*pek%XLAI(:)) * &
                       zwork(:)*exp(zlog2*(zcoef4*(ztg_sub(:)-zcoef5)))
  ENDWHERE
!
! RESP_ECO is diagnosed from RESP_SOIL_TOT and RESP_AUTO_ABOVE
!
  dek%XRESP_ECO(:) = zresp_soil_tot(:) + zresp_auto_above(:)
!  
ELSE IF (io%CRESPSL == 'PRM') THEN
!
   zwork(:)=0.0
!   
   IF(io%CISBA/='DIF')THEN            
      zwork(:) = pek%XWG(:,1)  
   ELSE
      DO jl=1,inl
         DO ji=1,ini        
            zwork(ji)=zwork(ji)+min(1.0,pek%XWG(ji,jl)/kk%XWFC(ji,jl))*zwght_top(ji,jl)/zdg_top(ji)
         ENDDO
      ENDDO  
   ENDIF
!
! Ecosystem respiration : Q10 model following Albergel et al. 2009 for SMOSREX
! (kgCO2/kgair m/s)
! RESP_ECO is directly calculated by the parameterization
!
! Before optimization 
! DEK%XRESP_ECO(:) = PK%XRE25(:)/PRHOA(:) * MIN(PEK%XWG(:,1)/KK%XWFC(:),1.)*2.**(ZCOEF4*(ZT2(:)-ZCOEF5))        
  dek%XRESP_ECO(:) = pk%XRE25(:)/prhoa(:) * zwork(:)*exp(zlog2*(zcoef4*(ztg_sub(:)-zcoef5)))
!
ELSE IF (io%CRESPSL == 'CNT') THEN
!
! Heterotrophic respiration following CENTURY model from Gibelin et al. 2008
!
  zmoist_top(:)=0.0
  zsat_top(:)=0.0
  zmoist_sub(:)=0.0
  zsat_sub(:)=0.0
  zsand_sub(:)=0.0
!
  IF(io%CISBA/='DIF')THEN
!          
    zmoist_top(:) = min(1.0,max(0.0,(pek%XWG(:,1)-kk%XWWILT(:,1))/(kk%XWFC (:,1)-kk%XWWILT(:,1))))
    zsat_top(:) = min(1.0,max(0.0,(pek%XWG(:,1)-kk%XWFC  (:,1))/(kk%XWSAT(:,1)-kk%XWFC  (:,1))))
    zmoist_sub(:) = min(1.0,max(0.0,(pek%XWG(:,2)-kk%XWWILT(:,2))/(kk%XWFC (:,2)-kk%XWWILT(:,2))))
    zsat_sub(:) = min(1.0,max(0.0,(pek%XWG(:,2)-kk%XWFC  (:,2))/(kk%XWSAT(:,2)-kk%XWFC  (:,2))))
!    
    zsand_sub(:) = kk%XSAND (:,2)
!    
  ELSE
!          
    DO jl=1,inl
       DO ji=1,ini
!       
          zmoistl=min(1.0,max(0.0,(pek%XWG(ji,jl)-kk%XWWILT(ji,jl))/(kk%XWFC (ji,jl)-kk%XWWILT(ji,jl))))
          zsatl  =min(1.0,max(0.0,(pek%XWG(ji,jl)-kk%XWFC  (ji,jl))/(kk%XWSAT(ji,jl)-kk%XWFC  (ji,jl)))) 
! 
          zmoist_top(ji)=zmoist_top(ji)+zmoistl*zwght_top(ji,jl)/zdg_top(ji)
          zsat_top(ji)=zsat_top(ji)+zsatl  *zwght_top(ji,jl)/zdg_top(ji)
          zmoist_sub(ji)=zmoist_sub(ji)+zmoistl*zwght_sub(ji,jl)/zdg_sub(ji)
          zsat_sub(ji)=zsat_sub(ji)+zsatl  *zwght_sub(ji,jl)/zdg_sub(ji)          
!
          zsand_sub(ji)=zsand_sub(ji)+kk%XSAND(ji,jl)*zwght_sub(ji,jl)/zdg_sub(ji)
!          
       ENDDO
    ENDDO 
!    
  ENDIF
!
  zcontrol_temp(:,1) = control_temp_func(ztg_top(:))
  zcontrol_temp(:,2) = control_temp_func(ztg_sub(:))
  zcontrol_moist(:,1) = control_moist_func(zmoist_top(:),zsat_top(:))
  zcontrol_moist(:,2) = control_moist_func(zmoist_sub(:),zsat_sub(:))
!
  CALL carbon_litter (ptstep, pk%XTURNOVER, pek%XLITTER, pek%XLIGNIN_STRUC, &
                     zcontrol_temp, zcontrol_moist, zresp_hetero_day_litter,zsoilcarbon_input)  
!
  DO itcspin = 1,io%NSPINS
     CALL carbon_soil (ptstep, zsand_sub, zsoilcarbon_input, zcontrol_temp,&
                       zcontrol_moist, pek%XSOILCARB, zresp_hetero_day_soil   )  
  ENDDO
!
! Transform units : gC/m2/day -> kgCO2/kgair m/s
!
  zresp_hetero(:) = (zresp_hetero_day_litter(:) + zresp_hetero_day_soil(:)) &
                    * (xmco2/xmc) / (1000. * prhoa(:)* xday)  
!  
! RESP_ECO is diagnosed from RESP_HETERO and RESP_AUTO
!
  dek%XRESP_ECO(:) = zresp_hetero(:) + dek%XRESP_AUTO(:)
!  
ENDIF
!
IF (lhook) CALL dr_hook('CARBON_EVOL',1,zhook_handle)
!
!-----------------------------------------------------------------
!
END SUBROUTINE carbon_evol