average_flux.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average_flux(PFRAC_TILE,             &
                   PSFTH_TILE, PSFTQ_TILE,              &
                   PSFTS_TILE, PSFCO2_TILE,             &
                   PSFU_TILE, PSFV_TILE,                &
                   PSFTH, PSFTQ, PSFTS, PSFCO2,         &
                   PSFU, PSFV                           )  
!     ######################################################################
!
!
!!****  *AVERAGE_FLUX*  
!!
!!    PURPOSE
!!    -------
!      Average the fluxes from the land and water surfaces depending on the
!      fraction of each surface cover type in the mesh area.
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/03/95 
!!      V.Masson    20/03/96  remove abnormal averages and average TS**4 instead
!!                            of TS
!!      (J.Stein)   27/03/96 use only H and LE in the soil scheme
!!      A. Boone    27/11/02 revised to output ALMA variables, and general applications
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE modd_surf_par,   ONLY : xundef
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:,:), INTENT(IN) :: PFRAC_TILE ! Fraction in a mesh-area of 
!                                              ! a given surface
REAL, DIMENSION(:,:), INTENT(IN) :: PSFTH_TILE ! pot. temp. flux  (mK/s)
REAL, DIMENSION(:,:), INTENT(IN) :: PSFTQ_TILE ! water vapor flux (m kg/kg/s)
REAL, DIMENSION(:,:), INTENT(IN) :: PSFCO2_TILE! CO2 flux         (m kg/kg/s)
REAL, DIMENSION(:,:,:),INTENT(IN):: PSFTS_TILE ! scalar flux      (m kg/kg/s)
REAL, DIMENSION(:,:), INTENT(IN) :: PSFU_TILE  ! zonal momentum flux    (pa)
REAL, DIMENSION(:,:), INTENT(IN) :: PSFV_TILE  ! meridian momentum flux (pa)
REAL, DIMENSION(:),   INTENT(OUT):: PSFTH      ! pot. temp. flux  (mK/s)
REAL, DIMENSION(:),   INTENT(OUT):: PSFTQ      ! water vapor flux (m kg/kg/s)
REAL, DIMENSION(:,:), INTENT(OUT):: PSFTS      ! scalar flux      (m kg/kg/s)
REAL, DIMENSION(:),   INTENT(OUT):: PSFCO2     ! CO2 flux         (m kg/kg/s)
REAL, DIMENSION(:),   INTENT(OUT):: PSFU       ! zonal momentum flux    (pa)
REAL, DIMENSION(:),   INTENT(OUT):: PSFV       ! meridian momentum flux (pa)
!
!*      0.2    declarations of local variables
!
INTEGER :: JSV   ! scalar loop counter
INTEGER :: JTILE ! tile loop counter
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!       0.     Initialization
!              --------------
!
IF (lhook) CALL dr_hook('AVERAGE_FLUX',0,zhook_handle)
psfth(:)   = 0.
psftq(:)   = 0.
psfco2(:)   = 0.
psfu(:)   = 0.
psfv(:)   = 0.
psfts(:,:) = 0.
!
!       1.     Grid-Box average 1d fluxes
!              --------------------------
!
!
DO jtile = 1, SIZE(psfth_tile,2)
!
!  potential temperature flux:
!
   psfth(:)  = psfth(:) + pfrac_tile(:,jtile) * psfth_tile(:,jtile)
!
!  water vapor flux:
!
   psftq(:)  = psftq(:) + pfrac_tile(:,jtile) * psftq_tile(:,jtile)
!
!  carbon flux:
!
   psfco2(:)  = psfco2(:) + pfrac_tile(:,jtile) * psfco2_tile(:,jtile)
!
!  wind surface friction:
!
   psfu(:)  = psfu(:) + pfrac_tile(:,jtile) * psfu_tile(:,jtile)
   psfv(:)  = psfv(:) + pfrac_tile(:,jtile) * psfv_tile(:,jtile)
!   
END DO
!
!
!
!       2.     Grid-Box average 2d fluxes
!              --------------------------
!
DO jsv = 1, SIZE(psfts_tile,2)
!
   DO jtile = 1, SIZE(psfts_tile,3)
!
!     scalar flux
!
      psfts(:,jsv) = psfts(:,jsv) + pfrac_tile(:,jtile) * psfts_tile(:,jsv,jtile)
!
   END DO
!
END DO
IF (lhook) CALL dr_hook('AVERAGE_FLUX',1,zhook_handle)

!-------------------------------------------------------------------------------
!
END SUBROUTINE average_flux