average1_ldb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average1_ldb(UG,KLUOUT,KNBLINES,PLAT,PLON,PVALUE,HTYPE,PNODATA)
!     #######################################################
!
!!**** *AVERAGE1_LDB* 
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    S. Faroux         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    17/02/11
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
!
USE modd_pgdwork, ONLY : xall, nsize_all
USE modd_data_lake, ONLY : xboundgraddepth_ldb, xboundgradstatus_ldb
!
USE modd_point_overlay
!
USE modi_get_mesh_index
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
!
INTEGER,                 INTENT(IN)    :: KLUOUT
INTEGER,                 INTENT(IN)    :: KNBLINES
REAL, DIMENSION(:),      INTENT(IN)    :: PLAT    ! latitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: PLON    ! longitude of the point to add
REAL, DIMENSION(:),      INTENT(IN)    :: PVALUE  ! value of the point to add
 CHARACTER(LEN=1),       INTENT(IN)    :: HTYPE
REAL, OPTIONAL, INTENT(IN) :: PNODATA
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL, DIMENSION(:), ALLOCATABLE :: ZBOUND
!
INTEGER, DIMENSION(NOVMX,SIZE(PLAT)) :: IINDEX ! mesh index of all input points
                                         ! 0 indicates the point is out of the domain                              
!
REAL, DIMENSION(SIZE(PLAT)) :: ZVALUE
REAL :: ZNODATA
!
REAL    :: ZCUT
INTEGER :: JL, JGR, JOV        ! loop index on input arrays
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
!*    1.     Get position
!            ------------
!     
IF (lhook) CALL dr_hook('AVERAGE1_LDB',0,zhook_handle)
!
SELECT CASE (htype)
!
  CASE('D')
    ALLOCATE(zbound(SIZE(xboundgraddepth_ldb)))
    zbound(:) = xboundgraddepth_ldb(:)
!
  CASE('S')
    ALLOCATE(zbound(SIZE(xboundgradstatus_ldb)))
    zbound(:) = xboundgradstatus_ldb(:)
!
  CASE DEFAULT
    CALL abor1_sfx("AVERAGE1_LDB: HTYPE NOT SUPPORTED")
!
END SELECT
!
!
IF (PRESENT(pnodata)) THEN
  zvalue(:) = pvalue(:)
  znodata = pnodata
  CALL get_mesh_index(ug,kluout,knblines,plat,plon,iindex,zvalue,znodata)
ELSE
  zvalue(:) = 1.
  znodata = 0.
  CALL get_mesh_index(ug,kluout,knblines,plat,plon,iindex)
ENDIF
!
!*    2.     Loop on all input data points
!            -----------------------------
!    
bloop: &
DO jl = 1 , SIZE(plat)
!
  DO jov = 1, novmx
!
!*    3.     Tests on position
!            -----------------
!     
    IF (iindex(jov,jl)==0) cycle bloop
!
!*    4.     Test on value meaning
!            ---------------------
!
    zcut = pvalue(jl)
!
    DO jgr = 1, SIZE(zbound)-1
      IF (zcut.GT.zbound(jgr) .AND. zcut.LE.zbound(jgr+1)) THEN
        xall(iindex(1,jl),jgr,1) = xall(iindex(1,jl),jgr,1) + 1
        EXIT
      ENDIF
    ENDDO
!
!*    5.     Summation
!            ---------
!
    nsize_all(iindex(1,jl),1)=nsize_all(iindex(1,jl),1)+1
!
  END DO
!
ENDDO bloop
!
DEALLOCATE(zbound)
!
IF (lhook) CALL dr_hook('AVERAGE1_LDB',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE average1_ldb