average1_orography.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average1_orography (UG,USS, &
                                     KLUOUT,KNBLINES,PLAT,PLON,PVALUE,PNODATA)
!     #######################################################
!
!!**** *AVERAGE1_OROGRAPHY* computes the sum of orography, squared orography
!!                              and subgrid orography characteristics
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    12/09/95
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_pgdwork,       ONLY : xall, xext_all, nsize_all, xsso_all, nsso_all, nsso
!
USE modi_get_mesh_index
USE modd_point_overlay, ONLY : novmx
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(sso_t), INTENT(INOUT) :: USS
!
INTEGER,                 INTENT(IN)    :: KLUOUT
INTEGER,                 INTENT(IN)    :: KNBLINES
REAL, DIMENSION(:),      INTENT(IN)    :: PLAT    ! latitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: PLON    ! longitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: PVALUE  ! value of the point to add
REAL, OPTIONAL, INTENT(IN) :: PNODATA
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: IINDEX ! mesh index of all input points
                                         ! 0 indicates the point is out of the domain
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: ISSOX  ! X submesh index in their mesh of all input points
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: ISSOY  ! Y submesh index in their mesh of all input points
!
INTEGER :: JL, JOV        ! loop index on input arrays
REAL, DIMENSION(SIZE(PLAT)) :: ZVALUE
REAL :: ZNODATA
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
!
!*    1.     Get position
!            ------------
!     
IF (lhook) CALL dr_hook('AVERAGE1_OROGRAPHY',0,zhook_handle)
!      
IF (PRESENT(pnodata)) THEN
  zvalue(:) = pvalue(:)
  znodata = pnodata
  CALL get_mesh_index(ug,kluout,knblines,plat,plon,iindex,zvalue,znodata,nsso,issox,issoy)
ELSE
  zvalue(:) = 1.
  znodata = 0.
  CALL get_mesh_index(ug,kluout,knblines,plat,plon,iindex,ksso=nsso,kissox=issox,kissoy=issoy)
ENDIF
!
!*    2.     Loop on all input data points
!            -----------------------------
!    
bloop: &
DO jl = 1 , SIZE(plat)
!
  DO jov = 1, novmx
!
!*    3.     Tests on position
!            -----------------
!     
    IF (iindex(jov,jl)==0) cycle bloop
!
!*    4.     Summation
!            ---------
!
    nsize_all(iindex(jov,jl),1) = nsize_all(iindex(jov,jl),1)+1
!
!*    5.     Orography
!            ---------
!
    xall(iindex(jov,jl),1,1) = xall(iindex(jov,jl),1,1)+pvalue(jl)
!
!*    6.     Square of Orography
!            -------------------
!
    xall(iindex(jov,jl),2,1) = xall(iindex(jov,jl),2,1)+pvalue(jl)**2
!
!*    7.     Maximum orography in a subgrid square
!            -------------------------------------
!
    nsso_all(iindex(jov,jl),issox(jov,jl),issoy(jov,jl)) = 1
    xsso_all(iindex(jov,jl),issox(jov,jl),issoy(jov,jl)) = &
         max(  xsso_all(iindex(jov,jl),issox(jov,jl),issoy(jov,jl)) , pvalue(jl) )   
!
!
!*    8.     Maximum orography in the mesh
!            -----------------------------
!
    xext_all(iindex(jov,jl),1) = max(xext_all(iindex(jov,jl),1),pvalue(jl))
!
!
!*    9.     Minimum orography in the mesh
!            -----------------------------
!
    xext_all(iindex(jov,jl),2) = min(xext_all(iindex(jov,jl),2),pvalue(jl))
!
!
  END DO
!
ENDDO bloop
IF (lhook) CALL dr_hook('AVERAGE1_OROGRAPHY',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE average1_orography