bilin_value.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
     SUBROUTINE bilin_value (KLUOUT,KX,KY,PFIELD1,PCX,PCY,KCI,KCJ,PFIELD2)
!     #########################################################################
!
!!****  *BILIN_VALUEEAR * - subroutine to interpolate surface FIELD
!!
!!    PURPOSE
!!    -------
!!
!!
!!**  METHOD
!!    ------
!!
!!     Interpolation is bilinear, and uses 9 grid points, located in the
!!   center of model 1 grid mesh, and at the boundaries of this grid
!!   mesh (2 X limits, 2 Y limits and 4 corners).
!!     This implies that the grid mesh values located around the model 1
!!   grid mesh are not used directly. The values at the boundaries of the
!!   grid mesh are defined by the average between the middle point
!!   (this grid mesh value), and the one in the considered direction.
!!   So the eight grid meshes around the considered grid mesh are used
!!   equally.
!!     This is important to note that these average values are erased
!!   and replaced by zero if they are at the limit of any grid
!!   mesh with the zero value. This allows to insure zero value in model 2
!!   grid meshes where there was not the considered class in corresponding
!!   model 1 grid mesh, and to insure continuity of the FIELD type
!!   at such boundaries.
!!
!!
!!    The arrays and array index are defined on the following (model1) grid:
!!
!!
!!        XFIELD                    XFIELD                    XFIELD
!!          *                         *                         *
!!       i-1,j+1                    i,j+1                    i+1,j+1
!!
!!
!!
!!                   ZFIELD_XY     ZFIELD_Y    ZFIELD_XY
!!                       *            *            *
!!                     i,j+1        i,j+1       i+1,j+1
!!
!!
!!
!!        XFIELD      ZFIELD_X      XFIELD      ZFIELD_X      XFIELD
!!          *            *            *            *            *
!!        i-1,j         i,j          i,j         i+1,j        i+1,j
!!
!!
!!
!!                    ZFIELD_XY     ZFIELD_Y    ZFIELD_XY
!!                       *            *            *
!!                      i,j          i,j         i+1,j
!!
!!
!!
!!        XFIELD                    XFIELD                    XFIELD
!!          *                         *                         *
!!       i-1,j-1                    i,j-1                    i+1,j-1
!!
!!
!!
!!
!!
!!    AUTHOR
!!    ------
!!
!!       V. Masson     * METEO-FRANCE *
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      Original     01/2004
! TD&DD: added OpenMP directives

!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surfex_mpi, ONLY : nrank, npio, ncomm, nproc, idx_i
USE modd_surf_par,   ONLY : xundef
!
USE modi_bilin_gridin
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*       0.1   Declarations of dummy arguments :
!
INTEGER,              INTENT(IN) :: KLUOUT  ! output listing logical unit
INTEGER, INTENT(IN) :: KX, KY
REAL, DIMENSION(:,:), INTENT(IN) :: PFIELD1 ! FIELD on regular input grid
REAL, DIMENSION(:,:), INTENT(IN) :: PCX, PCY
INTEGER, DIMENSION(:), INTENT(IN):: KCI, KCJ
REAL, DIMENSION(:,:),   INTENT(OUT) :: PFIELD2 ! FIELD on model 2
!
!*       0.2    Declarations of local variables for print on FM file
!
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE) :: ISTATUS
#endif
REAL, DIMENSION(:,:,:), ALLOCATABLE :: ZFIELD1,ZFIELDS
REAL, DIMENSION(:,:), ALLOCATABLE :: ZFIELD_X, ZFIELD_Y, ZFIELD_XY
INTEGER, DIMENSION(2) :: IB
INTEGER, DIMENSION(2,2) :: IJEXT
INTEGER, DIMENSION(2,2,0:NPROC-1) :: IBOR
INTEGER :: INFOMPI, ISIZE, IS1, IS2, J, IT1, IT2
INTEGER  :: JL, JK, JI, JJ, INL        ! grid 2 index
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE, ZHOOK_HANDLE_OMP
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('BILIN_VALUE_1',0,zhook_handle)
!
inl = SIZE(pfield2,2)
!
IF (SIZE(kci)>0) THEN
  ijext(1,1) = max(1,minval(kci)-1)
  ijext(1,2) = min(maxval(kci)+1,kx)
  ijext(2,1) = max(1,minval(kcj)-1)
  ijext(2,2) = min(maxval(kcj)+1,ky)
ELSE
  ijext(:,:) = 0
ENDIF
!
IF (lhook) CALL dr_hook('BILIN_VALUE_1',1,zhook_handle)

IF (lhook) CALL dr_hook('BILIN_VALUE_2',0,zhook_handle)
!
IF (nproc>1) THEN
#ifdef SFX_MPI
  CALL mpi_gather(ijext,4*kind(ijext)/4,mpi_integer,&
                ibor,4*kind(ibor)/4,mpi_integer,& 
                npio,ncomm,infompi)
#endif
ELSE
  ibor(:,:,0) = ijext(:,:)
ENDIF
!
IF (lhook) CALL dr_hook('BILIN_VALUE_2',1,zhook_handle)
!
IF (nrank/=npio) THEN
  !
  IF (lhook) CALL dr_hook('BILIN_VALUE_3',0,zhook_handle)
  !
  idx_i = idx_i + 1
  is1 = ijext(1,2)-ijext(1,1)+1
  is2 = ijext(2,2)-ijext(2,1)+1
  isize = is1*is2
  ALLOCATE(zfield1(is1,is2,inl))
