canopy.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE canopy(KI, SB, PHEIGHT, PDENSITY, PCDRAG, PAIRVOL, PSV, &
                  PFORC, PFORC_U, PDFORC_UDU, PFORC_E, PDFORC_EDE   )  
!     ###############################################################################
!
!!****  *ISBA_CANOPY_n * - prepares forcing for canopy air model
!!
!!    SB%XURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2006
!!---------------------------------------------------------------
!
USE modd_canopy_n, ONLY : canopy_t
!
USE modd_csts,         ONLY : xrd, xcpd, xp00, xg
USE modd_surf_par,     ONLY : xundef
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER,                  INTENT(IN)    :: KI        ! number of points
TYPE(canopy_t), INTENT(INOUT) :: SB
REAL, DIMENSION(KI), INTENT(IN)    :: PHEIGHT   ! canopy height                       (m)
REAL, DIMENSION(KI,SB%NLVL), INTENT(IN)    :: PDENSITY  ! canopy density                  (-)
REAL, DIMENSION(KI,SB%NLVL), INTENT(IN)    :: PCDRAG
!
REAL, DIMENSION(KI,SB%NLVL), INTENT(IN)    :: PAIRVOL   ! Fraction of air for each canopy level total volume
!
REAL, DIMENSION(KI,SB%NLVL), INTENT(OUT)   :: PSV       ! vertical surface of building
                                                     ! (walls) for each canopy level
REAL, DIMENSION(KI,SB%NLVL), INTENT(OUT)   :: PFORC     !
!
REAL, DIMENSION(KI,SB%NLVL), INTENT(OUT)   :: PFORC_U   ! tendency of wind due to canopy drag   (m/s2)
REAL, DIMENSION(KI,SB%NLVL), INTENT(OUT)   :: PDFORC_UDU! formal derivative of the tendency of
!                                                    ! wind due to canopy drag               (1/s)
REAL, DIMENSION(KI,SB%NLVL), INTENT(OUT)   :: PFORC_E   ! tendency of TKE  due to canopy drag   (m2/s3)
REAL, DIMENSION(KI,SB%NLVL), INTENT(OUT)   :: PDFORC_EDE! formal derivative of the tendency of
!                                                    ! TKE  due to canopy drag               (1/s)
!
!*      0.2    declarations of local variables
!
INTEGER                  :: JLAYER    ! loop counter on canopy heights      
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('CANOPY',0,zhook_handle)
!
!*      1.     Computations of canopy grid characteristics
!              -------------------------------------------
!
!
!*      1.2    Discretization on each canopy level
!
psv(:,:) = 0.
DO jlayer = 1,sb%NLVL-1
  !
  WHERE ( sb%XZF(:,jlayer) < pheight(:) )
    psv(:,jlayer) = pdensity(:,jlayer) / pheight(:)
    WHERE ( sb%XZF(:,jlayer+1) > pheight(:) )
      psv(:,jlayer) = psv(:,jlayer) * ( pheight(:) - sb%XZF(:,jlayer) )
    ELSEWHERE
      psv(:,jlayer) = psv(:,jlayer) *  sb%XDZ(:,jlayer)
    END WHERE
  END WHERE
  !
END DO
!
pforc(:,:) = pcdrag(:,:) * sb%XU(:,:) * psv(:,:)/pairvol(:,:)/sb%XDZ(:,:)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Computations of wind tendency due to canopy drag
!              ------------------------------------------------
!
pforc_u    = 0.
pdforc_udu = 0.
!
! Ext = - Cdrag  * u- * u- * Sv       tree canopy drag
!       - u'w'(ground)     * Sh       horizontal surfaces (ground)
!
!
!*      2.2    Drag force by wall surfaces
!              ---------------------------
!
!* drag force by vertical surfaces
!
pforc_u(:,:) = pforc_u    -      pforc(:,:) * sb%XU(:,:)
pdforc_udu(:,:) = pdforc_udu - 2. * pforc(:,:)
!
!-------------------------------------------------------------------------------------
!
!*      3.     Computations of TKE  tendency due to canopy drag
!              ------------------------------------------------
!
!* Tendency due to drag for TKE
!
pforc_e(:,:) = 0.
pdforc_ede(:,:) = 0.
!
!*      3.1    Creation of TKE by wake
!              -----------------------
!
! from Kanda and Hino (1994)
!
! Ext = + Cd * u+^3  * Sv/Vair        vertical surfaces or trees
!
! with Vair = Vair/Vtot * Vtot = (Vair/Vtot) * Stot * Dz
! and  Sv/Vair = (Sv/Stot) * Stot/Vair = (Sv/Stot) / (Vair/Vtot) / Dz
!
pforc_e    = pforc_e    + pforc(:,:) * sb%XU(:,:)**2
pdforc_ede = pdforc_ede + 0.
!
!
IF (lhook) CALL dr_hook('CANOPY',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE canopy