bld_e_budget.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE bld_e_budget( OTI_EVOL, PTSTEP, PBLD, PWALL_O_HOR,      &
                             PRHOA, PT_ROOF, PT_WALL, PTI_BLD, PTS_FLOOR )  
!   ##########################################################################
!
!!****  *BLD_E_BUDGET*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the evoultion of the temperature of inside building air
        
!     
!!**  METHOD
!     ------
!
!     The resistance term between the surfaces and the room is given
!     by a standard value, which mimics both the convection
!     and the radiative interactions in the room.
!     This explains the very low resistance. It is used to compute
!     the evolution of the surfaces only.
!     This resistance value is 0.123 Km/W  (typical for inside surfaces).
!     (ENVIRONMENTAL SCIENCE IN BUILDING, 3rd Edition, Randall McMullan,
!      THE MACMILLAN PRESS Limited).
!
!
!
!     On the contrary, the evolution of the air temperature is mainly
!     governed by the convection (considering the low radiative absorption
!     of the air itself).
!     In order to have a simple formulation, a diurnal cycle is assumed,
!     with a force restore formulation.
!
!     The floor temperature is fixed
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      V. Masson           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    24/08/00 
!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_csts,ONLY : xtt, xcpd, xday
USE modd_surf_par,ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
LOGICAL,              INTENT(IN)   :: OTI_EVOL      ! true --> internal temp. of
!                                                   !      of buildings evolves
!                                                   ! false--> it is fixed
REAL,                 INTENT(IN)   :: PTSTEP        ! time step
REAL, DIMENSION(:),   INTENT(IN)   :: PBLD          ! building fraction
REAL, DIMENSION(:),   INTENT(IN)   :: PWALL_O_HOR   ! wall surf. / hor. surf.
REAL, DIMENSION(:),   INTENT(IN)   :: PRHOA         ! air density
                                                    ! at the lowest level
REAL, DIMENSION(:,:), INTENT(IN)   :: PT_ROOF       ! roof layers temperatures
REAL, DIMENSION(:,:), INTENT(IN)   :: PT_WALL       ! wall layers temperatures
REAL, DIMENSION(:),   INTENT(INOUT):: PTI_BLD       ! building air temperature
                                                    ! computed with its equation evolution
REAL, DIMENSION(:),   INTENT(IN)  :: PTS_FLOOR     ! floor surface temperature
!
!*      0.2    declarations of local variables
!
!
REAL                           :: ZTAU         ! temporal filter period
!
INTEGER                        :: IROOF        ! number of roof layers
INTEGER                        :: IWALL        ! number of wall layers
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('BLD_E_BUDGET',0,zhook_handle)
!
!*      1.   initializations
!            ---------------
!
iroof = SIZE(pt_roof,2)
iwall = SIZE(pt_wall,2)
!
!!! 27/01/2012 passé dans TEB
!! PTS_FLOOR(:)= 19. + XTT
!!! 27/01/2012 passé dans TEB
!
!*      2.   no evolution of interior temperature if OTI_EVOL=.FALSE.
!            --------------------------------------------------------
!
IF (.NOT. oti_evol .AND. lhook) CALL dr_hook('BLD_E_BUDGET',1,zhook_handle)
IF (.NOT. oti_evol) RETURN
!
!*      3.   evolution of the internal temperature
!            -------------------------------------
!
ztau = xday
!
WHERE (pbld(:) .GT. 0.)
  pti_bld(:) = pti_bld(:) * (ztau-ptstep)/ztau       &
            + ( pt_roof(:,iroof) * pbld(:)    &
              + pt_wall(:,iwall) * pwall_o_hor(:)    &
              + pts_floor(:)      * pbld(:) )  &
             / (  2. * pbld(:)  +  pwall_o_hor(:) ) * ptstep / ztau
ELSEWHERE
  pti_bld(:) = pts_floor(:)
ENDWHERE
!
!
!*      5.   internal temperature set to a minimum value (heating)
!            -----------------------------------------------------
! 
pti_bld(:) = max( pti_bld(:) , pts_floor(:) )
!
IF (lhook) CALL dr_hook('BLD_E_BUDGET',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE bld_e_budget