#ifdef SFX_MPI  
  IF (sum(ijext)/=0) &
    CALL mpi_recv(zfield1,isize*inl*kind(zfield1)/4,mpi_real,npio,idx_i,ncomm,istatus,infompi)
#endif
  !
  IF (lhook) CALL dr_hook('BILIN_VALUE_3',1,zhook_handle)
  !
ELSE
  !
!$OMP PARALLEL PRIVATE(ZHOOK_HANDLE_OMP)
!$OMP DO SCHEDULE(DYNAMIC,1) PRIVATE(J,IT1,IT2,ISIZE,ZFIELDS)
  DO j=0,nproc-1
    !
    IF (j/=npio) THEN
      !
      IF (lhook) CALL dr_hook('BILIN_VALUE_31',0,zhook_handle_omp)
      !
      it1 = ibor(1,2,j)-ibor(1,1,j)+1
      it2 = ibor(2,2,j)-ibor(2,1,j)+1
      isize = it1*it2
      IF (sum(ibor(:,:,j))/=0) THEN
        ALLOCATE(zfields(it1,it2,inl))
        DO jl=ibor(2,1,j),ibor(2,2,j)
          zfields(:,jl-ibor(2,1,j)+1,:) = pfield1(kx*(jl-1)+ibor(1,1,j):kx*(jl-1)+ibor(1,2,j),:)
        ENDDO
#ifdef SFX_MPI        
        CALL mpi_send(zfields,SIZE(zfields)*kind(zfields)/4,mpi_real,j,idx_i+1,ncomm,infompi)
#endif
        DEALLOCATE(zfields)
      ENDIF
      IF (lhook) CALL dr_hook('BILIN_VALUE_31',1,zhook_handle_omp)
      !
    ELSE
      !    
      IF (lhook) CALL dr_hook('BILIN_VALUE_32',0,zhook_handle_omp)
      !
      is1 = ibor(1,2,0)-ibor(1,1,0)+1
      is2 = ibor(2,2,0)-ibor(2,1,0)+1
      isize = is1*is2
      ALLOCATE(zfield1(is1,is2,inl))
      IF (sum(ibor(:,:,0))/=0) THEN    
        DO jl=ibor(2,1,0),ibor(2,2,0)
          zfield1(:,jl-ibor(2,1,0)+1,:) = pfield1(kx*(jl-1)+ibor(1,1,0):kx*(jl-1)+ibor(1,2,0),:)
        ENDDO
      ENDIF
      !
      IF (lhook) CALL dr_hook('BILIN_VALUE_32',1,zhook_handle_omp)
      !
    ENDIF
    !
  ENDDO
!$OMP END DO
!$OMP END PARALLEL
  !
  idx_i = idx_i + 1
  !
ENDIF
!
ALLOCATE(zfield_x(is1+1,is2),zfield_y(is1,is2+1),zfield_xy(is1+1,is2+1))
!
DO jk=1,inl
  !
  IF (lhook) CALL dr_hook('BILIN_VALUE_4',0,zhook_handle)
  CALL bilin_gridin(zfield1(:,:,jk),zfield_x,zfield_y,zfield_xy)
  !
  IF (lhook) CALL dr_hook('BILIN_VALUE_4',1,zhook_handle)
  IF (lhook) CALL dr_hook('BILIN_VALUE_5',0,zhook_handle)
  pfield2(:,jk) = xundef
  !
  DO jl=1,SIZE(pfield2,1)
    !
    ji = kci(jl) - ijext(1,1) + 1
    jj = kcj(jl) - ijext(2,1) + 1
    ji = max(min(ji,SIZE(zfield1,1)),0)
    jj = max(min(jj,SIZE(zfield1,2)),0)
    !
    !* interpolation weights in X direction
    !
    !
    !* interpolation
    !
    IF(zfield1(ji,jj,jk) /= xundef) THEN
      
      pfield2(jl,jk) = pcy(jl,1) * &
         ( pcx(jl,1) * zfield_xy(ji,jj)   + pcx(jl,2) * zfield_y(ji,jj)   + pcx(jl,3) * zfield_xy(ji+1,jj) ) &
                  + pcy(jl,2) * &
         ( pcx(jl,1) * zfield_x(ji,jj)   + pcx(jl,2) * zfield1(ji,jj,jk) + pcx(jl,3) * zfield_x(ji+1,jj) ) &
                  + pcy(jl,3) * &
         ( pcx(jl,1) * zfield_xy(ji,jj+1) + pcx(jl,2) * zfield_y(ji,jj+1) + pcx(jl,3) * zfield_xy(ji+1,jj+1) )  

    ENDIF

  END DO
  !
  IF (lhook) CALL dr_hook('BILIN_VALUE_5',1,zhook_handle)
  !
ENDDO
!
IF (lhook) CALL dr_hook('BILIN_VALUE_6',0,zhook_handle)
!
DEALLOCATE(zfield1,zfield_x,zfield_y,zfield_xy)
!
!-------------------------------------------------------------------------------
!
WHERE(abs(pfield2-xundef)<1.e-6) pfield2=xundef
!
IF (lhook) CALL dr_hook('BILIN_VALUE_6',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE bilin_value